zoho - Zoho creator 与 zoho 图书的集成

Question

所以我最近开始使用 Zoho 平台，所以我对它很陌生，我被分配了以下任务：

在 zoho creator 上构建具有各种不同字段（名称、公司名称、帐单地址和一些额外的自定义字段）的客户表单。将表单中的数据集成到 zoho books 平台。

基本上，用户提交表单并在提交时在其创建的 zoho 书籍上创建新记录。

在此处输入图像描述

在此处输入图像描述

我的问题，当提交表单时，zoho book 上没有新客户。

有人能帮助我吗

谢谢你

Answer 1

cpList = List();
firstName = input.Contact_Name.first_name;
lastName = input.Contact_Name.last_name;
contactName = firstName + " " + lastName;
contactMap = Map();
contactMap.put("contact_name",contactName);
contactMap.put("company_name",input.Company_Name);
contactMap.put("website",input.Website);
billingMap = Map();
billingMap.put("zip",input.Billing_Address.postal_Code);
billingMap.put("country",input.Billing_Address.country);
billingMap.put("address",input.Billing_Address.address_line_1);
billingMap.put("street2",input.Billing_Address.address_line_2);
billingMap.put("city",input.Billing_Address.district_city);
billingMap.put("state",input.Billing_Address.state_province);
contactP = Map();
contactP.put("first_name",firstName);
contactP.put("last_name",lastName);
contactP.put("designation",input.Designation);
contactP.put("department",input.Department);
contactP.put("contact_salutation","Mr/Mrs");
contactP.put("mobile",input.Mobile_Phone);
contactP.put("phone",input.Phone_Number);
contactP.put("email",input.Email);
contactP.put("is_primary_contact",true);
contactMap.put("billing_address",billingMap);
cpList.add(contactP);
contactMap.put("contact_persons",cpList);
params = Map();
params.put("JSONString",contactMap);
createContact = invokeurl
[
    url :"https://books.zoho.eu/api/v3/contacts?organization_id="
    type :POST
    parameters:params
    connection:"books"
];

这是我能够使它工作的方式。

Answer 2

标题中可能需要包含“书籍”的身份验证令牌。查看 books.zoho API 文档，查看是否有关于创建和使用 API 令牌的信息。

此外，通过添加detailed:true到 invokeurl 调用，您可以了解来自 invokeurl 的响应中的任何信息或错误消息。这是一些示例代码：

response = invokeurl
[
    url : "https://books.zoho.eu/api/v3/contacts?orgainization_id=20077348839
    type :POST
    parameters:datamap
    connection:"books_contact_auth"
    detailed:true
];

// To see all headers and content
info response;