pine-script - 在没有安全功能的情况下，在实时柱中计算向上跳动量和向下跳动量

Question

我想构建一个 pine 脚本，该脚本将在实时每日条形图中计算总​​向上刻度量和总向下刻度量。我怎么做？我不想使用安全功能，因为它有限制。

Answer 1

这可以通过使用varip来声明变量来完成。
请通读文档varip以充分了解其工作原理。
然后看看一些开源示例脚本，看看它是如何使用的。

如何实现它的示例：

//@version=5
indicator("Intrabar Tick Volume", "ITV", overlay=true)

varip int   tickDirection   = na
varip int   tickCount       = 0
varip float volumeUp        = 0
varip float volumeDown      = 0
varip float prevTickVolume  = 0
varip float prevTickClose   = 0

if barstate.isnew
    tickCount       := 0
    volumeUp        := 0
    volumeDown      := 0
    prevTickVolume  := 0
    prevTickClose   := close[1]
else
    tickCount       += 1
    tickDirection   := close > prevTickClose ? 1 : close < prevTickClose ? -1 : 0

    if tickDirection == 1 //uptick
        volumeUp += volume - prevTickVolume
    else if tickDirection == -1 //downtick
        volumeDown += volume - prevTickVolume

    // Save data of current tick to use as previous tick values on next tick.
    prevTickClose   := close
    prevTickVolume  := volume

plotchar(tickCount, 'tickCount', '')
plotchar(close, 'close', '')
plotchar(tickDirection, 'tickDirection', '')
plotchar(volume, 'volume', '')
plotchar(volumeUp, 'volumeUp', '')
plotchar(volumeDown, 'volumeDown', '')