1

我是 CMake 的新手，我想知道是否有可能target_sources()根据变量排除某些来源。

假设我在下面有这个

target_sources(myTarget
    PUBLIC
    PRIVATE
        myDir1/src/a.c
        myDir2/src/b.c
        myDir3/src/c.c      
    INTERFACE
)

target_include_directories(myTarget
    PUBLIC
    PRIVATE       
        myDir1/inc
        myDir2/inc
        myDir3/inc  
    INTERFACE
)

我想根据名为 ie 的标志从 myDir3 中排除/包含源/目录myFlag。我怎样才能做到这一点？

target_sources(myTarget
    PUBLIC
    PRIVATE
        myDir1/src/a.c
        myDir2/src/b.c
        if(DEFINED myFlag)
           myDir3/src/c.c
        endif()
    INTERFACE
)

target_include_directories(myTarget
    PUBLIC
    PRIVATE        
        myDir1/inc
        myDir2/inc
        if(DEFINED myFlag)
           myDir3/inc  
        endif()
    INTERFACE
)
4

2 回答 2

4

您不能将 if 语句放在命令的参数列表中。target_*命令不会覆盖，而是追加，因此最简单的解决方案如下：

target_sources(
  myTarget
  PRIVATE
    myDir1/src/a.c
    myDir2/src/b.c 
)
if (myFlag) 
  target_sources(myTarget PRIVATE myDir3/src/c.c)
endif ()

target_include_directories(
  myTarget
  PRIVATE
    myDir1/inc
    myDir2/inc
)
if (myFlag) 
  target_include_directories(myTarget PRIVATE myDir3/inc)
endif ()

另一个更具声明性的选项是使用生成器表达式，如下所示：

target_sources(
  myTarget
  PRIVATE
    myDir1/src/a.c
    myDir2/src/b.c
    $<$<BOOL:${myFlag}>:myDir3/src/c.c>
)
于 2021-03-25T10:13:42.310 回答
1

根据您尝试这样做的原因，将它们保留为源文件也可能有意义（因此它们显示在例如 Visual Studio 的目标视图中），但将它们标记为标头以便它们不会被编译：

if (NOT myFlag)
  set_source_files_properties(
      srcfile1.cpp
      srcfile2.cpp
    PROPERTIES
      HEADER_FILE_ONLY ON
  )
endif()

为此目的，CMake 的文档甚至建议这样做：

如果您有一些以某种方式预处理的源文件，然后通过 add_library() 或 add_executable() 添加这些预处理的源，这将很有用。通常，在 IDE 中，不会引用原始源，只有这些预处理源。因此，通过将所有原始源文件的此属性设置为 ON，然后在传递预处理源和原始源的同时调用 add_library() 或 add_executable()，或者使用 target_sources() 添加原始源文件将完全按照人们的期望去做，即原始源文件将在 IDE 中可见，并且不会被构建。

于 2021-03-25T20:24:38.993 回答