5

我想写一个文本界面，它提供了一些默认的命令。该程序支持这些命令的制表符完成。

该程序还记录用户输入并将其存储在StateData. 现在我希望这个程序支持这些用户输入的选项卡完成。例如：

*Main > main
> read a<tab> -- press tab and no suggestions (read is a default command)
> read abcde
...
> read a<tab> -- press tab
abcde         -- suggestions

是否可以在不使用不安全机制的情况下做到这一点IORef？有没有办法将更新st从loop(in repl) 传递到replSettings startState(in repl)？

我是 Haskeline 的新手，感谢您的宝贵时间。

repl :: StateData -> IO()
repl startState                    =  runInputT (replSettings startState) $ loop startState
  where
    loop :: StateData              -> InputT IO ()
    loop st                        =  do
      inputL                       <- getInputLine "> "
      case inputL                  of
           Nothing                 -> return ()
           Just "quit"             -> outputStrLn "--Exited--" >> return ()
           Just ipt                -> do (opt, st')     <- process ipt `runStateT` st
                                         ...
                                         loop st'

replSettings :: StateData -> Settings IO
replSettings st =
  Settings
    { complete       = replCompletion st,
      historyFile    = Just "history.txt",
      autoAddHistory = True
    }

replCompletion :: StateData -> CompletionFunc IO
replCompletion st = completeWordWithPrev Nothing [' '] st (\x y -> return $ completionGenerator x y)

completionGenerator :: String -> String -> StateData -> [Completion]
completionGenerator "" c st = 
  commandSuggestion c (updatesSuggestions st) -- I wish to update it at run time
completionGenerator p  c st = ...
4

1 回答 1

5

IORef不是不安全的；您已经在 中IO，因此这是在此处添加可变状态的一种非常合理的方式。

但是如果你想避免IO，你可以简单地使用StateT StateData IO作为底层的 monad InputT，从而在Settings. 看来你已经在尝试使用StateT了。这是一个完整的示例，它只是将每个条目添加到列表中并天真地自动完成它们：

import Control.Monad.Trans.Class (lift)
import Control.Monad.Trans.State (StateT, evalStateT, get, modify)
import Data.List (isPrefixOf)
import System.Console.Haskeline

type StateData = [String]

main :: IO ()
main = repl []

repl :: StateData -> IO ()
repl startState
  = flip evalStateT startState
  $ runInputT replSettings loop
  where
    loop :: InputT (StateT StateData IO) ()
    loop = do
      inputL <- getInputLine "> "
      case inputL of
        Nothing -> pure ()
        Just "quit" -> outputStrLn "--Exited--"
        Just ipt -> do
          -- Just add each entry to the state directly.
          lift $ modify (ipt :)
          loop

replSettings :: Settings (StateT StateData IO)
replSettings = Settings
  { complete       = replCompletion
  , historyFile    = Just "history.txt"
  , autoAddHistory = True
  }

replCompletion :: CompletionFunc (StateT StateData IO)
replCompletion = completeWordWithPrev Nothing " " completionGenerator

completionGenerator :: String -> String -> StateT StateData IO [Completion]
completionGenerator prefix suffix = do
  st <- get
  -- Trivial completion that just ignores the suffix.
  pure $ fmap (\ s -> Completion s s True)
    $ filter (prefix `isPrefixOf`) st

完成生成器也可以使用MonadState(from mtl) 编写，以使其无法访问IO，并且其他代码同样可以使用这种纯状态，同时不知道IO. 但除此之外，由于您已经IO在此代码中，StateT StateData IO//与get//没有什么modify不同。ReaderT (IORef StateData) IOreadIORefmodifyIORef

事实上，如果你在你的代码中加入一个IORef in StateData，假设它是一个更复杂的记录类型，那么后者是一个很好的方法，可以使它的某些部分可变而其他部分不可变。

data StateData = StateData
  { mutableThing   :: !(IORef Thing)
  , immutableStuff :: !Stuff
  …
  }
于 2021-03-29T19:31:20.027 回答