50

我有一个架构，它有 6 种不同类型的实体，但它们都有很多共同点。我想我可能可以在类型级别抽象出很多这种共性，但是我遇到了 HaskellDB 和重叠实例的问题。这是我开始使用的代码，效果很好：

import Database.HaskellDB
import Database.HaskellDB.DBLayout

data Revision a = Revision deriving Eq
data Book = Book

instance FieldTag (Revision a) where
  fieldName _ = "rev_id"

revIdField :: Attr (Revision Book) (Revision Book)
revIdField = mkAttr undefined

branch :: Table (RecCons (Revision Book) (Expr (Revision Book)) RecNil)
branch = baseTable "branch" $ hdbMakeEntry undefined
bookRevision :: Table (RecCons (Revision Book) (Expr (Revision Book)) RecNil)
bookRevision = baseTable "book_revision" $ hdbMakeEntry undefined

masterHead :: Query (Rel (RecCons (Revision Book) (Expr (Revision Book)) RecNil))
masterHead = do
  revisions <- table bookRevision
  branches <- table branch
  restrict $ revisions ! revIdField .==. branches ! revIdField
  return revisions

这很好用，但是branch太具体了。我真正想表达的是：

branch :: Table (RecCons (Revision entity) (Expr (Revision entity)) RecNil)
branch = baseTable "branch" $ hdbMakeEntry undefined

但是，通过此更改，我收到以下错误：

Overlapping instances for HasField
                            (Revision Book)
                            (RecCons (Revision entity0) (Expr (Revision entity0)) RecNil)
  arising from a use of `!'
Matching instances:
  instance [overlap ok] HasField f r => HasField f (RecCons g a r)
    -- Defined in Database.HaskellDB.HDBRec
  instance [overlap ok] HasField f (RecCons f a r)
    -- Defined in Database.HaskellDB.HDBRec
(The choice depends on the instantiation of `entity0'
 To pick the first instance above, use -XIncoherentInstances
 when compiling the other instance declarations)
In the second argument of `(.==.)', namely `branches ! revIdField'
In the second argument of `($)', namely
  `revisions ! revIdField .==. branches ! revIdField'
In a stmt of a 'do' expression:
      restrict $ revisions ! revIdField .==. branches ! revIdField

我试过盲目地抛出-XOverlappingInstances和-XIncoherentInstances，但这没有帮助（我想真正理解为什么用类型变量替换具体类型会导致问题如此严重）。

任何帮助和建议将不胜感激！

4

1 回答 1

2

随着这个问题的年龄，答案可能为时已晚，无法对您产生任何影响，但也许如果其他人遇到类似的问题......

这归结为这样一个事实，即无法推断您想要entity引用Bookwhenbranch用于masterHead. 读取的错误消息部分

选择取决于“entity0”的实例化

告诉您需要在哪里消除歧义，特别是您需要提供更多关于entity0应该是什么的信息。您可以提供一些类型注释来帮助解决问题。

首先，定义branch为

type BranchTable entity = Table (RecCons (Revision entity) (Expr (Revision entity)) RecNil)
branch :: BrancTable entity
branch = baseTable "branch" $ hdbMakeEntry undefined

然后masterHead改为阅读

masterHead :: Query (Rel (RecCons (Revision Book) (Expr (Revision Book)) RecNil))
masterHead = do
  revisions <- table bookRevision
  branches <- table (branch :: BranchTable Book)
  restrict $ revisions ! revIdField .==. branches ! revIdField
  return revisions

请注意应用于branch:的类型注释，branch :: BranchTable Book它用于消除导致类型错误的歧义。

要使其masterHead适用于其中包含Revision e字段的任何内容，您可以使用以下定义：

masterHead :: (ShowRecRow r, HasField (Revision e) r) => Table r -> e -> Query (Rel r)
masterHead revTable et =
  do  revisions <- table revTable
      branches <- table branch'
      restrict $ revisions ! revIdField' .==. branches ! revIdField'
      return revisions
  where (branch', revIdField') = revBundle revTable et
        revBundle :: HasField (Revision e) r => Table r -> e -> (BranchTable e, Attr (Revision e) (Revision e))
        revBundle table et = (branch, revIdField)

需要该et参数来指定e类型应该是什么，并且可以undefined归因于正确的类型，如

masterHead bookRevision (undefined :: Book)

生成 SQL

SELECT rev_id1 as rev_id
FROM (SELECT rev_id as rev_id2
      FROM branch as T1) as T1,
     (SELECT rev_id as rev_id1
      FROM book_revision as T1) as T2
WHERE rev_id1 = rev_id2

虽然这确实需要FlexibleContexts，但它可以应用于询问者的模块而无需重新编译 HaskellDB。

于 2012-07-09T06:34:22.150 回答