3

使用Allegrograph，Prolog 函子非常棒，但有一个缺点。

假设您定义了一个链接两个实体的函子，例如parentOf等于“ ！n:motherOf OR !n:fatherOf ”，它们都是在您的本体中定义的 rdf 对象属性（不是函子）。

让我们定义三元组“A ！n:fatherOf B”。由于“ parentOf ”是函子而不是 rdf 对象属性，如果您请求链接 A 和 B 的所有属性，您将仅获得三元组“A !n:fatherOf B”（而不是“A parent B”）。

知道 A 是否是 B 的父级的唯一方法是直接询问布尔问题。

所以我的问题是：如何轻松获得“获得由函子生成的 FACTS + INFERRED FACTS 组成的 RDF 三元组”的结果？

4

2 回答 2

2

Prolog 函子是 Prolog 程序的一部分。当您使用 Prolog 在 AllegroGraph 存储上编写查询时，您实际上是在编写一个 Prolog 程序，该程序为程序中表达的约束导出一组答案。

parentOf不是商店的一部分，它是程序的一部分。

您要做的是将 Prolog 程序所隐含的知识具体化，以便它以与基本三元组相同的形式可用。

为此，您需要编写一个... Prolog 程序，该程序导出推断的知识并将其添加到存储中。

这是一些应该有帮助的代码。这是 Lisp 中的一些设置和示例，但 Prolog 函子应该是显而易见的。

;; Assume the prefix is set up. These are for the Lisp environment.
(register-namespace "ex" "http://example.com/")
(enable-!-reader)

;; Define functors for basic relationships.
(<-- (parent ?x ?y)  
     (father ?x ?y))  

(<- (parent ?x ?y)  
    (mother ?x ?y))  

(<-- (male ?x)  
     (q- ?x !ex:sex !ex:male))  

(<-- (female ?x)  
     (q- ?x !ex:sex !ex:female))  

(<-- (father ?x ?y)  
     (male ?x)  
     (q- ?x !ex:has-child ?y))  

(<-- (mother ?x ?y)  
     (female ?x)  
     (q- ?x !ex:has-child ?y)) 

;; Functors for adding triples.
(<-- (a- ?s ?p ?o)
 ;; Fails unless all parts ground.
 (lisp (add-triple ?s ?p ?o)))

(<-- (a- ?s ?p ?o ?g)
 ;; Fails unless all parts ground.
 (lisp (add-triple ?s ?p ?o ?g)))

(<-- (a-- ?s ?p ?o)
 ;; Fails unless all parts ground.
 (lispp (not (get-triple :s ?s :p ?p :o ?o)))
 (lisp (add-triple ?s ?p ?o)))

(<-- (a-- ?s ?p ?o ?g)
 ;; Fails unless all parts ground.
 (lispp (not (get-triple :s ?s :p ?p :o ?o :g ?g)))
 (lisp (add-triple ?s ?p ?o ?g)))

;; Add some sample data.
(create-triple-store "/tmp/foo")
(add-triple !ex:john !ex:sex !ex:male)
(add-triple !ex:dave !ex:sex !ex:male)
(add-triple !ex:alice !ex:sex !ex:female)
(add-triple !ex:alice !ex:has-child !ex:dave)
(add-triple !ex:john !ex:has-child !ex:dave)

;; Now who is a parent of whom?
(select (?parent ?child)
  (parent ?parent ?child))

;; Returns:
;; (("http://example.com/john" "http://example.com/dave")
;;  ("http://example.com/alice" "http://example.com/dave"))

;; Add the triples.
(select (?parent ?child)    ; never succeeds
  (parent ?parent ?child)
  (a-- ?parent !ex:parentOf ?child)
  (fail))

;; Now see what's in the store using the materialized triples.
(select (?parent ?child)
  (q- ?parent !ex:parentOf ?child))

;; Returns:
;; (("http://example.com/john" "http://example.com/dave")
;;  ("http://example.com/alice" "http://example.com/dave"))
于 2011-07-14T19:31:31.983 回答
0

你想要这样的东西吗？

(<-- (parentOf ?a ?b)
    (or
        (q ?a !n:fatherOf ?b)
        (q ?a !n:motherOf ?b)))

(select (?a ?b)
    (parentOf ?a ?b))

select 语句将返回涉及 n:fatherOf 或 n:motherOf 的三元组。

于 2012-06-05T17:47:37.377 回答