xslt - 如何找到a中的元素个数使用 XSLT？

Question

我有一个包含以下类型的 XML 模式：

<xs:simpleType name="valuelist">
  <xs:list itemType="xs:double"/>
</xs:simpleType>

一个示例 XML 片段将是：

<values>1 2 3.2 5.6</values>

在 XSLT 转换中，如何获取列表中的元素数量？

如何迭代元素？

Answer 1

如果列表是严格间隔的，您可以根据字符串长度计算空格。

<values>1 2 3.2 5.6</values>

XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

    <xsl:template match="/">
        <xsl:value-of select="string-length(values) 
                      - string-length(translate(values, ' ', '')) + 1"/>
    </xsl:template>

</xsl:stylesheet>

要遍历元素，您必须拆分此字符串。SO有很多例子。

Answer 2

一、XPath 2.0（XSLT 2.0）解决方案：

count(tokenize(., ' '))

二、XPath 1.0 (XSLT 1.0) 解决方案：

 string-length()
-
 string-length(translate(normalize-space(), ' ', ''))
+ 1

至于迭代这个列表的项目：

1. 在 XPath 2.0 / XSLT 2.0 中，只需使用上面的 XPath 2.0 表达式作为select属性的值：

--

 for $i in tokenize(., ' '),
     $n in number($i)
  return
    yourXPathExpression

--

2.在 XSLT 1.0 中，您需要更多代码来进行拆分/标记化。这个问题有几个很好的答案（其中一部分是我的）——只需搜索“xslt split a string”之类的内容

Answer 3

在模式感知转换中，使用count(data(value)).

Answer 4

有一点想象力，您可以编写自己的拆分函数：

<xsl:stylesheet version = '1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
    <xsl:output method='text'/>

    <xsl:template name="split-list">
    <xsl:param name="list" />
    <xsl:param name="separator"/>
    <xsl:variable name="newlist" select="concat(normalize-space($list), $separator)" /> 
    <xsl:variable name="first" select="substring-before($newlist, $separator)" /> 
    <xsl:variable name="remaining" select="substring-after($newlist, $separator)" />
            <xsl:message terminate="no">
            <xsl:value-of select="$first" />
        </xsl:message>

    <xsl:if test="$remaining">
        <xsl:call-template name="split-list">
          <xsl:with-param name="list" select="$remaining" />
                    <xsl:with-param name="separator" select="$separator"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template match="/">
    <xsl:variable name="myList">
            1 2 3.2 5.6
    </xsl:variable>
        <xsl:call-template name="split-list">
            <xsl:with-param name="list" select="$myList" />
            <xsl:with-param name="separator">
                <xsl:text> </xsl:text>
            </xsl:with-param>
        </xsl:call-template>
</xsl:template>
</xsl:stylesheet>

输出 ：

[xslt] Loading stylesheet D:\Tools\StackOverFlow\test.xslt
[xslt] 1
[xslt] 2
[xslt] 3.2
[xslt] 5.6