3

我想在我的 Delphi 程序中使用 VST 插件，它充当 VST 主机。我已经尝试了 tobybear 示例，使用了 delphiasiovst stuf，其中一些甚至可以工作，但是......我不知道如何将 MIDI 消息发送到插件（我知道大多数插件不会处理 MIDI，但我有一个示例插件）。

更具体地说：我希望当我发送 MIDI 消息时，我必须在 VST 插件中使用一种或其他方法，或者重新路由 MIDI 输出。我只是不知道怎么做。

谁能指出我如何做到这一点的文档或代码？提前致谢。

阿诺德

我使用了两个测试插件：一个从 DelphiAsioVst 包和 PolyIblit 编译而来。两者都在 Finale 和 LMMS 中工作。加载到我的测试程序中都显示了他们的 VST 编辑器。

我确实插入了 TvstEvent 记录并对其进行了初始化，我插入了 MIDIData 和 AddMIDIData 过程以及一个计时器来提供测试数据并执行插件的 ProcessEvents 例程。ProcessEvents 获得正确的测试数据，但听不到声音。当我将它直接发送到 midi 输出端口时，我会听到一些声音。

在下面的代码中 PropcessEvents 应该足够恕我直言，附加代码是测试 MIDI 信息是否正确发送。VstHost [0] 是第一个插件，可以是 PolyIblit 或 VSTPlugin，具体取决于测试。

procedure TMain_VST_Demo.TimerTimer (Sender: TObject);
var i: Int32;
begin
//   MIDIOutput.PutShort ($90, 60, 127);
   MIDIData (0, $90, 60, 127);

   if FMDataCnt > 0 then
   begin
      FMyEvents.numEvents := FMDataCnt;
      VSTHost[0].ProcessEvents(@FMyEvents);
//    if (FCurrentMIDIOut > 0) and MIMidiThru.Checked then
//     begin
      for i := 0 to FMDataCnt - 1 do
      MIDIOutput.PutShort (PVstMidiEvent (FMyEvents.events[i])^.midiData[0],
                           PVstMidiEvent (FMyEvents.events[i])^.midiData[1],
                           PVstMidiEvent (FMyEvents.events[i])^.midiData[2]);
//       FMidiOutput.Send(//FCurrentMIDIOut - 1,
//                   PVstMidiEvent(FMyEvents.events[i])^.midiData[0],
//                   PVstMidiEvent(FMyEvents.events[i])^.midiData[1],
//                   PVstMidiEvent(FMyEvents.events[i])^.midiData[2]);
//     end;
     FMDataCnt := 0;
   end;
end; // TimerTimer //

所以我没有得到插件中的事件。知道我做错了什么吗？

4

3 回答 3

4

您应该真正查看 minihost 核心示例（Delphi ASIO 项目，v1.4）。

有一个使用 midi 事件。基本上

  1. 你有一个 TVstEvents 变量（比如说 MyMidiEvents: TvstEvents）。
  2. 对于整个运行时，您为此变量分配内存（例如在应用程序构造函数中）
  3. 当您的 MIDI 回调中有一个事件时，您将其复制到 TVstEvents 堆栈中。
  4. 在 TVstHost 中调用进程之前，调用 MyVstHost.ProcessEvents(@MyMidiEvents)。

对于前面的每个步骤，这就是示例（微型主机核心）中的完成方式：

1/ 在第 215 行，声明

FMyEvents: TVstEvents;

2/ 在第 376 行，分配：

for i := 0 to 2047 do
begin
 GetMem(FMyEvents.Events[i], SizeOf(TVSTMidiEvent));
 FillChar(FMyEvents.Events[i]^, SizeOf(TVSTMidiEvent), 0);
 with PVstMidiEvent(FMyEvents.Events[i])^ do
  begin
   EventType := etMidi;
   ByteSize := 24;
  end;
end;

3/ 在第 986 行，然后在第 1782 行，从回调复制 midi 事件：

回调

procedure TFmMiniHost.MidiData(const aDeviceIndex: Integer; const aStatus, aData1, aData2: Byte);
begin
 if aStatus = $FE then exit; // ignore active sensing
 if (not Player.CbOnlyChannel1.Checked) or ((aStatus and $0F) = 0) then
  begin
   if (aStatus and $F0) = $90
    then NoteOn(aStatus, aData1, aData2) //ok
    else
   if (aStatus and $F0) = $80
    then NoteOff(aStatus, aData1)
    else AddMidiData(aStatus, aData1, aData2);
  end;
end;

活动副本

procedure TFmMiniHost.AddMIDIData(d1, d2, d3: byte; pos: Integer = 0);
begin
 FDataSection.Acquire; 
 try
  if FMDataCnt > 2046 
   then exit;                 

  inc(FMDataCnt);
  with PVstMidiEvent(FMyEvents.events[FMDataCnt - 1])^ do
   begin
    EventType := etMidi;
    deltaFrames := pos;
    midiData[0] := d1;
    midiData[1] := d2;
    midiData[2] := d3;
   end;
 finally 
  FDataSection.Release;
 end; 
end;

4/ 在第 2322 行，在 TAsioHost.Bufferswitch 中，调用了 TVstHost.ProcessEvents

FDataSection.Acquire;
try
  if FMDataCnt > 0 then
   begin
    FMyEvents.numEvents := FMDataCnt;

    VSTHost[0].ProcessEvents(FMyEvents);

    if (FCurrentMIDIOut > 0) and MIMidiThru.Checked then
     begin
      for i := 0 to FMDataCnt - 1 do
       FMidiOutput.Send(FCurrentMIDIOut - 1,
                   PVstMidiEvent(FMyEvents.events[i])^.midiData[0],
                   PVstMidiEvent(FMyEvents.events[i])^.midiData[1],
                   PVstMidiEvent(FMyEvents.events[i])^.midiData[2]);
     end;
     FMDataCnt := 0;
   end;
 finally  
  FDataSection.Release;
 end;

如果您无法分析所使用的方法，这应该会对您有很大帮助。

于 2011-09-18T11:27:20.333 回答
2

如果您托管 VST 2.x 插件，您可以使用 AudioEffectX.ProcessEvents() 将 MIDI 事件发送到插件。

来自 VST 文档。

  • 事件始终与当前音频块相关。

  • 对于每个流程周期， processEvents() 在 processReplacing() 调用之前调用一次（如果有新事件可用）。

我不知道任何代码示例。DelphiAsioVST 中可能有一些东西。

于 2011-09-18T01:09:11.507 回答
1

如果你想改变编程语言，你可以试试VST.NET，它允许你用 C# 和 VB.NET 编写插件和主机。

希望能帮助到你。

于 2011-09-18T08:32:34.523 回答