4

我正在尝试对 XML 文档进行转换。根据某个元素的值，我的 XML 转换可能会产生两种不同类型的基本元素：

<xsl:template match="/">
  <xsl:choose>
    <xsl:when test="/databean/data[@id='pkhfeed']/value/text()='200'">
      <xsl:call-template name="StructureA">
        <xsl:with-param name="structure" select="//databean" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="StructureB">
        <xsl:with-param name="structure" select="//databean" />
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

然后使用自己的命名空间和 schemaLocations 创建 StructureA 或 StructureB：

<StructureA xmlns="http://...">

StructureA 和 B 共享一些公共元素，因此这些元素在一个名为“xmlcommon.xslt”的单独文件中定义，这两个结构都包含来自其中的模板。这个 xmlcommon 文件没有定义默认命名空间，因为我希望它可以从 StructureA 或 StructureB 中定义的命名空间中使用。但是当我运行我的转换时，从公共文件中提取的任何模板都会导致空白 xmlns 属性：

<StructureA xmlns="http://...">
  <SharedElement xmlns="">Something</SharedElement>
</StructureA>

验证时，然后使用空白命名空间而不是正确的父命名空间。 有谁知道如何阻止我的通用文件中的模板添加那些空白的 xmlns 属性？

这是来自公共文件的片段：

<xsl:stylesheet version="1.0" xmlns:fn="http://www.w3.org/2005/02/xpath-functions" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template name="ControlledListStructure">
    <xsl:param name="xmlElem" />
    <xsl:param name="structure" />

    <xsl:element name="{$xmlElem}">
      <!-- Blah blah blah -->
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>
4

1 回答 1

9

要意识到的关键是您的样式表规定了您添加到结果树中的每个元素的名称。元素的名称有两部分：本地名称和命名空间 URI。在上面的代码中，您提供了本地名称（ 的值$xmlElem），但您没有指定命名空间 URI，这意味着它将默认为空字符串。（实际上，它采用该样式表模块的默认命名空间；因为没有，所以它是空字符串。）换句话说，该元素将不在命名空间中。序列化文档时，XSLT 处理器必须包含xmlns=""取消声明以取消声明出现在顶部的默认命名空间。否则，该元素将采用该名称空间，这不是您的样式表所规定的。解决此问题的最少侵入性方法是添加另一个参数（例如$namespaceURI），就像您使用$xmlElem. 然后你会写：

<xsl:element name="{$xmlElem}" namespace="{$namespaceURI}">

现在，生成的元素将采用您告诉它采用的任何命名空间（这将具有删除那些默认命名空间取消声明的效果）。

那应该回答你的问题。我提供以下免费奖励材料。;-)

您应该在值比较中删除text()节点测试。您很少需要直接比较文本节点的值。相反，您可以只比较元素本身的字符串值（定义为其所有后代文本节点的字符串值的串联）。看起来像这样：

<xsl:when test="/databean/data[@id='pkhfeed']/value = '200'">

这样做的好处是，如果其中隐藏了注释，您的代码不会中断：

<value>2<!--test-->00</value>

在这种情况下，有两个文本节点（“2”和“00”）。您的原始测试将失败，因为它会检查其中是否有任何一个等于“200”。在这种情况下不太可能发生，但无论如何测试元素的字符串值（而不是其文本节点子节点）是一种很好的做法，如果这是您的意图。

最后，我鼓励您了解模板规则和 XPath 上下文。我倾向于避免<xsl:choose>, <xsl:call-template>, 和<xsl:with-param>尽可能。一方面，模板规则可以帮助您避免 XSLT 中许多丑陋、冗长的部分。

<xsl:template match="/databean[data[@id='pkhfeed']/value = '200']" priority="1">
  <StructureA xmlns="http://...">
    ...
  </StructureA>
</xsl:template>

<xsl:template match="/databean">
  <StructureB xmlns="http://...">
    ...
  </StructureB>
</xsl:template>

即使您继续使用<xsl:call-template>，也不必传递该$structure参数，因为当前节点在被调用模板中将保持不变。您可以从您的或模板中轻松访问//databean（或/databean，我怀疑这是您的意思），因为当前节点仍将是“/”（文档节点）。StructureAStructureB

如果您有兴趣进一步了解 XSLT 的核心处理模型及其最强大的特性（模板规则），那么我鼓励您查看“XSLT 工作原理” ，这是我的XSLT 1.0 袖珍参考中的免费示例章节。

我希望这对您有所帮助，即使它超出了您的预期！

于 2009-04-30T07:23:03.583 回答