opengl - 在OpenGL中将三角形更改为圆形

Question

很多时候，我尝试在 vertexShader.glsl 中将三角形点更改为圆形，但没有成功。我会要求您重写代码，以便程序绘制圆形而不是三角形吗？

所以vertexShader代码：

uniform float offsetX;
uniform float offsetY;

void main(void)
{

    if(gl_VertexID == 0) gl_Position = vec4(0.25 + offsetX, -0.25 + offsetY, 0.0, 1.0);
    else if(gl_VertexID == 1) gl_Position = vec4(-0.25 + offsetX, -0.25 + offsetY, 0.0, 1.0);
    else gl_Position = vec4(0.0 + offsetX, 0.25 + offsetY, 0.0, 1.0);
}

Answer 1

一种选择是在片段着色器中绘制三角形的内圆。

计算三角形内心的坐标和半径。请参阅三角形的内圆和外圆并将其传递给片段着色器：

#version 150

uniform float offsetX;
uniform float offsetY;

out vec2 v_pos;
out vec2 center;
out float radius;

void main(void)
{
    vec2 pts[3] = vec2[3](
       vec2(0.25, -0.25),
       vec2(-0.25, -0.25),
       vec2(0.0, 0.25));

    v_pos = pts[gl_VertexID] + vec2(offsetX, offsetY);

    float a = distance(pts[1], pts[2]); 
    float b = distance(pts[2], pts[0]); 
    float c = distance(pts[0], pts[1]); 

    center = (pts[0] * a + pts[1] * b + pts[2] * c) / (a+b+c) + vec2(offsetX, offsetY);
    float s = (a + b + c) / 2.0;
    radius = sqrt((s - a) * (s - b) * (s - c) / s);

    gl_Position = vec4(v_pos, 0.0, 1.0);
}

discard片段着色器内圆外的点：

#version 150

out vec4 out_color;

in vec2 v_pos;
in vec2 center;
in float radius;

void main(void)
{
    if (distance(v_pos, center) > radius)
    {
        discard;

        // debug
        //out_color = vec4(0.5, 0.5, 0.5, 1.0);
        //return;
    }
    out_color = vec4(1.0, 0.0, 0.0, 1.0);
}