awk - 将排序序数显示为列表中的计数

Question

我有以下输入文件

system info com1 command set
system info com2 command set 
system command set1 information description test
system command 21-22 information description pass
system command T1-T2-T3 information description file
system command commonset information description info

和以下命令

awk '/system command/&&/information description/ { gsub("\"","") ; print ++ OFS") Command = " $3}' inputfile.txt

给我以下输出

1) Command = set1
2) Command = 21-22
3) Command = T1-T2-T3
4) Command = commonset

有没有办法让我的命令列表计数不是简单的数字，而是排序序数并有这样的输出

1st) Command = set1
2nd) Command = 21-22
3rd) Command = T1-T2-T3
4th) Command = commonset

Answer 1

没有内置函数可以获取该序数。我们需要动手并编写以下代码：

awk 'function ordinal(i,   mod, str) {mod = i%10; str=i; if (i~/1[1-3]$/) str=str "th"; else if (mod==1) str=str "st"; else if (mod==2) str=str "nd"; else if (mod==3) str=str "rd"; else str=str "th"; return str;} /system command/&&/information description/ { gsub(/"/,"") ; print ordinal(++i) ") Command = " $3}' file

1st) Command = set1
2nd) Command = 21-22
3rd) Command = T1-T2-T3
4th) Command = commonset

扩展形式：

awk '
function ordinal(i,   mod, str) {
   mod = i%10
   str = i
   if (i~/1[1-3]$/)  # for numbers ending in 11, 12, 13
      str = str "th"
   else if (mod==1)
      str = str "st"
   else if (mod==2)
      str = str "nd"
   else if (mod==3)
      str = str "rd"
   else
      str = str "th"
   return str
}
/system command/&&/information description/ {
   gsub(/"/,"")
   print ordinal(++i) ") Command = " $3
}' file

实现上述功能的另一种方法是：

function ordinal(num,   idx, sfxs) {
   split("st nd rd th",sfxs," ")
   idx = ( (num ~ /[123]$/) && (num !~ /1[123]$/) ? num % 10 : 4 )
   return num sfxs[idx]
}