15

在 SAS 中删除表的最有效方法是什么？

我有一个程序循环和丢弃大量表，想知道PROC SQL之间是否存在性能差异；和过程数据集；一次删除一个表..

或者如果有另一种方式也许？？？

4

6 回答 6

16

如果外包给操作系统是合理的，那可能是最快的。否则，我的不科学观察似乎表明 drop table inproc sql是最快的。这让我感到惊讶，因为我预计proc datasets会是最快的。

在下面的代码中，我创建了 4000 个虚拟数据集，然后尝试使用不同的方法将它们全部删除。第一个是使用 sql，在我的系统上删除文件大约需要 11 秒。

接下来的两个都使用proc datasets. 首先为每个数据集创建一个删除语句，然后删除。第二个只是发出一个全面的 kill 命令来删除工作目录中的所有内容。（我曾期望这种技术是最快的）。两个 proc 数据集例程都报告了大约 20 秒来删除所有 4000 个文件。

%macro create;
proc printto log='null';run;
%do i=1 %to 4000;
data temp&i;
x=1;
y="dummy";
output;run;
%end;
proc printto;run;
%mend;

%macro delsql;
proc sql;
%do i=1 %to 4000;
drop table temp&i;
%end;
quit;
%mend;

%macro deldata1;
proc datasets library=work nolist;
   %do i=1 %to 4000;
   delete temp&i.;
   %end;
run;quit;
%mend;

%macro deldata2;
proc datasets library=work kill;
run;quit;
%mend;

option fullstimer;
%create;
%delsql;

%create;
%deldata1;

%create;
%deldata2;
于 2009-04-29T14:24:25.277 回答
5

我试图摆弄操作系统删除方法。

不推荐使用 X 命令删除。它花了很长时间！

然后我尝试在数据步骤中使用系统命令：

%macro delos;
data _null_;
do i=1 to 9;
delcmd="rm -f "!!trim(left(pathname("WORK","L")))!!"/temp"!!trim(left(put(i,4.)))!!"*.sas7*";
rc=system(delcmd);
end;
run;
%mend;

如您所见，我必须将删除操作拆分为 9 个单独的删除命令。原因是，我使用通配符“*”，而底层操作系统 (AIX) 将它们扩展为一个列表，然后它变得太大而无法处理......

该程序基本上为九个文件组“temp[1-9]*.sas7*”中的每一个构造一个删除命令并发出该命令。

使用 cmjohns answer 中的 create 宏函数创建 4000 个数据表，我可以使用这种方法在 5 秒内删除它们。

因此，正如我所料，直接删除操作系统是批量删除的最快方式。

于 2009-04-30T13:22:04.717 回答
3

我们在讨论表还是数据集？

表意味着数据库表。要快速摆脱这些，使用 proc SQL 传递工具将是最快的。特别是如果您可以连接到数据库一次并删除所有表，然后断开连接。

如果我们讨论 SAS 中的数据集，我认为 proc sql 和 proc 数据集都非常相似。从应用程序的角度来看，它们都通过相同的推论来创建删除文件的系统命令。我从 SAS 用户组或演示文稿中看到的所有测试都表明，使用一种方法而不是另一种方法是微不足道的，并且基于许多变量。

如果您必须拥有绝对最快的方法来删除数据集/表，您可能只需要对其进行测试。SAS 的每次安装和设置都不同，足以保证测试。

于 2009-04-29T18:23:28.870 回答
3

就哪个更快而言，不包括非常大的数据，我敢打赌它们之间几乎没有区别。然而，在处理永久 SAS 数据集时，我更喜欢使用 PROC DATASETS 而不是 PROC SQL，只是因为我觉得使用 SAS 设计的方法而不是 SQL 实现更好地处理永久数据集

于 2012-07-12T07:44:50.147 回答
3

类似命名的临时表的简单解决方案：

如果所有表都以相同的前缀开头，例如 p1_table1 和 p1_table2，则以下代码将删除以 p1 开头的任何表

proc datasets; delete p1: ; run;

于 2014-05-13T15:34:16.797 回答
2

proc delete 是另一种解决方案，尽管没有记录。

http://www.sascommunity.org/wiki/PROC_Delete

于 2009-12-08T11:31:06.670 回答