9

当我正在处理haskell-exercises问题时。Constraint我看到以下代码通过将每种类型应用于约束构造函数来创建聚合。在 GHC 中，深度嵌套的 s 元组似乎Constraint仍然是一种类型Constraint（可能是扁平化的？）。

{-# LANGUAGE DataKinds     #-}
{-# LANGUAGE PolyKinds     #-}
{-# LANGUAGE TypeFamilies  #-}
{-# LANGUAGE TypeOperators #-}


type family All (c :: Type -> Constraint) (xs :: [Type]) :: Constraint where
  All c '[] = ()
  All c (x ': xs) = (c x, All c xs)

-- >>> :kind! All
-- All :: (* -> Constraint) -> [*] -> Constraint
-- = All

-- >>> :kind! All Eq '[Int, Double, Float]
-- All Eq '[Int, Double, Float] :: Constraint
-- = (Eq Int, (Eq Double, (Eq Float, () :: Constraint)))

我尝试使用PolyKinds以下扩展名对其进行概括。

{-# LANGUAGE DataKinds     #-}
{-# LANGUAGE PolyKinds     #-}
{-# LANGUAGE TypeFamilies  #-}
{-# LANGUAGE TypeOperators #-}


type family All' (c :: k -> r) (xs :: [k]) :: r where
  All' c '[] = ()
  All' c (x ': xs) = (c x, All' c xs)

-- >>> :kind! All'
-- All' :: (k -> r) -> [k] -> r
-- = All'

--- This one works. Tuples of Types is a Type.
-- >>> :kind! All' Maybe '[Int, Double, Float]
-- All' Maybe '[Int, Double, Float] :: *
-- = (Maybe Int, (Maybe Double, (Maybe Float, ())))

--- However this one gets stuck.
-- >>> :kind! All' Eq '[Int, Double, Float]
-- All' Eq '[Int, Double, Float] :: Constraint
-- = All' Eq '[Int, Double, Float]

是种'(,) (a :: k) (b :: k)也是种k。往下看，似乎并非如此，所以我想知道为什么All' c (x ': xs) = (c x, All' c xs)首先接受类型族定义（考虑到类型族返回 kind 是r）？

λ> :kind! '(,)
'(,) :: a -> b -> (a, b)
= '(,)

λ> :kind! '(,) ('True :: Bool) ('False :: Bool)
'(,) ('True :: Bool) ('False :: Bool) :: (Bool, Bool)
= '( 'True, 'False)

更新

正如@Daniel Wagner 下面已经提到的，(,)这里使用的被认为是Type -> Type -> Type，并且 kind 参数在上面的第二个等式中r被实例化（ ）。事实上，如果我们使用了，它会正确地返回一个类型错误。我能够使用此博客文章中描述的技术进一步确认它，如下所示（使用 kind和实例化）：TypeAll' c (x ': xs) = (c x, All' c xs)'(,)All'k*

λ> :set -fprint-explicit-kinds
λ> :info All'
type All' :: forall k r. (k -> r) -> [k] -> r
type family All' @k @r c xs where
  forall k (c :: k -> *). All' @k @(*) c ('[] @k) = ()
  forall k (c :: k -> *) (x :: k) (xs :: [k]).
    All' @k @(*) c ((':) @k x xs) = (c x, All' @k @(*) c xs)
4

1 回答 1

6

这里有一个句法双关语。实际上有几种不同的逗号，有不同的种类：

 (,) :: Type -> Type -> Type
 (,) :: Constraint -> Constraint -> Constraint -- ...ish
'(,) :: a -> b -> (a, b)

请注意，这些类型中没有一种与其他类型统一。此外，第二个有点谎言。ifx :: Constraint和y :: Constraint, then (x, y) :: Constraint，但逗号不能像 in 一样放在前缀(,) x y。

当试图消除前两个歧义时，GHC 假定您正在使用(,) :: Type -> Type -> Type，除非您在语法上不能使用它的地方（例如在 的左侧=>）或者您已经给出了明确的种类注释:: Constraint. 单勾'消除了前两个和最后一个之间的歧义。

于 2021-08-10T16:48:26.530 回答