2

我想为每个字母写一个带有链接的字母表。所以我使用了模板，但我不知道如何制作这个字母我试过了，但我犯了一个正常的错误：（十进制表示必须立即跟在字符引用中的 之后）。

<xsl:template name="alphabet">
    <xsl:param name="iLetter"/>
    <xsl:if test="$iLetter &lt; 91">
        <a><xsl:attribute name="href">req.html?X_letter=&#<xsl:value-of select="$iLetter"/>;</xsl:attribute>&#<xsl:value-of select="$iLetter"/>;</xsl:attribute></a>
        <xsl:call-template name="alphabet">
            <xsl:with-param name="iLetter" select="number($iLetter)+1"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

我称这个模板为：

<xsl:call-template name="alphabet">
        <xsl:with-param name="iLetter" select="number(65)"/>
</xsl:call-template>

所以，我想得到这个结果：

A B C D ..... X Y Z没有......当然:)

4

4 回答 4

2

当前接受的答案是不正确的，因为它不能正确生成任何元素的文本子a元素。

这是一个正确的 XSLT 1.0 解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vAlpha" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:template match="/">
     <xsl:call-template name="alphabet"/>
 </xsl:template>

 <xsl:template name="alphabet">
  <xsl:param name="pCode" select="65"/>
  <xsl:if test="not($pCode > 90)">
    <xsl:variable name="vChar" select=
     "substring($vAlpha, $pCode - 64, 1)"/>
    <a href="req.html?X_letter={$vChar}">
     <xsl:value-of select="$vChar"/>
    </a>
    <xsl:call-template name="alphabet">
      <xsl:with-param name="pCode" select="$pCode+1"/>
    </xsl:call-template>
   </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当应用于任何 XML 文档（未使用）时，会产生所需的正确结果：

<a href="req.html?X_letter=A">A</a>
<a href="req.html?X_letter=B">B</a>
<a href="req.html?X_letter=C">C</a>
<a href="req.html?X_letter=D">D</a>
<a href="req.html?X_letter=E">E</a>
<a href="req.html?X_letter=F">F</a>
<a href="req.html?X_letter=G">G</a>
<a href="req.html?X_letter=H">H</a>
<a href="req.html?X_letter=I">I</a>
<a href="req.html?X_letter=J">J</a>
<a href="req.html?X_letter=K">K</a>
<a href="req.html?X_letter=L">L</a>
<a href="req.html?X_letter=M">M</a>
<a href="req.html?X_letter=N">N</a>
<a href="req.html?X_letter=O">O</a>
<a href="req.html?X_letter=P">P</a>
<a href="req.html?X_letter=Q">Q</a>
<a href="req.html?X_letter=R">R</a>
<a href="req.html?X_letter=S">S</a>
<a href="req.html?X_letter=T">T</a>
<a href="req.html?X_letter=U">U</a>
<a href="req.html?X_letter=V">V</a>
<a href="req.html?X_letter=W">W</a>
<a href="req.html?X_letter=X">X</a>
<a href="req.html?X_letter=Y">Y</a>
<a href="req.html?X_letter=Z">Z</a>

二、XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="my:my" exclude-result-prefixes="xs my"
    xmlns="http://www.w3.org/1999/xhtml">
    <xsl:output omit-xml-declaration="yes" method="xhtml" indent="yes"/>

    <xsl:param name="pStart" as="xs:integer" select="65"/>
    <xsl:param name="pEnd" as="xs:integer" select="90"/>

    <xsl:variable name="vCodes" as="xs:integer*" select=
     "for $i in $pStart to $pEnd
       return $i
     "/>

 <xsl:template match="/">
   <html>
       <xsl:sequence select="my:alphabet()"/>
   </html>
 </xsl:template>

 <xsl:function name="my:alphabet" as="element()*">
  <xsl:for-each select="$vCodes">
    <xsl:variable name="vChar" select="codepoints-to-string(.)"/>
    <a href="req.html?X_letter={$vChar}">
     <xsl:sequence select="$vChar"/>
    </a>
  </xsl:for-each>
 </xsl:function>
</xsl:stylesheet>
于 2011-11-26T16:38:01.280 回答
0

在a元素内容内部，您可以禁用输出转义，如

<a href="req.html?X_letter={$iLetter}">
  <xsl:value-of select="concat('&amp;#', $iLetter, ';')" disable-output-escaping="yes"/>
</a>

然而，这种方法在属性节点中不起作用，所以我离开那部分来传递字符代码，而不是字符。

另请注意，disable-output-escaping 是一种可选的序列化功能，并非所有 XSLT 处理器都支持，例如 Firefox/Mozilla 的内置 XSLT 处理器不会序列化结果树，而是简单地呈现它，因此该方法不会去去工作。

于 2011-11-26T11:59:15.377 回答
0

正如马丁建议的那样，最好避免使用禁用输出转义。您也不需要它，如果您对纯 ascii 字符而不是数字字符引用感到满意。如果是这样，您可以像这样使用子字符串和字母查找字符串：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="alphabet" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

    <xsl:template name="alphabet"> 
        <xsl:param name="iLetter" select="65"/> 
        <xsl:if test="$iLetter &lt; 91"> 
            <a>
                <xsl:attribute name="href">req.html?X_letter=<xsl:value-of select="substring($alphabet, $iLetter - 64, 1)"/></xsl:attribute>
                <xsl:value-of select="substring($alphabet, $iLetter - 64, 1)"/>
            </a> 
            <xsl:call-template name="alphabet"> 
                <xsl:with-param name="iLetter" select="number($iLetter)+1"/> 
            </xsl:call-template> 
        </xsl:if> 
    </xsl:template> 

    <xsl:template match="/">
        <xsl:call-template name="alphabet"/> 
    </xsl:template>
</xsl:stylesheet>

干杯!

于 2011-11-26T13:39:18.113 回答
0

XSLT 2.0 具有该功能codepoints-to-string()。对于许多 XSLT 1.0 处理器，实现与扩展函数相同的函数应该很容易，尽管它会使您的代码依赖于该处理器。

于 2011-11-27T10:10:19.027 回答