spring-boot - 如何导入具有spring cloud vault客户端依赖的本地外部jar

Question

我有一个名为“utils”的“多模块”Gradle 项目。在那，我创建了一个新的子项目，将用作 Hashicorp 的 Vault 的客户端。我将使用这个 jar 作为我的 Spring Boot 微服务的依赖项。

目标是为 Vault 提供一个通用配置并在所有服务中使用它。

我的问题是，当我尝试在我VaultTemplate的一个 Spring Boot 微服务（比如）中自动连接对象（假设它将从这个 jar 中添加）时secrets-management-service，我无法实现这一点。

出于开发目的，我将 jar 包含为本地依赖项。我已经包含了这两个build.gradle文件。

外部罐子：vault-client

group = 'com.example.learning'
version = '1.0.0-SNAPSHOT'

buildscript {
    ext {
        springVersion = '2.4.4'
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${springVersion}"
    }
}

apply plugin: 'java-library'
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'

sourceCompatibility = '1.8'

ext {
    springCloudVersion = '2020.0.2'
}

repositories {
    mavenCentral()
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}


dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
    }
}

dependencies {
    implementation 'org.springframework.cloud:spring-cloud-starter-vault-config'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

test {
    useJUnitPlatform()
}

微服务：secrets-management-service

plugins {
    id 'org.springframework.boot' version '2.4.3'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
}

group = 'com.example.learning'
version = ''
sourceCompatibility = '1.8'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

bootJar {
    setArchivesBaseName("secret-management-service")
    version("")
}

dependencies {
    compile fileTree(dir: "${projectDir}/libs", include: "*.jar")
    implementation 'org.springframework.boot:spring-boot-starter-web'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

test {
    useJUnitPlatform()
}

Answer 1

我自己找到了。我错过了vault-client罐子里的下面的块，也忘了删除“主”类。

bootJar {
    enabled = false
}