8

我正在尝试找到一种安全/确定的方式来释放封装在 OleVariant 中的接口。

AFAICS Delphi 在程序结束时释放接口引用，但在我的情况下，我必须提前这样做，因为我必须关闭 COM。

procedure Test;
var
  LLibrary: OleVariant;
begin
  CoInitialize(nil);
  try
    LLibrary := Null;
    try
      LLibrary := CreateOleObject(LibraryName);
    finally
      LLibrary := Unassigned; // <-- I would like to release the interface here
    end;
  finally
    CoUninitialize; // <-- Shutdown of COM
  end;
end; // <-- The compiler releases the interface here

我想把 OleVariant 放在一个额外的类实例中，我可以在调用之前释放它CoUninitialize。

procedure Test;
var
  Container: TLibraryContainer; // Holds the OleVariant
begin
  CoInitialize(nil);
  try
    Container := TLibraryContainer.Create;
    try
      {...}
    finally
      Container.Free;
    end;
  finally
    CoUninitialize;
  end;
end;

这个解决方案是安全的还是我忽略了更好的解决方案？

4

1 回答 1

9

编译器显然使用隐式本地接口变量作为CreateOleObject. 然后在例程结束时释放它，对你来说太晚了。

有几种方法可以解决这个问题。首先，您可以明确IDispatch说明CreateOleObject. 这使您可以控制其生命周期。

procedure Test;
var
  intf: IDispatch;
  LLibrary: OleVariant;
begin
  CoInitialize(nil);
  try
    intf := CreateOleObject(LibraryName);
    try
      LLibrary := intf;
    finally
      VarClear(LLibrary);
      intf := nil;
    end;
  finally
    CoUninitialize;
  end;
end;

另一种方法是将调用的代码移动CreateOleObject到具有自己范围的单独例程中。

procedure DoWork;
var
  LLibrary: OleVariant;
begin
  LLibrary := CreateOleObject(LibraryName);
  //do stuff with LLibrary
end;

procedure Test;
begin
  CoInitialize(nil);
  try
    DoWork;
  finally
    CoUninitialize;
  end;
end;

由于隐式本地引用在其范围内，因此在运行DoWork结束时释放。DoWorkCoUninitialize

我的建议是使用更简洁的第二个选项，并强制编译器代表您完成工作。

于 2011-07-19T10:41:51.293 回答