1

我不明白为什么这不起作用

xSource = vrtSelectedItem  '<<== C:\Users\Me\Desktop\Document01.pdf

Set FSO = VBA.CreateObject("Scripting.FileSystemObject")
    
If Not InStr(xSource, ".jpg") Or Not InStr(xSource, ".bmp") Or Not InStr(xSource, ".png") _
Or Not InStr(xSource, ".tif") Or Not InStr(xSource, ".tga") Or Not InStr(xSource, ".jpeg") _
Or Not InStr(xSource, ".doc") Or Not InStr(xSource, ".pdf") Or Not InStr(xSource, ".rtf") _
Or Not InStr(xSource, ".htm") Or Not InStr(xSource, ".html") Or Not InStr(xSource, ".txt") _
Or Not InStr(xSource, ".docx") Or Not InStr(xSource, ".tdm") Or Not InStr(xSource, ".wri") _
Or Not InStr(xSource, ".xls") Or Not InStr(xSource, ".xlsx") Or Not InStr(xSource, ".xlsm") _
Or Not InStr(xSource, ".ods") Or Not InStr(xSource, ".odt") Then

MsgBox "File type not allowed"
Exit Sub

Else

.....

虽然文件包含.pdf，但我得到 MsgBox "File type not allowed"！我列出的所有其他文件类型也会发生这种情况，实际上将它们从错误消息中排除！谁能给我一些建议？谢谢

4

1 回答 1

1

TL;DR：InStr不返回 a Boolean，而是返回一个Variant( Long)，指定一个字符串在另一个字符串中第一次出现的位置。

简化解释问题：

xSource = "C:\Users\Me\Desktop\Document01.pdf"

Debug.Print InStr(xSource, "pdf")
Debug.Print Not InStr(xSource, "pdf")
Debug.Print CBool(Not InStr(xSource, "pdf"))

返回

 32 
-33 
True

InStr不返回布尔值，而是一个字符串在另一个字符串中第一次出现的位置。而不是使用Not，通常人们会检查结果是否InStr是> 0确定是否找到匹配项。

在数值表达式上使用Not是执行按位否定，如上所示，这会导致匹配结果最终计算为True. 事实上，没有匹配也计算为True（CBool(Not(0))返回True）。

这是执行此操作的另一种方法：

Private Function IsValidFileType(ByVal filePath As String) As Boolean
    Dim FSO As Scripting.FileSystemObject
    Set FSO = New Scripting.FileSystemObject
    
    Dim extension As String
    extension = FSO.GetExtensionName(filePath)

    Select Case extension
        Case "jpg", "bmp", "png" '< and so on
            IsValidFileType = True
        Case Else
            IsValidFileType = False
    End Select
End Function
于 2021-06-26T16:33:21.233 回答