delphi - 如何最好地在 Delphi IDE 中修改/安装组件库路径，而无需手动操作？

Question

我正在准备一个安装程序（Inno Setup）来将我的组件包安装到 Delphi XE 中，而无需手动在 IDE 中摆弄。

我需要修改 Delphi 库路径，例如删除它的一部分（例如， xxx;MyOldPath;yyy）并插入一个新路径，xxxx;MyNewPath;yyyy. 有这样做的首选方法还是我必须编写一个实用程序来做到这一点？

谢谢

Answer 1

修改路径是基本的字符串操作：您从注册表中读取当前路径，根据需要对其进行操作，然后将其写回。

您可能可以编写一个 Inno Setup 脚本函数，这样您就没有任何外部依赖项。或者编写一个从 Inno Setup 的脚本中使用的 Delphi DLL，这样调试起来会更容易。

---

编辑

这是我实际在生产中使用的例程的修改版本。它将从Search Path注册表值或Browsing Path（与此相关的任何其他路径）读取整个路径列表，可能会删除一些路径，并添加一些路径（如果它们尚不存在）。

procedure UpdateDelphiPaths(const RegistryKey, RegistryValue: string; PathsToRemove, PathsToAdd: TStrings);
var R:TRegistry;
      SKeys:TStringList;
      Found:Boolean;
      Updated:Boolean;
      i,j:Integer;
      s:string;
      R_Globals:TRegistry;

  // This function normalises paths in comparasions
  function PrepPathForComparasion(const Path:string):string;
  begin
    if Path = '' then Result := '\'
    else
      if Path[Length(Path)] = '\' then
        Result := LowerCase(Path)
      else
        Result := LowerCase(Path) + '\';
  end;

  function PathMatchesRemoveCriteria(const Path:string): Boolean;
  var i:Integer;
  begin
    // This needs to be addapted to match your criteria!
    for i:=0 to PathsToRemove.Count-1 do
      if AnsiPos(PathsToRemove[i], Path) <> 0 then
        Exit(True);
    Result := False;
  end;

begin
  R := TRegistry.Create;
  try
    R.RootKey := HKEY_CURRENT_USER;
    if R.OpenKey(RegistryKey + '\Library', False) then
      if R.ValueExists(RegistryValue) then
      begin
        SKeys := TStringList.Create;
        try
          SKeys.Delimiter := ';';
          SKeys.StrictDelimiter := True;
          SKeys.DelimitedText := R.ReadString(RegistryValue);

          Updated := False;

          // Look at all the paths in the PathsToAdd list, if any one's missing add it to the list and mark
          // "Updated".
          for i:=0 to PathsToAdd.Count-1 do
          begin
            Found := False;
            for j:=0 to SKeys.Count-1 do
              if LowerCase(Trim(SKeys[j])) = LowerCase(Trim(PathsToAdd[i])) then
                Found := True;
            if not Found then
            begin
              SKeys.Add(PathsToAdd[i]);
              Updated := True;
            end;
          end;

          // Look at every single path in the current list, if it's not in the "PathsToAdd" and it matches
          // a name in "PathsToRemove", drop it and mark "Updated"
          i := 0;
          while i < SKeys.Count do
          begin
            if PathMatchesRemoveCriteria(SKeys[i]) then
              begin
                // Path matches remove criteria! It only gets removed if it's not actually present in
                // PathsToAdd
                Found := False;
                for j:=0 to PathsToAdd.Count-1 do
                begin
                  if PrepPathForComparasion(SKeys[i]) = PrepPathForComparasion(PathsToAdd[j]) then
                    Found := True;
                end;
                if not Found then
                  begin
                    SKeys.Delete(i);
                    Updated := True;
                  end
                else
                  Inc(i);
              end
            else
              Inc(i);
          end;

          // If I've updated the SKeys in any way, push changes back to registry and force updates
          if Updated then
          begin
            s := SKeys[0];
            for i:=1 to SKeys.Count-1 do
              if SKeys[i] <> '' then
              begin
                s := s + ';' + SKeys[i];
              end;
            R.WriteString(RegistryValue, s);

            // Force delphi to re-load it's paths.
            R_Globals := TRegistry.Create;
            try
              R_Globals.OpenKey(RegistryKey + '\Globals', True);
              R_Globals.WriteString('ForceEnvOptionsUpdate', '1');
            finally R_Globals.Free;
            end;

          end;

        finally SKeys.Free;
        end;
      end;
  finally R.Free;
  end;
end;

从 Delphi 代码中，我可以像这样调用例程，以确保安装了给定库的最新搜索路径：

var ToRemove, ToAdd: TStringList;
begin
  ToRemove := TStringList.Create;
  try
    ToAdd := TStringList.Create;
    try
      ToRemove.Add('LibraryName\Source');
      ToAdd.Add('C:\LibraryName\Source');
      UpdateDelphiPaths('Software\CodeGear\BDS\7.0', 'Test Path', ToRemove, ToAdd);
    finally ToAdd.Free;
    end;
  finally ToRemove.Free;
  end;
end;

注意ToRemove和ToAdd。我可以在“删除”和“添加”列表中安全地指定搜索路径：仅当路径与“删除”条件匹配但不在“待添加”列表中时，它们才会被删除。还要注意PathMatchesRemoveCriteria功能。

您可能可以修改代码以直接从 InnoScript 本身工作，或者您可以将代码放在 DLL 中并使用安装程序中的 DLL。DLL 变体的优点是在 Delphi 中易于调试，在 Inno 本身上也很容易；Inno 变体的优点是没有外部依赖，但代码需要调整和调试。