0

我有一个 NetCDF 文件，其中包含代表全球几个月内总降水量的数据（因此它存储在一个三维数组中）。我首先在 XConv 和 ncdump 中确保数据是合理的，以及它的形成方式。一切看起来都很合理 - 值从非常小（~10^-10 - 这是有道理的，因为这是模型数据，并且有效地表示零）到大约 5x10^-3 不等。

当我尝试在 IDL 或 MatLab 中处理这些数据时，问题就开始了。在这些程序中生成的数组充满了巨大的负数，例如 -4x10^4，偶尔还有巨大的正数，例如 5000。奇怪的是，在 MatLab 中查看数据关于经纬度的图（在特定时间），降雨模式看起来很合理，但数值完全错误。

在 IDL 中，我正在读取文件以将其写入文本文件，因此它可以由一些采用非常基本的文本文件的软件处理。这是我正在使用的代码：

PRO nao_heaps

address = '/Users/levyadmin/Downloads/'
file_base = 'output'
ncid = ncdf_open(address + file_base + '.nc')

MONTHS=['january','february','march','april','may','june','july','august','september','october','november','december']

varid_field = ncdf_varid(ncid, "tp")
varid_lon = ncdf_varid(ncid, "longitude")
varid_lat = ncdf_varid(ncid, "latitude")
varid_time = ncdf_varid(ncid, "time")

ncdf_varget,ncid, varid_field, total_precip
ncdf_varget,ncid, varid_lat, lats
ncdf_varget,ncid, varid_lon, lons
ncdf_varget,ncid, varid_time, time

ncdf_close,ncid

lats = reform(lats)
lons = reform(lons)
time = reform(time)
total_precip = reform(total_precip)
total_precip = total_precip*1000. ;put in mm

noLats=(size(lats))(1)
noLons=(size(lons))(1)
noMonths=(size(time))(1)

; the data may not be an integer number of years (otherwise we could make this next loop cleaner)
av_precip=fltarr(noLons,noLats,12)
for month=0, 11 do begin
  year = 0
  while ( (year*12) + month lt noMonths ) do begin
    av_precip(*,*,month) = av_precip(*,*,month) + total_precip(*,*, (year*12)+month )
    year++
  endwhile
  av_precip(*,*,month) = av_precip(*,*,month)/year
endfor

fname = address + file_base + '.dat'
OPENW,1,fname
PRINTF,1,'longitude'
PRINTF,1,lons

PRINTF,1,'latitude'
PRINTF,1,lats

for month=0,11 do begin
  PRINTF,1,MONTHS(month)
  PRINTF,1,av_precip(*,*,month)
endfor


CLOSE,1

END

任何人都知道为什么我在 MatLab和IDL 中得到如此奇怪的值？！

4

1 回答 1

1

啊！找到了答案。NetCDF 文件使用偏移量和数据比例因子来将文件大小保持在最小。要获得正确的值，我只需要：

total_precip = offset + (scale_factor * total_precip) ;put into correct range

目前我正在从 ncdump 获取比例因子和偏移量，并将它们硬编码到我的 IDL 程序中，但是有谁知道我如何在我的 IDL 代码中动态获取它们..？

于 2011-11-04T14:27:46.730 回答