2

我在使用 rijndael 密码解密从 PHP 发送到 Delphi 的字符串时遇到问题。我在 PHP 端使用 mcrypt，在 Delphi 端使用 DCP_rijndael。

目前我有以下代码。

PHP：

function encRJ($key, $iv, $data)
{
    $r = mcrypt_encrypt(MCRYPT_RIJNDAEL_256, $key, $data, MCRYPT_MODE_CBC, $iv);
    $r = base64_encode($r);
    return $r;
}

在德尔福：

function decRJ(Data: string; Key: string; IV: string): string;
var ciph: TDCP_rijndael;
begin
  Data := Base64DecodeStr(Data);

  ciph:= TDCP_rijndael.Create(Self);
  ciph.Init(Key[1], 256, @IV[1]);
  ciph.DecryptCBC(Data[1], Data[1], Length(Data));
  ciph.Free;

  Result := Data;
end;

我尝试在 Internet 上使用几个单元来实现密码，并发现大多数人都在谈论 DCP 组件。即便如此，我还没有设法让它正确解密。我已经尝试使用字节数组作为参数、AnsiStrings、WideStrings 等，但不幸的是没有运气。

对不起，如果我在这里遗漏了一些非常明显的东西，因为经过数小时的搜索，我的大脑状况不佳。

4

2 回答 2

9

我似乎在这方面花了太长时间，但是......

你的问题是块大小。TDCP_rijndael 等效于 MCRYPT_RIJNDAEL_128（不是 _256）。ciph.Init(...) 调用中的 '256' 值仍然是正确的。除此之外，它看起来还不错。也就是说，假设您对 key/iv 使用 ansistrings，或者您使用的是非 unicode Delphi。
对于 unicode Delphi 版本，我倾向于使用 TBytes 和 key[0] / iv[0]。

填充可能仍然是一个问题。如果是这样，那么这就是我根据 PHP 手册页和一些试验和错误整理出来的内容。

PHP：

function Encrypt($src, $key, $iv)
{
  $block = mcrypt_get_block_size(MCRYPT_RIJNDAEL_128, 'cbc');
  //echo "Block size: " . $block . "\r\n";
  $pad = $block - (strlen($src) % $block);
  $src .= str_repeat(chr($pad), $pad);  

  $enc = mcrypt_encrypt(MCRYPT_RIJNDAEL_128, $key, $src, MCRYPT_MODE_CBC, $iv);
  $r = base64_encode($enc);
  return $r;
}

function Decrypt($src, $key, $iv)
{
  $enc = base64_decode($src);
  $dec = mcrypt_decrypt(MCRYPT_RIJNDAEL_128, $key, $enc, MCRYPT_MODE_CBC, $iv);

  $block = mcrypt_get_block_size(MCRYPT_RIJNDAEL_128, 'cbc');
  $pad = ord($dec[($len = strlen($dec)) - 1]);
  return substr($dec, 0, strlen($dec) - $pad);
}

德尔福：

function DecryptData(Data: string; AKey: AnsiString; AIv: AnsiString): string;
var
  key, iv, src, dest: TBytes;
  cipher: TDCP_rijndael;
  slen, pad: integer;
begin
  //key := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AKey));
  //iv := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AIv));
  key := TEncoding.ASCII.GetBytes(AKey);
  iv := TEncoding.ASCII.GetBytes(AIv);

  src := Base64DecodeBytes(TEncoding.UTF8.GetBytes(Data));

  cipher := TDCP_rijndael.Create(nil);
  try
    cipher.CipherMode := cmCBC;
    slen := Length(src);
    SetLength(dest, slen);
    cipher.Init(key[0], 256, @iv[0]); // DCP uses key size in BITS not BYTES
    cipher.Decrypt(src[0], dest[0], slen);
    // Remove the padding. Get the numerical value of the last byte and remove
    // that number of bytes
    pad := dest[slen - 1];
    SetLength(dest, slen - pad);

    // Base64 encode it
    result := TEncoding.Default.GetString(dest);
  finally
    cipher.Free;
  end;
end;

function EncryptData(Data: string; AKey: AnsiString; AIv: AnsiString): string;
var
  cipher: TDCP_rijndael;
  key, iv, src, dest, b64: TBytes;
  index, slen, bsize, pad: integer;
begin
  //key := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AKey));
  //iv := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AIv));
  key := TEncoding.ASCII.GetBytes(AKey);
  iv := TEncoding.ASCII.GetBytes(AIv);

  src := TEncoding.UTF8.GetBytes(Data);

  cipher := TDCP_rijndael.Create(nil);
  try
    cipher.CipherMode := cmCBC;
    // Add padding.
    // Resize the Value array to make it a multiple of the block length.
    // If it's already an exact multiple then add a full block of padding.
    slen := Length(src);
    bsize := (cipher.BlockSize div 8);
    pad := bsize - (slen mod bsize);
    Inc(slen, pad);
    SetLength(src, slen);
    for index := pad downto 1 do
    begin
      src[slen - index] := pad;
    end;

    SetLength(dest, slen);
    cipher.Init(key[0], 256, @iv[0]); // DCP uses key size in BITS not BYTES
    cipher.Encrypt(src[0], dest[0], slen);

    b64 := Base64EncodeBytes(dest);
    result := TEncoding.Default.GetString(b64);
  finally
    cipher.Free;
  end;
end;

PHP 和 Delphi 函数现在给了我相同的答案。

编辑

Base64DecodeBytes 是我添加到 DCP Base64 单元的一段代码：

function Base64DecodeBytes(Input: TBytes): TBytes;
var
  ilen, rlen: integer;
begin
  ilen := Length(Input);
  SetLength(result, (ilen div 4) * 3);
  rlen := Base64Decode(@Input[0], @result[0], ilen);
  // Adjust the length of the output buffer according to the number of valid
  // b64 characters
  SetLength(result, rlen);
end;

编辑 2018（复活死者......）：

根据要求，这里是编码方法，未经检查，直接从我找到的旧源文件中提取。

免责声明：它已有多年历史，在最近的记忆中未经测试，自 Delphi 2010 以来未使用过。现在可能有很多更好的选择。使用风险自负。

function Base64EncodeBytes(Input: TBytes): TBytes;
var
  ilen: integer;
begin
  ilen := Length(Input);
  SetLength(result, ((ilen + 2) div 3) * 4);
  Base64Encode(@Input[0], @result[0], ilen);
end;
于 2011-08-16T12:31:12.310 回答
0

您的 PHP 和 Delphi 方法似乎都没有指定任何填充。如果默认填充不同，那么您将遇到问题。为两者显式指定 PKCS7（或 PKCS5）。

GregS 对 Base64 解码结果的评论是正确的。您正在为您的 decRJ() 方法提供加密的密文。那将是随机出现的字节。尝试将其转换为 UTF-8 会破坏它，使其无法解密。传入的密文必须从 Base64 直接转换为字节数组。Cyphertext 不是字符串，因此需要将其转换为 Base64 才能作为文本传输。只有在解密回明文后，它才会再次成为文本。

于 2011-08-13T23:22:14.577 回答