4

我正在寻找一种（相当轻松）向小型旧版 Delphi 5 应用程序添加一些 Windows 应用程序事件日志支持的方法。我们只希望它在启动、关闭、无法连接到数据库等时记录下来。

我见过的几个解决方案/组件似乎表明我们需要创建一个资源 DLL，Windows 事件日志查看器在尝试读取我们的“条目”时将链接到该 DLL。虽然这看起来并不太繁琐，但我想如果/当我们将来进一步开发应用程序时，还需要记住其他一些事情——我们需要让这个 DLL 保持最新。

在未来的某个时候，我们希望将应用程序变成服务，可能是用 D2007 编写的。

那么任何人都可以推荐一条合适的路线来将事件添加到 D5 中的事件日志中吗？我正在寻找具体的“我们使用了这个并且没问题”的评论，而不是谷歌拖网（我可以自己做！）免费或付费，真的不介意 - 但我可以迁移到 D2007未来很重要。

4

4 回答 4

6

摘要：使用 Delphi 写入 Windows 事件日志

如果您正在编写 Windows 服务并且需要写入本地计算机的 Windows 事件日志，那么您可以调用 TService。此处提到的LogMessage。

//TMyTestService = class(TService)

procedure TMyTestService.ServiceStart(Sender: TService; var Started: Boolean);
begin
  LogMessage('This is an error.');
  LogMessage('This is another error.', EVENTLOG_ERROR_TYPE);
  LogMessage('This is information.', EVENTLOG_INFORMATION_TYPE);
  LogMessage('This is a warning.', EVENTLOG_WARNING_TYPE);
end;

对于任何其他类型的应用程序，您可以使用 SvcMgr。TEventLogger 未记录的 TService帮助器类，用于编写本地计算机的 Windows 事件日志，如此处、此处和此处所述。

uses
  SvcMgr;

procedure TForm1.EventLoggerExampleButtonClick(Sender: TObject);
begin
  with TEventLogger.Create('My Test App Name') do
  begin
    try
      LogMessage('This is an error.');
      LogMessage('This is another error.', EVENTLOG_ERROR_TYPE);
      LogMessage('This is information.', EVENTLOG_INFORMATION_TYPE);
      LogMessage('This is a warning.', EVENTLOG_WARNING_TYPE);
    finally
      Free;
    end;
  end;
end;

您还可以使用此处和此处提到的 Windows API ReportEvent函数。

我创建了一个简单的类来使它更容易，它可以在 GitHub 上找到。

//----------------- EXAMPLE USAGE: ---------------------------------

uses
  EventLog;

procedure TForm1.EventLogExampleButtonClick(Sender: TObject);
begin
  TEventLog.Source := 'My Test App Name';

  TEventLog.WriteError('This is an error.');
  TEventLog.WriteInfo('This is information.');
  TEventLog.WriteWarning('This is a warning.');
end;

//------------------------------------------------------------------


unit EventLog;

interface

type
  TEventLog = class
  private
    class procedure CheckEventLogHandle;
    class procedure Write(AEntryType: Word; AEventId: Cardinal; AMessage: string); static;
  public
    class var Source: string;
    class destructor Destroy;

    class procedure WriteInfo(AMessage: string); static;
    class procedure WriteWarning(AMessage: string); static;
    class procedure WriteError(AMessage: string); static;

    class procedure AddEventSourceToRegistry; static;
  end;

threadvar EventLogHandle: THandle;

implementation

uses Windows, Registry, SysUtils;

class destructor TEventLog.Destroy;
begin
  if EventLogHandle > 0 then
  begin
    DeregisterEventSource(EventLogHandle);
  end;
end;

class procedure TEventLog.WriteInfo(AMessage: string);
begin
  Write(EVENTLOG_INFORMATION_TYPE, 2, AMessage);
end;

class procedure TEventLog.WriteWarning(AMessage: string);
begin
  Write(EVENTLOG_WARNING_TYPE, 3, AMessage);
end;

class procedure TEventLog.WriteError(AMessage: string);
begin
  Write(EVENTLOG_ERROR_TYPE, 4, AMessage);
end;

class procedure TEventLog.CheckEventLogHandle;
begin
  if EventLogHandle = 0 then
  begin
   EventLogHandle := RegisterEventSource(nil, PChar(Source));
  end;
  if EventLogHandle <= 0 then
  begin
    raise Exception.Create('Could not obtain Event Log handle.');
  end;
end;

class procedure TEventLog.Write(AEntryType: Word; AEventId: Cardinal; AMessage: string);
begin
  CheckEventLogHandle;
  ReportEvent(EventLogHandle, AEntryType, 0, AEventId, nil, 1, 0, @AMessage, nil);
end;

// This requires admin rights. Typically called once-off during the application's installation
class procedure TEventLog.AddEventSourceToRegistry;
var
  reg: TRegistry;
begin
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    if reg.OpenKey('\SYSTEM\CurrentControlSet\Services\Eventlog\Application\' + Source, True) then
    begin
      reg.WriteString('EventMessageFile', ParamStr(0)); // The application exe's path
      reg.WriteInteger('TypesSupported', 7);
      reg.CloseKey;
    end
    else
    begin
      raise Exception.Create('Error updating the registry. This action requires administrative rights.');
    end;
  finally
    reg.Free;
  end;
end;

initialization

TEventLog.Source := 'My Application Name';

end.

ReportEvent支持将日志条目写入本地或远程计算机的事件日志。有关远程示例，请参阅John Kaster 的 EDN 文章。

请注意，您还必须创建一个消息文件并注册您的事件源，否则您的所有日志消息都将以如下内容开头：

找不到来自源 xxxx 的事件 ID xxx 的描述。引发此事件的组件未安装在本地计算机上，或者安装已损坏。您可以在本地计算机上安装或修复组件。

如果事件起源于另一台计算机，则显示信息必须与事件一起保存。

活动中包含以下信息：

1，有关如何创建消息文件的更多信息，请参阅Finn Tolderlund 的教程或Michael Hex 的文章，或者您可以使用GitHub 项目中包含 的现有 MC 和RES 文件。

2，通过将 MessageFile.res 包含在 DPR 文件中，将 RES 文件嵌入到您的应用程序中。或者，您可以为消息创建一个 dll。

program MyTestApp;

uses
  Forms,
  FormMain in 'FormMain.pas' {MainForm},
  EventLog in 'EventLog.pas';

{$R *.res}
{$R MessageFile\MessageFile.res}

begin
  Application.Initialize;

3，一次性注册需要管理员权限写入注册表，所以我们通常在您的应用程序安装过程中完成。

//For example
AddEventSourceToRegistry('My Application Name', ParamStr(0));
//or
AddEventSourceToRegistry('My Application Name', 'C:\Program Files\MyApp\Messages.dll');

//--------------------------------------------------

procedure AddEventSourceToRegistry(ASource, AFilename: string);
var
  reg: TRegistry;
begin
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    if reg.OpenKey('\SYSTEM\CurrentControlSet\Services\Eventlog\Application\' + ASource, True) then
    begin
      reg.WriteString('EventMessageFile', AFilename);
      reg.WriteInteger('TypesSupported', 7);
      reg.CloseKey;
    end
    else
    begin
      raise Exception.Create('Error updating the registry. This action requires administrative rights.');
    end;
  finally
    reg.Free;
  end;
end;

如果您需要 Windows 事件日志记录和其他日志记录要求，您还可以使用log4d和TraceTool等日志记录框架

如果要写入 Delphi IDE 中的事件日志窗口，请参见此处。

于 2015-05-14T06:41:37.203 回答
4

对于 D5 中的简单事件日志记录，我使用以下代码将消息添加到应用程序日志。

  • 将“SvcMgr”添加到使用子句

  • 使用此代码添加您的短信和 ID 号（LogMessage 行的最后一个参数）

    with TEventLogger.create('My Application Name') do
begin
  try
    LogMessage('Information Message!', EVENTLOG_INFORMATION_TYPE, 0, 1);
    LogMessage('Error Message!', EVENTLOG_ERROR_TYPE, 0, 2);
    LogMessage('Warning Message!', EVENTLOG_WARNING_TYPE, 0, 3);
    LogMessage('Audit Success Message!', EVENTLOG_AUDIT_SUCCESS, 0, 4);
    LogMessage('Audit Failure Message!', EVENTLOG_AUDIT_FAILURE, 0, 5);
  finally
    free;
  end;
end;
于 2009-03-26T11:15:45.200 回答
3

我在 Delphi 6 中为此使用标准 VCL，我无法告诉您这在 Delphi 5 中是否可用。自己尝试一下，让我们知道 D5 中是否有这些东西。

  1. 声明一个 TEventLogger 类型的全局/表单变量。这是在 SvcMgr 单元中声明的，因此需要将此单元添加到您的使用列表中。如果这是一个普通的应用程序（即不是一个服务），那么请确保在表单单元之后添加了 SvcMgr。

    我的事件日志：TEventLogger；

  2. 创建记录器的实例。

    MyEventLog := TEventLogger.Create('MyApplication');

  3. 要写入事件日志：

    MyEventLog.LogMessage('MyApplication 已启动。'), EVENTLOG_INFORMATION_TYPE);

  4. 不要忘记在最后释放它：

    MyEventLog.免费；

您还需要做其他事情来使用 Windows 事件日志注册应用程序，以便消息出现在其前面而没有此内容：

找不到源 (Microsoft Internet Explorer) 中事件 ID (1000) 的描述。本地计算机可能没有必要的注册表信息或消息 DLL 文件来显示来自远程计算机的消息。以下信息是事件的一部分：

于 2009-03-26T10:40:31.637 回答
1

感谢J和 Peter 的回复，我立即将代码写入事件日志。还有一些事情要做，特别是如果您希望您的事件在事件日志中“很好地”显示，而没有关于无法找到描述的标准 Windows 消息（根据J的帖子的底部）。

我按照这里的提示制作了一个合适的 DLL 并将其输入到注册表中，并且很快就解决了所有问题。

根据问题，这一切都在Delphi5中，但我没有看到任何让我认为它在D2007中也不起作用的东西。

于 2009-03-27T07:20:34.887 回答