0

我正在尝试在表之间建立关联。

我目前有一个包含以下字段的“用户”表：

ID 电子邮件 密码 名 姓 角色
1 老师@example.io 哈希 鲍勃 白色的 老师
2 学生@example.io 哈希 乔 棕色的 学生

我正在尝试实现两种新的用户类型：教师和学生

因此，我想为两种用户类型创建两个不同的表，它们将引用主表，如下所示：

  • 教师桌
ID 用户身份 名 姓
1 1（参考“用户”） 鲍勃 白色的
  • 学生桌
ID 用户身份 名 姓
1 2（参考“用户”） 乔 棕色的

我生成了一个新的迁移并创建了“教师”表，如下所示：

create table("teachers") do
   add :user_id, references("users")
   add :first_name, :string
   add :last_name, :string
end

然后我为教师表定义了一个模式，如下所示：

schema "teachers" do
   field :first_name, :string
   field :last_name, :string

   belongs_to :user, User

最后，我将其添加到用户架构中：

   has_many :teachers, Teacher

我现在已经成功地添加了我想要的列的教师表。问题是，我的注册表只包含一个变更集。用户模式进行所有验证，并在注册成功时将用户添加到“用户”表中。但“教师”表仍然是空的。用注册用户的信息填充教师表的最佳做法是什么？

4

1 回答 1

3

首先要知道的是没有一个“最佳实践”。

根据我的经验，有两种不同的方法：

  1. cast_assoc在你的User.changeset函数中使用。
  2. 在您的create_user函数中，使用Ecto.Multi创建:user，然后使用此用户 ID 创建teacheror student。

这两个都不是“更好”。使用对您感觉更好的那个。

我现在将更详细地解释这两种方法：

1.cast_assoc方法

在您的accounts.ex上下文中，您将拥有：

def create_user(attrs) do
  %User{}
  |> User.creation_changeset(attrs)
  |> Repo.insert()
end

地图将attrs如下所示：

%{
  password: "unhashed-password"
  student: %{
    first_name: "Bob",
    last_name: "Smith"
  }
}

或这个：

%{
  password: "unhashed-password"
  teacher: %{
    first_name: "Bob",
    last_name: "Smith"
  }
}

我决定创建一个仅用于创建用户的变更集函数，因为有时我可能只想更新用户而不更新相关的教师/学生。所以，在user.ex文件中，我有这个：

def creation_changeset(user, attrs) do
  User
  |> cast(attrs, @user_fields_to_cast)
  |> cast_assoc(:teacher, with: &Teacher.user_creation_changeset/2)
  |> cast_assoc(:student, with: &Student.user_creation_changeset/2)
end

差不多就是这样。

该create_user函数应该返回一个{:ok, %User{}}（或{:error, %Ecto.Changeset{}}）元组，teacher其中student加载了用户（教师或学生应该是nil）。

您不必使用专用的“创建”变更集，但我发现它通常会使这更容易。

2.Ecto.Multi方法

如果您这样做，则无需使用cast_assoc，您可以保持用户/教师/学生模式不变。相反，上下文函数看起来像这样：

alias Ecto.Multi

def create_user(attrs) do
  {teacher_attrs, attrs} = Map.pop(attrs, :teacher)
  {student_attrs, attrs} = Map.pop(attrs, :student)

  Multi.new()
  |> Multi.insert(:user, User.changeset(%User{}, attrs)
  |> Multi.run(:teacher, fn repo, %{user: user} ->
    if teacher_attrs do
      %Teacher{}
      |> Teacher.changeset(Map.put(teacher_attrs, :user_id, user.id))
      |> repo.insert()
    else
      {:ok, nil}
    end
  end)
  |> Multi.run(:student, fn repo, %{user: user} ->
    if student_attrs do
      %Student{}
      |> Student.changeset(Map.put(student_attrs, :user_id, user.id))
      |> repo.insert()
    else
      {:ok, nil}
    end
  end)
end

这将返回（在快乐的道路上），这个：

{:ok, %{user: user, student: student, teacher: teacher}}

学生或老师都将为零。

好了，我完成了。

我在浏览器中输入了所有这些内容，没有进行任何测试，所以要小心拼写错误、不匹配的括号和其他小问题！这只是说明性的。

于 2022-01-23T18:06:21.170 回答