1

我在使用 cmake 生成器表达式TARGET_NAME_IF_EXISTS时遇到问题。有了这个CMakeLists.txt：

cmake_minimum_required(VERSION 3.13.0)
option(SLIB_BUILD_STATIC "" ON)
project(slib VERSION 1.0)

add_library(slibObjects OBJECT main.c)
add_library(slib SHARED $<TARGET_OBJECTS:slibObjects>)

if (SLIB_BUILD_STATIC)                  # Can this if() be replaced with a GenExp?
  add_library(slibStatic STATIC $<TARGET_OBJECTS:slibObjects>)
endif()

set_target_properties(
    slib
    $<TARGET_NAME_IF_EXISTS:slibStatic> # This GenExp doesn't get reduced
  PROPERTIES
    VERSION ${SLIB_VERSION}
    SOVERSION ${SLIB_VERSION_MAJOR}
)

我明白了

CMake Error at CMakeLists.txt:12 (set_target_properties):
  set_target_properties Can not find target to add properties to:
  $<TARGET_NAME_IF_EXISTS:slibStatic>

我希望set_target_properties根据是否SLIB_BUILD_STATIC设置减少到其中之一：

set_target_properties( slib slibStatic PROPERTIES ...)
set_target_properties( slib PROPERTIES ...)

我究竟做错了什么？

4

1 回答 1

2

生成器表达式不是if命令的替代品

生成器表达式仅可用于某些属性和某些变量，因此可以在配置阶段结束时将它们评估为一个值，这取决于构建类型。这种行为无法通过普通方式实现，if因为多配置 CMake 生成器（如 Visual Studio）读取CMakeLists.txt一次但会创建多个配置。

生成器表达式也可用于设置这些属性和变量的命令。

生成器表达式的每种可能用法都在支持它们的命令/属性/变量的文档中明确说明。

命令set_target_properties的文档没有描述生成器表达式的用法，因此该命令根本不支持它们。

实际上，可以将生成器表达式作为属性的值传递给该命令。在这种情况下，该命令只会将该值分配给相应的属性。配置后评估属性时是否解析生成器表达式取决于属性。

但是无论是目标名称还是属性名称都不能是生成器表达式。

对于有条件地为目标设置属性，请使用 plain if：

# Unconditionally set properties for 'slib' target.
set_target_properties(
    slib
  PROPERTIES
    VERSION ${SLIB_VERSION}
    SOVERSION ${SLIB_VERSION_MAJOR}
)
# Set properties for 'slibStatic' target only if this target exist.
if (TARGET slibStatic)
  set_target_properties(
      slibStatic
    PROPERTIES
      VERSION ${SLIB_VERSION}
      SOVERSION ${SLIB_VERSION_MAJOR}
  )
endif()

为了避免复制粘贴属性的分配，您可以创建一个包含目标列表的变量，然后使用此变量：

# Variable which contain list of affected targets.
set(targets_for_version_set slib)
# Add target 'slibStatic' to the list only if the target exist

if (TARGET slibStatic)
  list(APPEND targets_for_version_set slibStatic)
endif()
# Now assign properties for all variables in the list
set_target_properties(
    ${targets_for_version_set}
  PROPERTIES
    VERSION ${SLIB_VERSION}
    SOVERSION ${SLIB_VERSION_MAJOR}
)
于 2021-04-20T22:30:30.157 回答