3

前段时间，我问了一个问题：如何重新定义 Perl 的内置函数？

答案对我很有帮助。我有一个包覆盖 Perl 的“打开”功能，使我能够记录文件访问。

现在我遇到了一个破坏原始代码功能的案例。

use strict;
use warnings;
use Data::Dumper;

sub myopen (*;@) {
  my $p;
  my $retval = CORE::open($p, $_[1]);
  {
    no strict;
    *{"main::$_[0]"} = $p;
  }
  return $retval;
}

BEGIN {
  *CORE::GLOBAL::open = *myopen;
};

my @a = (1, 2, 3);

open(CHECK, ">dump") or print "UNABLE TO OPEN DUMPER FILE: $!\n";
print CHECK "test\n";
print CHECK Data::Dumper->Dump(\@a);
close CHECK

现在我收到这条消息：

Can't locate object method "CHECK" via package "Data::Dumper"

我如何解决它？

4

3 回答 3

8

尝试使用 "CHECK" 以外的名称。

“CHECK”是一个在编译时调用的特殊函数，你真的不应该使用它。

$ open CHECK , '<', 'foo.txt'; 
Took 0.00224494934082031 seconds.

Runtime error: Undefined subroutine &Devel::REPL::Plugin::Packages::DefaultScratchpad::CHECK called at (eval 329) line 5.

$ open CHECKS , '<', 'foo.txt'; 
Took 0.00155806541442871 seconds.

$

为什么会出现这个特定错误？

perl -MO=Deparse -e 'print CHECK Data::Dumper 1';
print 'Data::Dumper'->CHECK(1);

此外，您正在使用全局文件句柄，这是有问题的。

使用这个符号：

open my $fh, '<' , $foo ; 
print <$fh>;
close $fh;

这些是额外的好处，因为它们在超出范围时会自动关闭。

于 2009-05-02T01:25:57.370 回答
1

这将起作用并且不会产生错误...

 print {*CHECK} Data::Dumper->Dump(\@a);

这可以防止它被混淆具有“间接对象语法”

但是，我确实建议不要在 Perl 中使用 CHECK 和其他特殊命名的代码块，而对文件句柄使用词法变量是首选方法。PBP

于 2009-05-02T16:44:01.923 回答
1

相比：

> perl -MData::Dumper -e'local*_=*STDOUT;print _ Data::Dumper->Dump([2]);'
Can't locate object method "_" via package "Data::Dumper" at -e line 1.

至

> perl -MData::Dumper -e'local*_=*STDOUT;print _ ( Data::Dumper->Dump([2]) );'
$VAR1 = 2;

我使用了与“STDOUT”不同的名称，因为它似乎只在间接对象不是内置句柄时才会出错。

于 2009-05-02T00:29:11.250 回答