11

start 命令可以在批处理文件中启动像记事本这样的应用程序，如下所示：

start notepad
start "my love.mp3"

但是如何从命令行关闭正在运行的应用程序？我taskkill在搜索中找到了，但我认为这不是正确的命令，因为它不起作用——它说没有这样的文件。

如何关闭使用 启动的应用程序start？

4

2 回答 2

18

输入taskkill /?语法和一些示例。您要做的是/IM使用要杀死的程序的名称传递参数。例如：

TASKKILL /F /IM notepad.exe

将杀死notepad.exe。

TASKKILL /F /IM note*

将杀死所有以“note”开头的进程。

于 2011-07-15T11:01:56.407 回答
5

任务杀手是正确的。但是您必须终止播放文件的进程，而不是文件本身。从命令提示符中找出 mp3 文件的注册处理程序将有点棘手。

如果您知道它，那么您可以终止该过程。

这是一个脚本，它计算出 mp3 文件的注册应用程序并终止任务：

@echo off
if not .%1==. goto show

:createtemp
set tempfile="%temp%\temp-%random%-%time:~6,5%.bat"
if exist %tempfile% goto :createtemp

reg query HKEY_CLASSES_ROOT\mp3file\shell\play\command\ > %tempfile%

for /F "skip=4 delims=> tokens=2 usebackq" %%e in (`type %tempfile%`) do call %0 %%e

del %tempfile% > nul
set tempfile=
set handler=
set teststring=
set offset=
set cmd=
goto end

:show
set handler=%2
set handler=%handler:~1,-1%
set /A offset=-1

:loop
set cmd=set teststring=%%handler:~%offset%%%
echo %cmd% > %tempfile%
call %tempfile%
if %teststring:~0,1%==\ goto complete
set /A offset=offset-1
goto loop

:complete
set /A offset=offset+1
set cmd=set handler=%%handler:~%offset%%%
echo %cmd% > %tempfile%
call %tempfile%
taskkill /IM %handler% > nul

:end

如果您将其另存为killmp3.bat或其他内容，则可以在需要时调用它。当然要注意，如果程序已经在运行，正在做其他事情，无论如何它都会被关闭。

请注意，这在很大程度上取决于注册表中的条目是否将可执行路径包含在双引号中。如果你没有那个并且可执行文件名中有空格，它将失败。

您可以概括我的技术，以便能够传入文件扩展名（例如.mp3，您可以在注册表中查找以找到类名mp3file，然后从那里找到处理程序。

一个更通用的解决方案，采用您启动的文件的名称并从中计算出扩展名，理论上是可行的，但要困难得多。如果notepad您必须通过搜索所有可执行文件的路径等来弄清楚那是什么。

如果您创建了一个可以启动的极短 mp3 文件，这可能会更简单。根据程序的不同，它可能会停止播放当前文件并切换到新文件，这几乎会立即结束并有效地停止播放。

于 2011-07-15T05:02:04.237 回答