0

我正在使用 Terraform 创建一组 CloudWatch 警报，如下所示：

resource "aws_cloudwatch_metric_alarm" "lambda_concurrent_executions" {
  for_each = toset(var.function_names)

  alarm_name          = "${each.key}-concurrent-executions"
  alarm_description   = "The number of function instances that are processing events."
  namespace           = "AWS/Lambda"
  metric_name         = "ConcurrentExecutions"
  comparison_operator = "GreaterThanOrEqualToThreshold"
  statistic           = "Sum"
  period              = "60"
  evaluation_periods  = "1"
  threshold           = "100"

  treat_missing_data = "ignore"

  dimensions = {
    FunctionName = each.key
  }

  alarm_actions = var.alarm_actions
  ok_actions    = var.alarm_actions
}

所以它使用for_each函数名称列表。

接下来，我需要创建一个 CloudWatch 仪表板。它显然是通过提供具有相关名称（文档）的 JSON 来创建的：

resource "aws_cloudwatch_dashboard" "main" {
  dashboard_name = "my-dashboard"

  dashboard_body = <<EOF
{
    "widgets": [
        {
            "type": "alarm",
            "x": 0,
            "y": 0,
            "width": 12,
            "height": 6,
            "properties": {
                "title": "Alarms",
                "alarms": [
                    "arn:aws:cloudwatch:eu-west-1:167170067742:alarm:mylambda-concurrent-executions",
                    "arn:aws:cloudwatch:eu-west-1:167170067742:alarm:mylambda-concurrent-executions-2",
                    "arn:aws:cloudwatch:eu-west-1:167170067742:alarm:mylambda-concurrent-executions-3",
                    "arn:aws:cloudwatch:eu-west-1:167170067742:alarm:mylambda-concurrent-executions-4",
   
/// ... and so on
}
EOF
}

如何在变量中收集创建的警报 ARN 并将其插入仪表板 JSON？

4

1 回答 1

1

你需要一个for循环你的aws_cloudwatch_metric_alarm资源。

我用以下方法模拟了您的设置：

variable "function_names" {
  type    = list(string)
  default = ["fun-1", "fun-2", "fun-3"]
}

resource "null_resource" "lambda_concurrent_executions" {
  for_each = toset(var.function_names)

  triggers = {
    function_name = each.key
  }
}

然后这样的事情使我能够循环for_each生成的资源：

join(", ", [for i in null_resource.lambda_concurrent_executions : format("\"%s\"", i.id)])

因此，对于您的示例，您需要警报 ARN 的部分将变为：

"alarms": [${join(", ", [for a in aws_cloudwatch_metric_alarm.lambda_concurrent_executions : format("\"%s\"", a.arn)])}]

（顺便说一句。它也应该与splat 表达式一起使用，但我只能使其与传统的for-loop 一起使用。）

于 2021-03-16T18:01:25.543 回答