2

这个问题与用户mark fitzpatrick的这个答案密切相关。

我的工作表图片

我在 M3# 和 AB3# （相同的列表）中有一个可变的国家代码标题列表和一个作为 A4# 行的唯一“提及”的可变列表。M4# 和 AB4# 中的公式计算 A4# 中的特定提及在每个国家/地区被列出的次数，分别为“P”和“O”两个问题。每个提及都出现在“P”或“O”中的至少一个中。对于 L 和 AA 列中的每一行，我有一个公式可以分别对每个国家的“P”和“O”的每行提及计数（如果没有提及，则为“-”），但这不是动态公式 - 我每次更新范围时，都必须将其复制到提及范围内。

我希望列 L 和 AA 改为包含动态公式。如何更新 AM 和 AN 列中的 Mark 公式以包含 L 和 AA 列中的国家代码？

在 AM4# 和 AN4# 中，我在我的溢出范围 M4# 和 AB4# 上使用Mark 的更新公式，它们产生与我的个人公式相同的结果，除了没有国家代码：

=LET( m, M4#,
   rSeq, SEQUENCE( ROWS(m) ),
   L, MMULT( LEN(m)--(m<>""), SIGN( SEQUENCE( COLUMNS(m) ) ) ) - 1,
   i, MMULT(--( TRANSPOSE( rSeq ) < rSeq ), L ) + rSeq,
   IFERROR( MID( TEXTJOIN( ",", TRUE, m ), i, L ), "" ) )

（编辑删除不必要的介绍）

4

2 回答 2

2

将标题连接到范围：

=LET( m, M4#&IF(M4#<>""," "&$M$3:$T$3,""),
   rSeq, SEQUENCE( ROWS(m) ),
   L, MMULT( LEN(m)--(m<>""), SIGN( SEQUENCE( COLUMNS(m) ) ) ) - 1,
   i, MMULT(--( TRANSPOSE( rSeq ) < rSeq ), L ) + rSeq,
   IFERROR( MID( TEXTJOIN( ",", TRUE, m ), i, L ), "" ) )

$M$3:$T$3你的头衔在哪里。

在此处输入图像描述

编辑：

要添加空间，我们需要做一些更改。我将所需的拆分器移动到它自己的变量中，以便找到它的长度：

=LET( m, M4#&IF(M4#<>""," "&$M$3:$T$3,""),
   spl,", ",
   rSeq, SEQUENCE( ROWS(m) ),
   L, MMULT( LEN(m)+(m<>"")*LEN(spl), SIGN( SEQUENCE( COLUMNS(m) ) ) ) - LEN(spl),
   i, MMULT(--( TRANSPOSE( rSeq ) < rSeq ), L ) + ((rSeq-1)*LEN(spl)) + 1,
   IFERROR( MID( TEXTJOIN( spl, TRUE, m ), i, L ), "" ) )

在此处输入图像描述

于 2021-07-30T16:30:18.720 回答
0

像我们以前那样在每一行上添加一个更简单的函数怎么样？

=TEXTJOIN(", ",TRUE,FILTER(RowData&" "&$Country$Codes, RowData))
于 2021-10-16T14:10:48.810 回答