batch-file - 为什么 xcopy 需要多个引号？

Question

当我的备份脚本中的 FOR 循环使用双引号输入参数（“默认用户”）时，我会在 xcopy 命令行中收到“参数数量无效”错误，除非我用一对额外的双引号将其括起来。没有额外的引号，其他命令可以正常工作。有人可以解释为什么 xcopy 会这样，以及是否有避免额外引号的解决方法？谢谢。

@echo off
setlocal
set drive=O:\Backups\test
set backupcmd=xcopy /s /c /d /e /i /r /y

if exist "c:\users" goto startvis7
if exist "c:\documents and settings\" goto startxp

:startxp
for %%a in ("Default User" Owner) do (
if exist "c:\documents and settings\%%a" (
echo ### Backing up desktop for %%a...
%backupcmd% ""c:\documents and settings\%%a\desktop"" ""%drive%\%%a\desktop""
) else (echo ### Account %%a not found.)
)
goto eof

:startvis7
for %%a in ("Default User" Owner) do (
if exist "c:\users\%%a" (
echo ### Backing up desktop for %%a...
%backupcmd% ""c:\users\%%a\desktop"" ""%drive%\%%a\desktop""
) else (echo ### Account %%a not found.)
)
:eof
echo Backup Complete!
@pause
endlocal

Answer 1

你遇到了%%ain
%backupcmd% ""c:\users\%%a\desktop"" ""%drive%\%%a\desktop""
它也可以包含引号的问题，所以你的字符串可能看起来像
""c:\users\"Default User"\desktop""

您可以使用%%~a语法，它会去除周围的引号，然后您应该可以使用
%backupcmd% "c:\users\%%~a\desktop" "%drive%\%%~a\desktop"