3

我有时会收到想要保留的电子邮件，但将它们移动到适当的文件夹可能会很痛苦。例如，我如何执行一个脚本，将我正在查看的电子邮件移动（如使用 CSv）到某个名为“buffer”的文件夹中？

我正在使用 Outlook 2007。

谢谢。

编辑：没有可以创建任何标准来自动化这个过程，就像通过规则一样。这只是我盯着它时做出的判断。

4

3 回答 3

5

这段代码可能会更好。

在您的代码中，objFolder 可能等于 Nothing，但您继续该过程。此外，For Each 循环假定每个项目都是邮件项目。

Sub MoveSelectedMessagesToFolder()
  Dim objNS As Outlook.NameSpace
  Dim objFolder As Outlook.MAPIFolder
  Dim obj As Object
  Dim msg As Outlook.mailItem

  Set objNS = Application.GetNamespace("MAPI")
  On Error Resume Next
  Set objFolder = objNS.Folders.item("Personal Folders").Folders.item("Buffer")
  On Error GoTo 0

  If objFolder Is Nothing Then
    MsgBox "This folder doesn't exist!", vbOKOnly + vbExclamation, "INVALID FOLDER"
    Exit Sub
  End If

  For Each obj In ActiveExplorer.Selection
    If TypeName(obj) = "MailItem" Then
      Set msg = obj
      msg.Move objFolder
    End If
  Next obj

End Sub
于 2011-11-21T18:03:42.213 回答
2

这是我正在使用的代码。

Sub MoveSelectedMessagesToFolder()
'Originally written by Chewy Chong
'Taken from http://verychewy.com/archive/2006/04/12/outlook-macro-to-move-an-email-to-folder.aspx
'Thanks Chewy!
'Ken
On Error Resume Next
    Dim objFolder As Outlook.MAPIFolder, objInbox As Outlook.MAPIFolder
    Dim objNS As Outlook.NameSpace, objItem As Outlook.MailItem

    Set objNS = Application.GetNamespace("MAPI")
    Set objInbox = objNS.GetDefaultFolder(olFolderInbox)
    'For the "Item" portion, I used the name of the folder exactly as it appear in the ToolTip when I hover over it.
    Set objFolder = objNS.Folders.Item("Personal Folders").Folders.Item("Buffer")

'Assume this is a mail folder

    If objFolder Is Nothing Then
        MsgBox "This folder doesn't exist!", vbOKOnly + vbExclamation, "INVALID FOLDER"
    End If

    If Application.ActiveExplorer.Selection.Count = 0 Then
        'Require that this procedure be called only when a message is selected
        Exit Sub
    End If
    For Each objItem In Application.ActiveExplorer.Selection
        If objFolder.DefaultItemType = olMailItem Then
            If objItem.Class = olMail Then
                objItem.Move objFolder
            End If
        End If
    Next
于 2009-04-21T16:03:37.083 回答
1

工具 -> 规则和警报

然后创建一个新规则，告诉所有符合任何标准的邮件被删除/标记为已读/移动到文件夹/这些的任何组合。

编辑： 如果您不想要规则/无法制定适合的规则，您可以创建一个宏（工具-> 宏）将其移动到文件夹，然后将其绑定到快捷方式。

于 2009-04-21T15:39:08.423 回答