metal - 在 CIFilter 内核中使用归一化采样器坐标

Question

我正在浏览有关自定义 CIFilter 的本教程：

https://medium.com/@m_tuzer/using-metal-shading-language-for-custom-cikernels-metal-swift-7bc8e7e913e6

除了采样器的坐标未标准化外，一切都运行良好。因此，例如这样的条件pos.y < 0.33不起作用，内核使用实际的图像坐标。

由于本教程较旧，因此 CIFilter 中可能发生了“破坏”此代码的更改。我浏览了CI 内核的手册，但找不到获取内核内部采样器的标准化坐标的方法。

这是内核的代码：

#include <metal_stdlib>
using namespace metal;
#include <CoreImage/CoreImage.h> // (1)

float3 multiplyColors(float3, float3);
float3 multiplyColors(float3 mainColor, float3 colorMultiplier) { // (2)
    float3 color = float3(0,0,0);
    color.r = mainColor.r * colorMultiplier.r;
    color.g = mainColor.g * colorMultiplier.g;
    color.b = mainColor.b * colorMultiplier.b;
    return color;
};

extern "C" { namespace coreimage {               // (3)
    float4 dyeInThree(sampler src, float3 redVector, float3 greenVector, float3 blueVector) {

        float2 pos = src.coord();
        float4 pixelColor = src.sample(pos);     // (4)
        
        float3 pixelRGB = pixelColor.rgb;
        
        float3 color = float3(0,0,0);
        if (pos.y < 0.33) {                      // (5)
            color = multiplyColor(pixelRGB, redVector);
        } else if (pos.y >= 0.33 && pos.y < 0.66) {
            color = multiplyColor(pixelRGB, greenVector);
        } else {
            color = multiplyColor(pixelRGB, blueVector);
        }

        return float4(color, 1.0);
    }
}}

Answer 1

您可以使用源的范围将源坐标转换为相对值，如下所示：

#include <metal_stdlib>
using namespace metal;
#include <CoreImage/CoreImage.h>


extern "C" { namespace coreimage {
    float4 dyeInThree(sampler src, float3 redVector, float3 greenVector, float3 blueVector) {

        float2 pos = src.coord();
        float4 pixelColor = src.sample(pos);

        // transform to relative coordinates
        pos -= src.origin();
        pos /= src.size();

        float3 color = float3(0,0,0);
        if (pos.y < 0.33) {
            color = pixelColor.rgb * redVector;
        } else if (pos.y < 0.66) {
            color = pixelColor.rgb * greenVector;
        } else {
            color = pixelColor.rgb * blueVector;
        }

        return float4(color, pixelColor.a);
    }
}}