1

我正在应对这个编码挑战：

为 Little Man Computer 编写一个程序，允许用户管理值列表。它应该从一个空列表开始，然后按如下方式处理输入：

如果输入是：

  • 小于 100：将此值添加到列表中，除非列表已经有 10 个值，在这种情况下，忽略该值
  • 995：使列表为空
  • 996：输出列表当前拥有的值的个数
  • 997：输出列表当前具有的每个值，按照它们添加到列表中的顺序
  • 998：以相反的顺序输出列表当前具有的每个值
  • 999：结束程序
  • 任何其他值都被忽略

只要输入值不是 999，就会继续处理输入值。

当输入 997 时，我在获取代码以正向打印存储列表时遇到问题。我想我可能对ADD和SUB指令感到困惑。输入 995 时，我也无法正确重置存储的列表。

我能够正确编程的所有其他内容。

下面是我的代码：

START   INP
        STA TEMP
        SUB NINES
        BRZ end

        LDA TEMP
        SUB EIGHT
        BRZ PRIT

        lda temp
        sub seven
        brz printf

        LDA TEMP
        SUB SIX
        BRZ DOOUT

        LDA TEMP
        SUB FIVE
        BRZ RESET

        LDA COUNT
        SUB TEN
        BRZ START

        LDA TEMP
        SUB HUND
        BRP START

SIT     LDA SINST
        ADD COUNT
        STA SLOC
        LDA TEMP
SLOC    DAT 0
        LDA COUNT
        ADD ONE
        STA COUNT
        BRA START
PRIT    LDA COUNT
        BRZ END
PRINTR  LDA LINST
        ADD COUNT
        SUB ONE
        STA LDIT
LDIT    DAT 0
        OUT
        LDA COUNT
        SUB ONE
        STA COUNT
        BRZ END
        BRA PRINTR

---PRINTF  LDA LINST
        ADD COUNT
        add ONE
        STA LDIT
LDIT    DAT 0
        OUT
        LDA COUNT
        SUB ONE
        STA COUNT
        BRZ END
        BRA PRINTF 

doout   lda count
        out
        bra start

reset   lda zero
        sta count
        bra start

END     HLT

TEMP    DAT 0
COUNT   DAT 0
ONE     DAT 1
TWO     DAT 2
TEN     DAT 10
HUND    DAT 100
SINST   DAT 380
LINST   DAT 580
five    dat 995
six     dat 996
seven   dat 997
eight   dat 998
NINES   DAT 999
4

1 回答 1

0

您的程序中的问题可以分类为：

  1. 一个好的模拟器在运行程序之前应该检测到的与标签相关的问题
  2. 与程序逻辑相关的问题，使程序产生错误的输出
  3. 代码风格相关问题

1. 标签

一个好的模拟器不应该接受以下错误：

  • PRINTF标签未定义。

    有一条brz printf指令，但没有定义该标签，因为---它是一个注释。显然，---需要删除标签引用才能有效。

  • LDIT标签重复：

    标签 LDIT 定义了两次。这将具有不可靠的行为。一个好的模拟器应该给出一个错误信息，但其他模拟器只会采用一个定义并忽略重复项。无论哪种方式，程序的意图是一个STA LDIT使用第一个LDIT 位置，第二个STA LDIT使用第二个LDIT 位置。如果有的话，这将不会发生。所以重命名两个标签之一，并STA LDIT相应地调整其中一个指令。

  • zero标签未定义：

    重置计数器的代码引用了一个未定义的标签zero。同样，好的模拟器在加载程序时会产生错误，但其他人可能会默默地使用邮箱 0，这会导致不良行为。所以将zero标签定义为

    zero DAT 0

2. 逻辑

  • 打印列表的代码，无论是向前还是向后，都会改变的值COUNT，但是这样代码会丢失列表的大小！例如，如果在这样的遍历之后您将选择操作 996——即查询列表的大小——它不会给出正确的结果。解决方案是使用不同的变量来遍历列表，并且COUNT保持不变。只有在向列表添加值或重置COUNT列表时才应更改。

  • 打印代码以跳转到 结束END，但似乎应该允许用户继续使用另一个“菜单”选项，所以不要跳转到END它应该跳转到START. 跳转到的唯一原因END应该是因为用户输入了选项 999。

  • 对于正向打印，您不应该从添加COUNT动态加载指令开始，因为您需要从列表的第一个元素开始，而不是最后一个元素。所以不要在第一次打印之前ADD COUNT做。ADD ONE相反，增加动态加载指令直到它与原始加载指令的差异——即计算列表中的相对偏移量——至少为COUNT.

  • LMC 规范有一个特别的奇怪之处：它没有定义当减法会导致负结果时累加器的值是什么。累加器不能存储负值，只能标记负结果。BRZ因此，当您刚刚执行SUB可能导致负值的指令时，这样做是不安全的（因为奇怪的是，当减法为负时，模拟器可能会对累加器中的零值做出反应）。简而言之，如果可以的话，更喜欢使用BRP而不是BRZ，或者在使用BRP之前最少使用BRZ。注意：即使是这门学科的老师也不总是意识到这一点。

  • LMC 有一个复位“句柄”，它将程序计数器设置回程序的开始位置。发生这种情况时，您需要从头开始，并COUNT重置为 0。因此，请在程序的最顶部添加重置代码。

这将解决程序中的语义问题。

3.代码风格

  • 我建议您使用更有意义的名称。doout不是很有启发性，因为您的程序旨在输出不同的内容（前序列表，后序列表，列表大小）。因此，例如，使用output_size代替doout. LDIT像, , ... 这样的名字PRIT非常神秘。当程序使用描述性名称时，它会更容易阅读和理解，而没有只有你会理解的缩写。

  • 动态指令基于SINST（存储指令）和LINST（加载指令），它们被硬编码为：

    SINST  DAT 380
LINST  DAT 580

    但很遗憾，您已经像那样对它们进行了硬编码。首先，他们假设邮箱 80 可以免费存储列表，其次它需要知道这些指令的操作码（3 和 5）。然而，有了一个好的汇编程序，你不应该这样做。所以我建议这样做：

    store_instruction STA list
load_instruction  LDA list

    ...并在代码的最底部list使用指令进行定义（因为那里有可用的邮箱）。DAT我什DAT至会在它之后添加虚拟行，以便非常清楚属于该列表的邮箱——它只是让人们更容易理解代码：

    list DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT

    这样，列表可能不会存储在邮箱 80 中，但我们不在乎。我们把它留给汇编程序为我们的列表分配下一个空闲邮箱。STA在你的“数据部分”中间有和指令可能看起来也很奇怪LDA，它们永远不会被执行，但是 LMC 架构（冯诺依曼架构）的原则是代码和数据使用相同的内存，所以这个很好。和指令将从那里复制到实际程序中LDA。STA

更正的程序

考虑到以上所有因素，程序可能如下所示：

#input:1 2 3 997 998 999
clear_list        LDA zero # Start by resetting the list
                  STA list_size

start             INP
                  STA input
                  SUB menu_nine
                  BRP end

                  LDA input
                  SUB menu_eight
                  BRP output_reversed

                  LDA input
                  SUB menu_seven
                  BRP output_forward

                  LDA input
                  SUB menu_six
                  BRP output_size

                  LDA input
                  SUB menu_five
                  BRP clear_list

                  LDA list_size
                  SUB max_list_size
                  BRP start

                  LDA input
                  SUB input_limit
                  BRP start

                  LDA store_instruction
                  ADD list_size
                  STA store
                  LDA input
store             DAT 0
                  LDA list_size
                  ADD one
                  STA list_size
                  BRA start

output_reversed   LDA load_instruction
                  ADD list_size
loop_reversed     SUB one
                  STA load_reversed
                  SUB load_instruction # are we still within the list?
                  BRP load_reversed # yes, continue printing
                  BRA start
load_reversed     DAT 0
                  OUT
                  LDA load_reversed # decrement the dynamic LDA instruction
                  BRA loop_reversed

output_forward    LDA load_instruction
loop_forward      STA load_forward
                  SUB load_instruction # get relative offset in the list
                  SUB list_size # are we still within the list?
                  BRP start # no, stop printing
load_forward      DAT 0
                  OUT
                  LDA load_forward # increment the dynamic LDA instruction
                  ADD one
                  BRA loop_forward

output_size       LDA list_size
                  OUT
                  BRA start

end               HLT

# constants
zero              DAT 0
one               DAT 1
two               DAT 2
max_list_size     DAT 10
input_limit       DAT 100
load_instruction  LDA list
store_instruction STA list
menu_five         DAT 995
menu_six          DAT 996
menu_seven        DAT 997
menu_eight        DAT 998
menu_nine         DAT 999
# variables
input             DAT 0
list_size         DAT 0
list              DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT



<script src="https://cdn.jsdelivr.net/gh/trincot/lmc@v0.816/lmc.js"></script>

您可以使用此代码段在此处运行代码。单击Run Code Snippet以激活 LMC 模拟器，然后使用右侧的面板与之交互。

于 2021-07-18T12:37:12.107 回答