autohotkey - 循环几个目录 AHK

Question

我需要从几个目录中获取 .csv 中的文件列表，我现在有这个脚本，我只需要添加更多目录，这可能吗？

FileList := "File FullPath,Base name,TimeLastModified"
Loop, \\DEFRA1SPDB054\Exports\*.*,0,1
If SubStr(A_LoopFileTimeCreated, 1, 8) = SubStr(A_Now, 1, 8) ;
{
  FormatTime, last_time_modified, %A_LoopFileTimeModified%, MM/dd/yyyy HH:mm:ss
  FileList .= "`n" . A_LoopFileFullPath . "," . A_LoopFileName . "," . last_time_modified
}
FileAppend,%FileList%,FileList.csv
Run, excel.exe "FileList.csv"

Answer 1

假设我正确理解了您的问题，例如，您可以这样做：

folders := "
(
C:\Users\User\Documents\My Cool Folder1
C:\Users\User\Documents\My Cool Folder2
C:\Users\User\Documents\My Cool Folder3
C:\Users\User\Documents\My Cool Folder4
)"

FileList := "File FullPath,Base name,TimeLastModified"

for each, folder in StrSplit(folders, "`n", "`r")
{
    Loop, Files, % folder "\*.*", FR
    {
        if (SubStr(A_LoopFileTimeCreated, 1, 8) = SubStr(A_Now, 1, 8))
        {
            FormatTime, last_time_modified, % A_LoopFileTimeModified, % "MM/dd/yyyy HH:mm:ss"
            FileList .= "`n" A_LoopFileFullPath "," A_LoopFileName "," last_time_modified
        }
    }
}

FileAppend, % FileList, % "FileList.csv"
Run, % "excel.exe ""FileList.csv"""

我只是简单地在字符串中定义了一些文件夹folders（使用延续部分^(docs)），然后遍历每个文件夹，将文件夹传递到文件循环^(docs)中。

此外，我从您的脚本中放弃了旧的语法/命令。
例如，您正在使用已弃用的文件循环，或者通过 legacy%variable%等引用变量。