10

我要做的是创建一种查看（而不是编辑）包含在项目中的 HTML 页面的能力。欢迎页面已经嵌入了网络浏览器，因此它似乎是一个很好的选择。

古玩为什么？这是一个带有背景信息的问题。

4

3 回答 3

26

这是我专门为您制定的解决方案...

在此处输入图像描述

从这里下载源代码，在 Delphi 中提取并加载包（我在 Delphi XE 中制作，但它会在任何版本中加载！不过，您需要在 XE 之前的版本中更改 Project Options 中的 Unit Output 路径） ...安装软件包。

在帮助菜单中，找到创建浏览器并单击它。然后，这将创建并显示一个导航到我的博客的选项卡（出于示例的目的）。

您可以轻松修改它以满足您的需求！帮助菜单项代码位于 中EditWizard.MenuItem.pas，可以忽略！请注意，单击 to 时(BorlandIDEServices as IOTAEditorViewServices).ShowEditorView(CreateTab('http://www.simonjstuart.com'));它正在调用，这实际上是创建浏览器选项卡实例的原因！

浏览器选项卡的所有代码（包括其框架布局）都包含在 中EditorWizard.Frame.pas，这使得修改以满足您的需要非常容易！

该单元EditorWizard.Wizard.pas包含将自定义浏览器选项卡注册到 IDE 所需的少量代码。

当然，您需要进行一些调整，但这肯定可以作为您尝试做的事情的一个非常可接受的基础。

享受 ：）

于 2011-11-30T20:19:46.817 回答
8

如果你愿意使用这样的黑客：

type
  TOpenNewURLModule = procedure(const URL: string; EditorForm: TCustomForm);

procedure OpenURL(const URL: string);
var
  EditWindow: INTAEditWindow;
  Lib: HMODULE;
  OpenNewURLModule: TOpenNewURLModule;
begin
  EditWindow := (BorlandIDEServices as INTAEditorServices).TopEditWindow;
  if not Assigned(EditWindow) or not Assigned(EditWindow.Form) then
    Exit;

  Lib := GetModuleHandle('startpageide150.bpl');
  if Lib = 0 then
    Exit;
  OpenNewURLModule := GetProcAddress(Lib, '@Urlmodule@OpenNewURLModule$qqrx20System@UnicodeStringp22Editorform@TEditWindow');
  if @OpenNewURLModule <> nil then
    OpenNewURLModule(URL, EditWindow.Form);
end;

缺点：

  • 这是一个 hack（startpageidexx.bpl 没有通过 API 公开或记录）
  • 它是为 Delphi XE 硬编码的（对于其他版本，您需要不同的文件名，方法签名也可能不同 - 例如在旧的 AnsiString 版本中）
  • 如果没有编辑窗口，它什么也不做（必须至少有一个打开的模块）
  • 它总是打开一个新的浏览器视图

编辑：似乎可以重用现有打开的欢迎页面，并使此 hack 与旧版本的 Delphi 兼容。下面显示了两个替代方案，Delphi XE 和 Delphi 2007（似乎都在工作）：

type
  IURLModule = interface(IOTAModuleData)
  ['{9D215B02-6073-45DC-B007-1A2DBCE2D693}']
    function GetURL: string;
    procedure SetURL(const URL: string);
    property URL: string read GetURL write SetURL;
  end;
  TOpenNewURLModule = procedure(const URL: string; EditorForm: TCustomForm);

function FindURLModule: IURLModule;
var
  I: Integer;
begin
  Result := nil;
  with BorlandIDEServices as IOTAModuleServices do
    for I := 0 to ModuleCount - 1 do
      if Supports(Modules[I], IURLModule, Result) then
        Break;
end;

procedure OpenURL(const URL: string; ReuseExistingView: Boolean = True);
{$IFDEF VER220} // Delphi XE
const
  SStartPageIDE = 'startpageide150.bpl';
  SOpenNewURLModule = '@Urlmodule@OpenNewURLModule$qqrx20System@UnicodeStringp22Editorform@TEditWindow';
{$ENDIF}
{$IFDEF VER185} // Delphi 2007
const
  SStartPageIDE = 'startpageide100.bpl';
  SOpenNewURLModule = '@Urlmodule@OpenNewURLModule$qqrx17System@AnsiStringp22Editorform@TEditWindow';
{$ENDIF}
var
  Module: IURLModule;
  EditWindow: INTAEditWindow;
  Lib: HMODULE;
  OpenNewURLModule: TOpenNewURLModule;
begin
  EditWindow := nil;
  Module := nil;
  if ReuseExistingView then
    Module := FindURLModule;
  if Assigned(Module) then
  begin
    Module.URL := URL;
    (Module as IOTAModule).Show;
  end
  else
  begin
{$IFDEF VER220}
    EditWindow := (BorlandIDEServices as INTAEditorServices).TopEditWindow;
{$ENDIF}
{$IFDEF VER185}
  if Assigned((BorlandIDEServices as IOTAEditorServices).TopView) then
    EditWindow := (BorlandIDEServices as IOTAEditorServices).TopView.GetEditWindow;
{$ENDIF}
    if not Assigned(EditWindow) or not Assigned(EditWindow.Form) then
      Exit;
    Lib := GetModuleHandle(SStartPageIDE);
    if Lib = 0 then
      Exit;

    OpenNewURLModule := GetProcAddress(Lib, SOpenNewURLModule);
    if @OpenNewURLModule <> nil then
      OpenNewURLModule(URL, EditWindow.Form);
  end;
end;

剩下的缺点：

  • 它仍然是一个黑客
  • 对于 Delphi XE (Unicode) 和 Delphi 2007 (ANSI)，它仍然是硬编码的
  • 如果没有编辑窗口，它仍然什么都不做

如果您需要其他版本的兼容性，也许您可​​以使用它作为开始。

于 2011-11-29T11:38:36.613 回答
3

您最好在其上显示您自己TForm的TWebBrowser组件，您可以将 HTML 加载到其中。

于 2011-11-10T01:42:43.743 回答