zig - 如何读取 zig 中的文件？

Question

如何读取 zig 文件，并逐行运行？

我确实找到了os.File.openRead，但它似乎很旧，因为它这么说 container 'std.os' has no member called 'File'。

Answer 1

std.io.reader.readUntilDelimiterOrEof让您std.io.reader逐行阅读任何内容。您通常通过调用文件的reader()方法来获取文件之类的阅读器。例如：

var file = try std.fs.cwd().openFile("foo.txt", .{});
defer file.close();

var buf_reader = std.io.bufferedReader(file.reader());
var in_stream = buf_reader.reader();

var buf: [1024]u8 = undefined;
while (try in_stream.readUntilDelimiterOrEof(&buf, '\n')) |line| {
    // do something with line...
}

这std.io.bufferedReader不是强制性的，但建议使用以获得更好的性能。

Answer 2

我通过查看 Zig 库源/文档来解决这个问题，所以这可能不是最惯用的方式：

const std = @import("std");

pub fn main() anyerror!void {
    //  Get an allocator
    var gp = std.heap.GeneralPurposeAllocator(.{ .safety = true }){};
    defer _ = gp.deinit();
    const allocator = &gp.allocator;

    // Get the path
    var path_buffer: [std.fs.MAX_PATH_BYTES]u8 = undefined;
    const path = try std.fs.realpath("./src/main.zig", &path_buffer);

    // Open the file
    const file = try std.fs.openFileAbsolute(path, .{ .read = true });
    defer file.close();

    // Read the contents
    const buffer_size = 2000;
    const file_buffer = try file.readToEndAlloc(allocator, buffer_size);
    defer allocator.free(file_buffer);

    // Split by "\n" and iterate through the resulting slices of "const []u8"
    var iter = std.mem.split(file_buffer, "\n");

    var count: usize = 0;
    while (iter.next()) |line| : (count += 1) {
        std.log.info("{d:>2}: {s}", .{ count, line });
    }
}

上面是一个小演示程序，您应该可以将其放入从创建的默认项目中zig init-exe，它只会打印出它自己的内容，并带有行号。

如果您提供所需的缓冲区，您也可以在没有分配器的情况下执行此操作。

我还建议查看这个很棒的资源：https ://ziglearn.org/chapter-2/#readers-and-writers

注意：我目前正在从 master 运行 Zig 的开发版本（报告为 0.9.0），但我认为这在最近的几个官方版本中一直有效。

Answer 3

打开文件并取回文件描述符 std.os.open

https://ziglang.org/documentation/0.6.0/std/#std;os.open

从文件中读取 std.os.read

https://ziglang.org/documentation/0.6.0/std/#std;os.read

我在 zig 标准库中找不到 .readlines() 样式函数。您必须编写自己的循环来查找\n字符。