c++ - 如何使 CMakelists.txt 仅包含一些 *.c 和 *.h 文件用于一个操作系统？

Question

我想包含一些仅适用于 Windows 操作系统的 *.c 和 *.h 文件。但是我找不到不创建另一个目标的方法，这会导致错误

我想做这样的事情：

add_executable(${TARGET}
     main.cpp
     mainwindow.cpp
     mainwindow.h
     mainwindow.ui
if (WIN32)
     test.c
     test.h
endif()
)

有没有办法做到这一点？

Answer 1

现代 CMake 解决方案是使用target_sources.

# common sources
add_executable(${TARGET}
     main.cpp
     mainwindow.cpp
     mainwindow.h
     mainwindow.ui
)

# Stuff only for WIN32
if (WIN32)
    target_sources(${TARGET}
        PRIVATE test.c
        PUBLIC test.h
    )
endif()

这应该使您的CMakeLists.txt文件比争论变量更容易维护。

Answer 2

您可以为源文件列表使用一个变量，并将类似于以下的操作系统特定文件附加到该变量：

set( MY_SOURCES 
     main.cpp
     mainwindow.cpp
     mainwindow.h
     mainwindow.ui
)

if (WIN32) 
SET( MY_SOURCES ${MY_SOURCES} 
     test.c
     test.h
)
endif()

add_executable(${TARGET} ${MY_SOURCES})

Answer 3

除了使用if块之外，您还可以使用生成器表达式来约束源：

add_executable(${TARGET} PUBLIC
   main.cpp
   mainwindow.cpp
   mainwindow.h
   mainwindow.ui
   $<$<PLATFORM_ID:Windows>:
       test.c
       test.h
  >
)

target_sources如果您愿意，此方法也适用于命令。