17

这是一个使用 reactive-banana 库的 Haskell FRP 程序示例。我才刚刚开始对 Haskell 有所了解，尤其是还没有完全理解 FRP 的含义。我真的很感激对下面的代码的一些批评

{-# LANGUAGE DeriveDataTypeable #-}
module Main where

{-
Example FRP/zeromq app.

The idea is that messages come into a zeromq socket in the form "id state". The state is of each id is tracked until it's complete.
-}

import Control.Monad
import Data.ByteString.Char8 as C (unpack)
import Data.Map as M
import Data.Maybe
import Reactive.Banana
import System.Environment (getArgs)
import System.ZMQ

data Msg = Msg {mid :: String, state :: String}
    deriving (Show, Typeable)

type IdMap = Map String String

-- | Deserialize a string to a Maybe Msg
fromString :: String -> Maybe Msg
fromString s =
  case words s of 
    (x:y:[]) -> Just $ Msg x y
    _ -> Nothing

-- | Map a message to a partial operation on a map
-- If the 'state' of the message is "complete" the operation is a delete
-- otherwise it's an insert
toMap :: Msg -> IdMap -> IdMap
toMap msg = case msg  of
               Msg id_ "complete" -> delete id_ 
               _ -> insert (mid msg) (state msg) 

main :: IO ()
main = do
  (socketHandle,runSocket) <- newAddHandler

  args <- getArgs
  let sockAddr = case args of
        [s] -> s
        _ -> "tcp://127.0.0.1:9999"
  putStrLn ("Socket: " ++ sockAddr)


  network <- compile $ do
    recvd <- fromAddHandler socketHandle

    let
      -- Filter out the Nothings
      justs = filterE isJust recvd
      -- Accumulate the partially applied toMap operations
      counter = accumE M.empty $ (toMap . fromJust <$> justs)


    -- Print the contents  
    reactimate $ fmap print counter  

  actuate network

  -- Get a socket and kick off the eventloop
  withContext 1 $ \ctx ->
    withSocket ctx Sub $ \sub -> do
      connect sub sockAddr
      subscribe sub ""
      linkSocketHandler sub runSocket


-- | Recieve a message, deserialize it to a 'Msg' and call the action with the message
linkSocketHandler :: Socket a -> (Maybe Msg -> IO ()) -> IO ()
linkSocketHandler s runner = forever $ do 
  receive s [] >>= runner . fromString . C.unpack

这里有一个要点：https ://gist.github.com/1099712 。

我特别欢迎任何关于这是否是 accumE 的“好”使用的评论，（我不清楚这个函数每次都会遍历整个事件流，尽管我猜不是）。

此外，我想知道如何从多个套接字中提取消息 - 目前我在永远的内部有一个事件循环。作为一个具体的例子，我将如何添加第二个套接字（zeromq 用语中的 REQ/REP 对）来查询计数器内 IdMap 的当前状态？

4

1 回答 1

21

（反应香蕉的作者。）

总的来说，你的代码对我来说看起来不错。我实际上不明白你为什么首先使用反应香蕉，但你会有你的理由。也就是说，如果您正在寻找 Node.js 之类的东西，请记住 Haskell 的轻量级线程无需使用基于事件的架构。

附录：基本上，当您有各种不同的输入、状态和输出必须在正确的时间（想想 GUI、动画、音频）下协同工作时，函数式反应式编程很有用。相比之下，当您处理许多本质上独立的事件时，它就显得过分了。这些最好用普通函数和偶尔的状态来处理。

关于个别问题：

“我特别欢迎任何关于这是否是 accumE 的“好”使用的评论，（我不清楚这个函数每次都会遍历整个事件流，尽管我猜不是）。

在我看来很好。如您所料，该accumE功能确实是实时的；它只会存储当前的累积值。

从您的猜测来看，您似乎在想，每当有新事件出现时，它都会像萤火虫一样在网络中传播。虽然这确实发生在内部，但这不是您应该如何考虑函数式反应式编程。相反，正确的图片是这样的：结果fromAddHandler是输入事件的完整列表，因为它们将发生。换句话说，您应该认为它recvd包含未来每个事件的有序列表。（当然，为了您自己的理智，您不应该在它们的时间到来之前尝试查看它们。;-)） 该accumE函数只是通过遍历一个列表将其转换为另一个列表。

我需要在文档中使这种思维方式更加清晰。

“另外，我想知道如何从多个套接字中提取消息 - 目前我在一个永远的事件循环中。作为一个具体的例子，我将如何添加第二个套接字（一个 REQ/REP 对用 zeromq 的说法）查询计数器内 IdMap 的当前状态？”

如果receive函数没有阻塞，你可以简单地在不同的套接字上调用它两次

linkSocketHandler s1 s2 runner1 runner2 = forever $ do 
  receive s1 [] >>= runner1 . fromString . C.unpack
  receive s2 [] >>= runner2 . fromString . C.unpack

如果它确实阻塞，您将需要使用线程，另请参阅Real World Haskell 一书中的处理多个 TCP 流部分。（请随意提出一个新问题，因为它超出了这个问题的范围。）

于 2011-07-25T14:16:35.393 回答