8

解析大型 (100 Mb) XML 文件时出现错误“内存不足”

use strict;
use warnings;
use XML::Twig;

my $twig=XML::Twig->new();
my $data = XML::Twig->new
             ->parsefile("divisionhouserooms-v3.xml")
               ->simplify( keyattr => []);

my @good_division_numbers = qw( 30 31 32 35 38 );

foreach my $property ( @{ $data->{DivisionHouseRoom}}) {

    my $house_code = $property->{HouseCode};
    print $house_code, "\n";

    my $amount_of_bedrooms = 0;

    foreach my $division ( @{ $property->{Divisions}->{Division} } ) {

        next unless grep { $_ eq $division->{DivisionNumber} } @good_division_numbers;
        $amount_of_bedrooms += $division->{DivisionQuantity};
    }

    open my $fh, ">>", "Result.csv" or die $!;
    print $fh join("\t", $house_code, $amount_of_bedrooms), "\n";
    close $fh;
}

我能做些什么来解决这个错误问题？

4

2 回答 2

18

处理不适合内存的大型 XML 文件是一种广告：XML::Twig

的优点之一XML::Twig是它可以让您处理不适合内存的文件（顺便说一句，将 XML 文档作为树存储在内存中的内存非常昂贵，扩展因子通常在 10 左右）。

为此，您可以定义处理程序，一旦完全解析特定元素，就会调用该处理程序。在这些处理程序中，您可以访问元素并按照您认为合适的方式处理它（...）

问题中发布的代码根本没有利用 的力量XML::Twig（使用该simplify方法并不比 更好XML::Simple）。

代码中缺少的是 ' twig_handlers' 或 ' twig_roots'，它们本质上会导致解析器高效地专注于 XML 文档的相关部分。

没有看到 XML 就很难说是逐块处理文档还是只处理选定的部分是要走的路，但是任何一个都应该解决这个问题。

所以代码应该如下所示（逐块演示）：

use strict;
use warnings;
use XML::Twig;
use List::Util 'sum';   # To make life easier
use Data::Dump 'dump';  # To see what's going on

my %bedrooms;           # Data structure to store the wanted info

my $xml = XML::Twig->new (
                          twig_roots => {
                                          DivisionHouseRoom => \&count_bedrooms,
                                        }
                         );

$xml->parsefile( 'divisionhouserooms-v3.xml');

sub count_bedrooms {

    my ( $twig, $element ) = @_;

    my @divParents = $element->children( 'Divisions' );
    my $id = $element->first_child_text( 'HouseCode' );

    for my $divParent ( @divParents ) {
        my @divisions = $divParent->children( 'Division' );
        my $total = sum map { $_->text } @divisions;
        $bedrooms{$id} = $total;
    }

    $element->purge;   # Free up memory
}

dump \%bedrooms;
于 2011-09-03T19:06:06.183 回答
8

请参阅XML::Twig文档的逐块处理 XML 文档部分，它专门讨论了如何逐部分处理文档，从而允许处理大型 XML 文件。

于 2011-09-03T18:54:02.783 回答