18

你如何gen_udp在 Erlang 中使用多播？我知道它在代码中，它背后没有文档。发送数据显而易见且简单。我想知道如何添加会员。不仅在启动时添加会员资格，而且在运行时添加会员资格也很有用。

4

4 回答 4

15

这是有关如何监听 Bonjour / Zeroconf 流量的示例代码。

-module(zcclient).

-export([open/2,start/0]).
-export([stop/1,receiver/0]).

open(Addr,Port) ->
   {ok,S} = gen_udp:open(Port,[{reuseaddr,true}, {ip,Addr}, {multicast_ttl,4}, {multicast_loop,false}, binary]),
   inet:setopts(S,[{add_membership,{Addr,{0,0,0,0}}}]),
   S.

close(S) -> gen_udp:close(S).

start() ->
   S=open({224,0,0,251},5353),
   Pid=spawn(?MODULE,receiver,[]),
   gen_udp:controlling_process(S,Pid),
   {S,Pid}.

stop({S,Pid}) ->
   close(S),
   Pid ! stop.

receiver() ->
   receive
       {udp, _Socket, IP, InPortNo, Packet} ->
           io:format("~n~nFrom: ~p~nPort: ~p~nData: ~p~n",[IP,InPortNo,inet_dns:decode(Packet)]),
           receiver();
       stop -> true;
       AnythingElse -> io:format("RECEIVED: ~p~n",[AnythingElse]),
           receiver()
   end.
于 2009-11-16T04:36:03.823 回答
11

组播发送已应答，接收需要订阅组播组。

它（仍然）似乎没有记录，但之前已经在 erlang-questions 邮件列表中介绍过。http://www.erlang.org/pipermail/erlang-questions/2003-March/008071.html

    {ok, Socket} = gen_udp:open(Port, [binary, {active, false},
                                       {reuseaddr, true},{ip, Addr}, 
                                       {add_membership, {Addr, LAddr}}]).

其中Addr是多播组，并且LAddr是本地接口。（代码由 mog 提供）

可以将上面使用的相同选项传递给inet:setopts包括{drop_membership, {Addr, LAddr}}以停止收听组。

于 2008-09-17T08:32:44.710 回答
4

我试图让这个例子在我的电脑上运行。如果我通过打开接收套接字总是收到消息 {error,eaddrnotavail} 会发生什么？

示例 1：这有效：

{ok, Socket} = gen_udp:open(?PORT, [{reuseaddr,true}, {ip,?SERVER_IP},
               {multicast_ttl,4}, {multicast_loop,false}, binary]),

示例 2：获取运行时错误：

{ok, Socket} = gen_udp:open(?PORT, [{reuseaddr,true}, {ip,?MULTICAST_IP},
               {multicast_ttl,4}, {multicast_loop,false}, binary]),

% --> {error,eaddrnotavail}

-define(SERVER_IP, {10,31,123,123}). % The IP of the current computer
-define(PORT, 5353).
-define(MULTICAST_IP, {224,0,0,251}).
于 2009-12-10T10:49:23.413 回答
0

多播由 IP 地址指定

erlang 中的所有语言都是一样的。IP 地址 224.0.0.0 到 239.255.255.255 是多播地址。

在该范围内选择一个地址，检查您是否没有与已分配的地址重叠，您就可以开始了。

http://www.iana.org/assignments/multicast-addresses

于 2008-09-17T01:18:29.450 回答