unit-testing - 如何为 test.check 生成随机密钥？

Question

我正在使用 test.check 生成哈希图。我希望一个键是随机数字关键字这是我尝试过的

(gen/hash-map
  :16 gen/nat
  :1041 gen/string
  (keyword (str gen/nat)) gen/string)

这适用于前两个键，但 gen/sample 返回最后一个键的函数而不是值。来自 gen/sample 的输出 {:16 1, :1041 "»", :clojure.test.check.generators.Generator@3daf97b7 "u"}

Answer 1

这是一个使用示例gen/bind

user> (require '[clojure.test.check.generators :as gen])
nil
user> (gen/sample (gen/bind gen/nat
                            #(gen/hash-map
                              :16 gen/nat
                              :1041 gen/string
                              (keyword (str %)) gen/string)))
({:16 0, :1041 "", :0 ""}
 {:16 1, :1041 "—", :1 "Õ"}
 {:16 1, :1041 "~", :2 "{"}
 {:16 0, :1041 "", :0 ""}
 {:16 1, :1041 "}", :2 "š¤#"}
 {:16 4, :1041 "", :4 "ÂêÃ"}
 {:16 6, :1041 "¯¾ùPêà", :1 "xaÝ$"}
 {:16 1, :1041 "", :4 "ž"}
 {:16 7, :1041 "", :3 "Ù¡"}
 {:16 3, :1041 "‚«¤s", :5 "ƶoÒA“"})
user> 

这是一个使用gen/fmap

user> (gen/sample (gen/fmap (fn [[m n s]] (assoc m (keyword (str n)) s))
                            (gen/tuple (gen/hash-map
                                        :16 gen/nat
                                        :1041 gen/string)
                                       gen/nat gen/string)))
({:16 0, :1041 "", :0 ""}
 {:16 0, :1041 "", :1 "Ô"}
 {:16 2, :1041 "`", :0 "V²"}
 {:16 1, :1041 "X", :2 "b"}
 {:16 3, :1041 "JÓ", :2 ""}
 {:16 2, :1041 "", :2 ""}
 {:16 2, :1041 "", :2 "×kîj"}
 {:16 0, :1041 "", :0 ""}
 {:16 5, :1041 "ÎÖ", :0 ":üv-`"}
 {:16 8, :1041 "¬KéÎêo\r", :4 "ÆÌ"})
user> 

在这种情况下，您必须使用gen/fmap或gen/bind。它们都允许您操纵生成器的输出。如果要返回生成器，请使用gen/bind. 如果要返回值，请使用gen/fmap. 两者都gen/fmap接受gen/bind两个参数，其中一个是生成器，另一个参数是一个函数，它将第一个生成的值作为其输入，并返回一个生成器 (for gen/bind) 或一个值 (for gen/fmap)。

Answer 2

您需要使用clojure.test.check.generators/fmap将您的函数 ( str, keyword) 应用于您的生成器。