12

我正在尝试编写一个函数，我可以在其中指定任意数量的数组，返回值将是一个包含所有指定数组内容的数组。

我已经这样做了，但这似乎是一种非常缓慢而丑陋的做法：

var ar1:Array = [1,2,3,4,5,6,7,8,9];
var ar2:Array = ['a','b','c','d','e','f','g','h'];


function merge(...multi):Array
{
    var out:String = "";

    for each(var i:Array in multi)
    {
        out += i.join(',');
    }

    return out.split(',');
}

trace(merge(ar1, ar2));

有没有一种内置的、更有效/更好的方法来实现这一目标？结果不需要与输入的顺序相同 - 完全未排序就可以了。

4

3 回答 3

24

您可以使用concat。

如果参数指定了一个数组，则该数组的元素被连接起来。

var ar1:Array = [1,2,3,4,5,6,7,8,9];
var ar2:Array = ['a','b','c','d','e','f','g','h'];
var ar3:Array = ['i','j','k','l'];

var ar4 = ar1.concat(ar2, ar3); // or: ar1.concat(ar2).concat(ar3);

要从二维数组中创建单个数组，您可以使用此函数：

private function flatten(arrays:Array):Array {
    var result:Array = [];
    for(var i:int=0;i<arrays.length;i++){
        result = result.concat(arrays[i]);
    }
    return result;
}

// call
var ar4 = [ar1, ar2, ar3];
var ar5 = flatten(ar4);

您还可以使用可变参数来合并多个数组：

private function merge(...arrays):Array {
    var result:Array = [];
    for(var i:int=0;i<arrays.length;i++){
        result = result.concat(arrays[i]);
    }
    return result;
}

// call
var ar5 = merge(ar1, ar2, ar3);
于 2011-09-26T06:34:19.207 回答
8

我不知道这种方法是否比使用循环更快，但它是一种合并 2 个数组的（花哨的）快速方法。（它适用于 Javascript 和 Actionscript）

var arr1:Array = [1,2,3,4,5]
var arr2:Array = [6,7,8,9,10]

arr1.push.apply(this, arr2); // merge 
// arr1.push.call(this, arr2); // don't use this. see comment below

trace(arr1) // 1,2,3,4,5,6,7,8,9,10
于 2011-09-26T14:55:59.410 回答
2 
function merge(...multi):Array
{
  var res:Array = [];

  for each(var i:Array in multi)
  {
    res = res.concat(i);
  }

  return res;
}

没有尝试过，但这样的事情会帮助你。

于 2011-09-26T07:16:19.597 回答