batch-file - 显示 Windows 命令提示符输出并将其重定向到文件

Question

如何在 Windows 命令提示符下运行命令行应用程序并同时显示输出并重定向到文件？

例如，如果我要运行 command dir > test.txt，这会将输出重定向到一个名为test.txt而不显示结果的文件。

我如何编写一个命令来显示输出并将输出重定向到 Windows 命令提示符中的文件，类似于teeUnix 上的命令？

score 194 · Accepted Answer

要扩展davor 的答案，您可以像这样使用 PowerShell：

powershell "dir | tee test.txt"

如果您尝试重定向当前目录中 exe 的输出，则需要.\在文件名上使用，例如：

powershell ".\something.exe | tee test.txt"

score 142 · Accepted Answer

我能够找到将输出重定向到文件然后到控制台的解决方案/解决方法：

dir > a.txt | type a.txt

其中dir是需要重定向输出的命令，a.txt是存储输出的文件。

score 106 · Accepted Answer

Unix 命令有一个 Win32 端口，tee正是这样做的。请参阅http://unxutils.sourceforge.net/或http://getgnuwin32.sourceforge.net/

score 58 · Accepted Answer

看看这个：温蒂

不需要cygwin。

我确实遇到并报告了一些问题。

您也可以检查unxutils，因为它包含 tee（并且不需要 cygwin），但请注意输出 EOL 在这里类似于 UNIX。

最后但同样重要的是，如果你有 PowerShell，你可以试试 Tee-Object。键入get-help tee-objectPowerShell 控制台以获取更多信息。

score 50 · Accepted Answer

@tori3852

我找到

dir > a.txt | type a.txt

没有工作（仅目录列表的前几行 - 怀疑某种进程分叉和第二部分，'type' 命令在可怕的列表完成之前终止？），所以我使用了：

dir > z.txt && type z.txt

确实如此 - 顺序命令，一个在第二个开始之前完成。

score 27 · Accepted Answer

不幸的是，没有这样的事情。

Windows 控制台应用程序只有一个输出句柄。（嗯，有两个STDOUT，STDERR但在这里没关系）>将通常写入控制台句柄的输出重定向到文件句柄。

如果您想进行某种多路复用，则必须使用可以将输出转移到的外部应用程序。然后，此应用程序可以写入文件并再次写入控制台。

score 24 · Accepted Answer

一个简单的 C# 控制台应用程序就可以解决问题：

using System;
using System.Collections.Generic;
using System.IO;

namespace CopyToFiles
{
    class Program
    {
        static void Main(string[] args)
        {
            var buffer = new char[100];
            var outputs = new List<TextWriter>();

            foreach (var file in args)
                outputs.Add(new StreamWriter(file));

            outputs.Add(Console.Out);

            int bytesRead;
            do
            {
                bytesRead = Console.In.ReadBlock(buffer, 0, buffer.Length);
                outputs.ForEach(o => o.Write(buffer, 0, bytesRead));
            } while (bytesRead == buffer.Length);

            outputs.ForEach(o => o.Close());
        }
    }
}

要使用它，您只需将源命令通过管道传输到程序中，并提供要将输出复制到的任何文件的路径。例如：

dir | CopyToFiles files1.txt files2.txt

将显示 dir 的结果并将结果存储在 files1.txt 和 files2.txt 中。

请注意，上面的错误处理方式并不多（任何东西！），实际上可能不需要支持多个文件。

score 21 · Accepted Answer

这可行，虽然它有点难看：

dir >_ && type _ && type _ > a.txt

它比其他一些解决方案更灵活一点，因为它可以逐语句工作，因此您也可以使用它来追加。我在批处理文件中经常使用它来记录和显示消息：

ECHO Print line to screen and log to file.  >_ && type _ && type _ >> logfile.txt

是的，您可以重复 ECHO 语句（一次用于屏幕，第二次重定向到日志文件），但这看起来同样糟糕，并且有点维护问题。至少这样您就不必在两个地方对消息进行更改。

请注意，_ 只是一个短文件名，因此您需要确保在批处理文件的末尾删除它（如果您使用的是批处理文件）。

score 19 · Accepted Answer

我想稍微扩展一下 Saxon Druce 的出色回答。

如前所述，您可以像这样重定向当前目录中可执行文件的输出：

powershell ".\something.exe | tee test.txt"

但是，这仅记录stdout到test.txt. 它也不记录stderr。

显而易见的解决方案是使用这样的东西：

powershell ".\something.exe 2>&1 | tee test.txt"

但是，这不适用于所有something.exes。有些something.exes 会将 the 解释2>&1为参数并失败。正确的解决方案是只在 thesomething.exe及其开关和参数周围加上撇号，如下所示：

powershell ".\something.exe --switch1 --switch2 … arg1 arg2 …&quot; 2^>^&1 ^| tee test.txt

但请注意，在这种情况下，您必须转义特殊的 cmd-shell 字符“>&|” 每个都有一个“^”，所以它们只能由 powershell 解释。

score 18 · Accepted Answer

mtee 是一个小型实用程序，非常适合此目的。它是免费的，源代码是开放的，而且它可以正常工作。

您可以在 http://www.commandline.co.uk找到它。

在批处理文件中用于显示输出并同时创建日志文件，语法如下所示：

    someprocess | mtee /+ mylogfile.txt

其中 /+ 表示追加输出。

当然，这假定您已将 mtee 复制到 PATH 中的文件夹中。

score 10 · Accepted Answer

我同意 Brian Rasmussen 的观点，unxutils 端口是最简单的方法。在他的脚本页面的批处理文件部分，Rob van der Woude 提供了大量有关使用 MS-DOS 和 CMD 命令的信息。我认为他可能对您的问题有一个本机解决方案，在那里挖掘后我发现了 TEE.BAT，这似乎就是 tee 的 MS-DOS 批处理语言实现。这是一个看起来很复杂的批处理文件，我仍然倾向于使用 unxutils 端口。

score 10 · Accepted Answer

10

如果您的 Windows 环境路径中有 cygwin，则可以使用：

 dir > a.txt | tail -f a.txt

于 2014-05-16T13:12:25.640 回答

score 8 · Accepted Answer

8

dir 1>a.txt 2>&1 | type a.txt

这将有助于重定向 STDOUT 和 STDERR

于 2011-11-02T15:23:07.303 回答

score 6 · Accepted Answer

我知道这是一个非常古老的话题，但是在以前的答案中，并没有完整实现以批处理方式编写的实时 Tee。我下面的解决方案是一个 Batch-JScript 混合脚本，它使用 JScript 部分只是为了从管道命令中获取输出，但是数据的处理是在 Batch 部分中完成的。这种方法的优点是任何 Batch 程序员都可以修改该程序以满足特定需求。该程序还正确处理其他批处理文件产生的CLS命令输出，即在检测到CLS命令输出时清除屏幕。

@if (@CodeSection == @Batch) @then


@echo off
setlocal EnableDelayedExpansion

rem APATee.bat: Asynchronous (real time) Tee program, Batch-JScript hybrid version
rem Antonio Perez Ayala

rem The advantage of this program is that the data management is written in Batch code,
rem so any Batch programmer may modify it to fit their own needs.
rem As an example of this feature, CLS command is correctly managed

if "%~1" equ "" (
   echo Duplicate the Stdout output of a command in the screen and a disk file
   echo/
   echo anyCommand ^| APATee teeFile.txt [/A]
   echo/
   echo If /A switch is given, anyCommand output is *appended* to teeFile.txt
   goto :EOF
)

if "%2" equ ":TeeProcess" goto TeeProcess

rem Get the output of CLS command
for /F %%a in ('cls') do set "cls=%%a"

rem If /A switch is not provided, delete the file that receives Tee output
if /I "%~2" neq "/A" if exist %1 del %1

rem Create the semaphore-signal file and start the asynchronous Tee process
echo X > Flag.out
if exist Flag.in del Flag.in
Cscript //nologo //E:JScript "%~F0" | "%~F0" %1 :TeeProcess
del Flag.out
goto :EOF

:TeeProcess
   rem Wait for "Data Available" signal
   if not exist Flag.in goto TeeProcess
   rem Read the line sent by JScript section
   set line=
   set /P line=
   rem Set "Data Read" acknowledgement
   ren Flag.in Flag.out
   rem Check for the standard "End Of piped File" mark
   if "!line!" equ ":_EOF_:" exit /B
   rem Correctly manage CLS command
   if "!line:~0,1!" equ "!cls!" (
      cls
      set "line=!line:~1!"
   )
   rem Duplicate the line in Stdout and the Tee output file
   echo(!line!
   echo(!line!>> %1
goto TeeProcess


@end


// JScript section

var fso = new ActiveXObject("Scripting.FileSystemObject");
// Process all lines of Stdin
while ( ! WScript.Stdin.AtEndOfStream ) {
   // Read the next line from Stdin
   var line = WScript.Stdin.ReadLine();
   // Wait for "Data Read" acknowledgement
   while ( ! fso.FileExists("Flag.out") ) {
      WScript.Sleep(10);
   }
   // Send the line to Batch section
   WScript.Stdout.WriteLine(line);
   // Set "Data Available" signal
   fso.MoveFile("Flag.out", "Flag.in");
}
// Wait for last "Data Read" acknowledgement
while ( ! fso.FileExists("Flag.out") ) {
      WScript.Sleep(10);
}
// Send the standard "End Of piped File" mark
WScript.Stdout.WriteLine(":_EOF_:");
fso.MoveFile("Flag.out", "Flag.in");

score 5 · Accepted Answer

我也在寻找相同的解决方案，经过一番尝试，我成功地在命令提示符中实现了这一点。这是我的解决方案：

@Echo off
for /f "Delims=" %%a IN (xyz.bat) do (
%%a > _ && type _ && type _ >> log.txt
)
@Echo on

它甚至还可以捕获任何 PAUSE 命令。

score 4 · Accepted Answer

这是我根据其他答案之一使用的示例

@echo off
REM SOME CODE
set __ERROR_LOG=c:\errors.txt
REM set __IPADDRESS=x.x.x.x

REM Test a variable
if not defined __IPADDRESS (
     REM Call function with some data and terminate
     call :TEE %DATE%,%TIME%,IP ADDRESS IS NOT DEFINED
     goto :EOF
)

REM If test happens to be successful, TEE out a message and end script.
call :TEE Script Ended Successful
goto :EOF


REM THE TEE FUNCTION
:TEE
for /f "tokens=*" %%Z in ("%*") do (
     >  CON ECHO.%%Z
     >> "%__ERROR_LOG%" ECHO.%%Z
     goto :EOF
)

score 4 · Accepted Answer

将输出发送到控制台，附加到控制台日志，从当前命令中删除输出

dir  >> usb-create.1 && type usb-create.1 >> usb-create.log | type usb-create.1 && del usb-create.1

score 4 · Accepted Answer

像这样的东西应该做你需要的吗？

%DATE%_%TIME% > c:\a.txt & type c:\a.txt
ipconfig >> c:\a.txt & type c:\a.txt
ping localhost >> c:\a.txt & type c:\a.txt
pause

score 3 · Accepted Answer

就像unix一样。

dir | tee a.txt

可以在 windows XP 上运行，它需要mksnt安装。

它显示在提示符上并附加到文件中。

score 3 · Accepted Answer

这不是另一个答案，而是对已经存在的答案的概述和澄清，例如显示 Windows 命令提示符输出并将其重定向到文件等

我自己发现有一系列问题导致一组 tee 实现在 Windows 中不可靠（Windows 7在我的情况下）。

我需要专门使用 tee 实现，因为已经使用了带有自重定向的批处理脚本：

@echo off

setlocal


... some conditions here ..

rem the redirection
"%COMSPEC%" /C call %0 %* 2>&1 | "<path_to_tee_utililty>" ".log\<log_file_name_with_date_and_time>.%~nx0.log"
exit /b

:IMPL
... here the rest of script ...

如果与 tee 实用程序一起使用，脚本和对脚本内某些实用程序的调用可能会破坏输出。

gnuwin32 实现：

http://gnuwin32.sourceforge.net/packages/coreutils.htm

优点：

正确处理标准输出和控制台进度条，其中\r字符被大量使用。

缺点：

使控制台进度条仅在日志文件中绘制，但在控制台窗口中没有重复或可见。
引发多条错误消息Cwrite error: No such file or directory，因为 cmd 解释器似乎过早关闭管道/标准输出，并且此后无法自行关闭（垃圾邮件直到终止）。
不在控制台窗口中复制/打印pause命令 ( ) 的输出。Press any key to continue...

wintee 实施：

https://code.google.com/archive/p/wintee/

https://github.com/rbuhl/wintee

优点：

在控制台窗口和日志文件（多次打印）中显示控制台进度条。
是否在控制台窗口中复制/打印pause命令 ( ) 的输出。Press any key to continue...

缺点：

不正确地处理\r字符，输出混合和混乱（https://code.google.com/archive/p/wintee/issues/7）。
有其他问题：https ://code.google.com/archive/p/wintee/issues

UnxUtils实现：

http://unxutils.sourceforge.net/

https://sourceforge.net/projects/unxutils/files/unxutils/current/

优点

在控制台窗口和日志文件（多次打印）中显示控制台进度条。
正确处理\r角色。
是否在控制台窗口中复制/打印pause命令 ( ) 的输出。Press any key to continue...

缺点

还没找到

ss64.net实现：

http://ss64.net/westlake/nt

http://ss64.net/westlake/nt/tee.zip

优点：

在控制台窗口和日志文件（多次打印）中显示控制台进度条。

缺点：

字符处理不正确\r，输出混杂
出于某种原因，在按键后会在控制台窗口中复制/打印pause命令 ( ) 的输出。Press any key to continue...

ritchielawrence mtee实施：

https://ritchielawrence.github.io/mtee

https://github.com/ritchielawrence/mtee

优点

在控制台窗口和日志文件（多次打印）中显示控制台进度条。
正确处理\r角色。
是否在控制台窗口中复制/打印pause命令 ( ) 的输出。Press any key to continue...
错误代码保留功能 w/oa 需要使用doskey（/E标志，Windows 命令解释器：如何获取第一个管道命令的退出代码）的解决方法

缺点

不支持日志文件路径中的正斜杠字符 ( https://github.com/ritchielawrence/mtee/issues/6 )
有竞争条件问题，当无法提取管道进程退出代码时，因为它在访问之前已经关闭（https://github.com/ritchielawrence/mtee/issues/4）

因此，如果您在上述之间选择 tee 实用程序实现，那么更好的选择是UnxUtilsor mtee。

如果您正在寻找具有更多功能和更少问题的更好实现，那么您可以使用callf实用程序：
https ://github.com/andry81/contools/blob/trunk/Utilities/src/callf/help.tpl

您可以运行而不是：

call test.bat | mtee /E 1.log

这个：

callf.exe /ret-child-exit /tee-stdout 1.log /tee-stdout-dup 1 "" "cmd.exe /c call test.bat"

这样做更好，因为它可以stdout单独进行管道传输stderr，您甚至可以使用命名管道在具有管理员权限隔离的进程之间进行管道传输。

score 3 · Accepted Answer

这是 MTS 先前答案的变体，但它添加了一些可能对其他人有用的功能。这是我使用的方法：

命令被设置为变量，以后可以在整个代码中使用，以输出到命令窗口并附加到日志文件，使用set _Temp_Msg_Cmd=
- 该命令已使用胡萝卜字符转义重定向^，因此最初不会评估命令
使用类似于正在运行的批处理文件的文件名创建一个临时文件，该文件%~n0_temp.txt使用命令行参数扩展语法 %~n0来获取批处理文件的名称。
输出附加到单独的日志文件%~n0_log.txt

以下是命令序列：

输出和错误消息被发送到临时文件^> %~n0_temp.txt 2^>^&1
临时文件的内容是：
- 附加到日志文件^& type %~n0_temp.txt ^>^> %~n0_log.txt
- 输出到命令窗口^& type %~n0_temp.txt
带有消息的临时文件被删除^& del /Q /F %~n0_temp.txt

这是示例：

set _Temp_Msg_Cmd= ^> %~n0_temp.txt 2^>^&1 ^& type %~n0_temp.txt ^>^> %~n0_log.txt ^& type %~n0_temp.txt ^& del /Q /F %~n0_temp.txt

这样，命令可以简单地附加在批处理文件中的后续命令之后，看起来更干净：

echo test message %_Temp_Msg_Cmd%

这也可以添加到其他命令的末尾。据我所知，当消息有多行时它会起作用。例如，如果有错误消息，以下命令会输出两行：

net use M: /D /Y %_Temp_Msg_Cmd%

score 1 · Accepted Answer

我使用带有“for”语句的批处理子例程来一次获取一行命令输出，并将该行写入文件并将其输出到控制台。

@echo off
set logfile=test.log

call :ExecuteAndTee dir C:\Program Files

Exit /B 0

:ExecuteAndTee
setlocal enabledelayedexpansion
echo Executing '%*'
  for /f "delims=" %%a in ('%* 2^>^&1') do (echo.%%a & echo.%%a>>%logfile%)
endlocal
Exit /B 0

score 1 · Accepted Answer

@echo on

set startDate=%date%
set startTime=%time%

set /a sth=%startTime:~0,2%
set /a stm=1%startTime:~3,2% - 100
set /a sts=1%startTime:~6,2% - 100


fullprocess.bat > C:\LOGS\%startDate%_%sth%.%stm%.%sts%.LOG | fullprocess.bat

这将使用当前日期时间创建一个日志文件，您可以在此过程中使用控制台行

score 1 · Accepted Answer

我刚刚找到了一种使用 perl 作为替代方案的方法，例如：

CMD1 | perl -ne "print $_; print STDERR $_;" 2> OUTPUT.TEE

score 1 · Accepted Answer

如果你在 CLI 上，为什么不使用 FOR 循环来“做”任何你想做的事情：

for /F "delims=" %a in ('dir') do @echo %a && echo %a >> output.txt

用于循环的 Windows CMD 上的大量资源：https ://ss64.com/nt/for_cmd.html 这里的关键是将分隔符（delims）设置为空，这将分解每一行输出。这样它就不会破坏默认的空白。%a 是一个任意字母，但它在“do”部分中用于，嗯……对每行解析的字符做一些事情。在这种情况下，我们可以使用与号 (&&) 执行第二个 echo 命令来创建或附加 (>>) 到我们选择的文件。如果在写入文件时出现问题，为了更安全地保持 DO 命令的顺序，我们至少会首先将回显发送到控制台。第一个回显前面的 at 符号 (@) 禁止控制台显示回显命令本身，而是仅显示命令的结果，即在 %a 中显示字符。否则你会看到：

echo 驱动器 [x] 中的
卷是 Windows 驱动器 [x] 中的卷是 Windows

更新： /F 跳过空白行，唯一的解决方法是预先过滤输出，在每一行中添加一个字符（可能通过命令 find 使用行号）。在 CLI 中解决这个问题并不快也不漂亮。另外，我没有包含 STDERR，所以这里也捕获错误：

for /F "delims=" %a in ('dir 2^>^&1') do @echo %a & echo %a >> output.txt

重定向错误消息

插入符号 (^) 用于对它们后面的符号进行转义，因为该命令是一个正在被解释的字符串，而不是直接在命令行上输入它。

score 0 · Accepted Answer

如何显示输出并将输出重定向到文件。假设如果我使用 dos 命令 dir > test.txt ，该命令会将输出重定向到文件 test.txt 而不显示结果。如何编写命令以显示输出并将输出重定向到使用 DOS 即 windows 命令提示符的文件，而不是在 UNIX/LINUX 中。

您可能会在 biterscripting ( http://www.biterscripting.com ) 中发现这些命令很有用。

var str output
lf > $output
echo $output                            # Will show output on screen.
echo $output > "test.txt"               # Will write output to file test.txt.
system start "test.txt"                 # Will open file test.txt for viewing/editing.

score 0 · Accepted Answer

这可以实时工作，但也很丑陋，性能也很慢。也没有经过很好的测试：

@echo off
cls
SET MYCOMMAND=dir /B
ECHO File called 'test.bat' > out.txt
for /f "usebackq delims=" %%I in (`%MYCOMMAND%`) do (
  ECHO %%I
  ECHO %%I >> out.txt
) 
pause

score 0 · Accepted Answer

另一种方法是在您的程序中将标准输出转换为标准错误：

在java中：

System.setOut(new PrintStream(new TeeOutputStream(System.out, System.err)));

然后，在您的 dos 批处理文件中：java program > log.txt

标准输出将转到日志文件，标准错误（相同数据）将显示在控制台上。

score 0 · Accepted Answer

如果您希望在屏幕上真正看到某些内容，则以下操作会有所帮助 - 即使批处理文件被重定向到文件。如果重定向到文件，也可以使用设备 CON

例子：

ECHO first line on normal stdout. maybe redirected
ECHO second line on normal stdout again. maybe redirected
ECHO third line is to ask the user. not redirected  >CON
ECHO fourth line on normal stdout again. maybe redirected

另请参阅良好的重定向描述： http ://www.p-dd.com/chapter7-page14.html

score 0 · Accepted Answer

我在我的大多数机器上都安装了 perl，所以使用 perl 来回答：tee.pl

my $file = shift || "tee.dat";
open $output, ">", $file or die "unable to open $file as output: $!";
while(<STDIN>)
{
    print $_;
    print $output $_;
}
close $output;

目录 | perl tee.pl 或目录 | perl tee.pl 目录.bat

粗糙且未经测试。

score 0 · Accepted Answer

另一种变体是拆分管道，然后根据需要重新定向输出。

    @echo off
    for /f "tokens=1,* delims=:" %%P in ('findstr /n "^"') do (
      echo(%%Q
      echo(%%Q>&3
    )
    @exit/b %errorlevel%

将以上内容保存到 .bat 文件中。它还将文件流 1 上的文本输出拆分为文件流 3，您可以根据需要对其进行重定向。在下面的示例中，我将上述脚本称为 splitPipe.bat ...

    dir | splitPipe.bat  1>con  2>&1  3>my_stdout.log

    splitPipe.bat 2>nul < somefile.txt

score -1 · Accepted Answer

https://cygwin.com/install
单击“setup-x86_.exe”的链接
运行安装程序
在〜第 2 页上，选择要下载的“镜像”（我查找了 .edu 域）
我对标准选项说好的
Cygwin 快速完成安装
打开命令
键入c:\cygwin64\bin\script.exe并输入
键入cmd并输入
运行你的程序
键入exit并输入（退出 Cygwin 的 cmd.exe）
键入exit并输入（退出 Cygwin 的 script.exe）
在名为“typescript”的文本文件中查看程序的屏幕输出

batch-file - 显示 Windows 命令提示符输出并将其重定向到文件

32 回答 32

Related

Reference