13

因此，当用户发送注册帐户的请求时，他们会发送用户名、密码、电子邮件和其他信息。注册功能必须验证他们的所有数据。一个例子是：

  • 验证未使用的电子邮件
  • 验证用户名未使用
  • 验证用户名是字母数字
  • 验证所有字段的长度都超过 X 个字符
  • 验证所有字段的长度小于 Y 个字符

现在我不想有一个 5 级深的 if 或 case 语句，但我还有什么其他选择？将其拆分为单独的函数听起来是个好主意，但是我只需要在某种条件下检查函数的返回值，它就会回到最初的问题。

我可以将它们分成函数，然后调用一个带有所有条件 OR 的 if 语句，但这不会给我想要的东西，因为如果有一个错误，我需要能够告诉用户特定的错误。

在 erlang 中如何处理这种情况？是否有等效的 return 语句，或者它必须是函数中的最后一个可执行行才能成为返回值？

4

4 回答 4

35

Joe Armstrong 的建议之一：将程序成功案例代码与错误处理分开。你可以这样做

create_user(Email, UserName, Password) ->
  try
    ok = new_email(Email),
    ok = valid_user_name(UserName),
    ok = new_user(UserName),
    ok = strong_password(Password),
    ...
    _create_user(Email, UserName, Password)
  catch
    error:{badmatch, email_in_use} -> do_something();
    error:{badmatch, invalid_user_name} -> do_something();
    error:{badmatch, user_exists} -> do_something();
    error:{badmatch, weak_password} -> do_something();
    ...
  end.

请注意，您可以从更好的 create_user 函数中捕获所有错误。

create_user(Email, UserName, Password) ->
    ok = new_email(Email),
    ok = valid_user_name(UserName),
    ok = new_user(UserName),
    ok = strong_password(Password),
    ...
    _create_user(Email, UserName, Password).

main() ->
  try
    ...
    some_function_where_create_user_is_called(),
    ...
  catch
    ...
    error:{badmatch, email_in_use} -> do_something();
    error:{badmatch, invalid_user_name} -> do_something();
    error:{badmatch, user_exists} -> do_something();
    error:{badmatch, weak_password} -> do_something();
    ...
  end.

模式匹配是 Erlang 中最酷的事情之一。请注意，您可以将您的标签包含在错误匹配错误中

{my_tag, ok} = {my_tag, my_call(X)}

和自定义数据

{my_tag, ok, X} = {my_tag, my_call(X), X}

如果异常对您来说足够快取决于您的期望。在我的 2.2GHz Core2 Duo Intel 上的速度：一秒钟内大约 200 万次异常（0.47us）与 600 万次成功（外部）函数调用（0.146us）相比——可以猜测异常处理大约需要 0.32us。在本机代码中，它是每秒 6.8 对 4700 万，处理可能需要大约 0.125us。try-catch 构造可能会有一些额外的成本，在本机和字节码中成功调用函数的成本约为 5-10%。

于 2009-03-21T10:10:40.470 回答
4 
User = get_user(),

Check_email=fun(User) -> not is_valid_email(User#user.email) end,
Check_username=fun(User) -> is_invalid_username(User#user.name) end,

case lists:any(fun(Checking_function) -> Checking_function(User) end, 
[Check_email, Check_username, ... ]) of
 true -> % we have problem in some field
   do_panic();
 false -> % every check was fine
   do_action()
 end

所以它不再是5级深了。对于真正的程序，我猜你应该使用 lists:foldl 从每个检查函数中累积错误消息。因为现在它简单地说“一切都好”或“有些问题”。

请注意，通过这种方式添加或删除检查条件并不是什么大问题

对于“是否有等效的 return 语句......” - 查看 try catch throw 语句，在这种情况下 throw 的行为类似于 return 。

于 2009-03-20T14:03:26.533 回答
0

以@JLarky 的回答为基础，这是我想出的。它还从 Haskell 的 monads 中汲取了一些灵感。

-record(user,
    {name :: binary(), 
     email :: binary(), 
     password :: binary()}
).
-type user() :: #user{}.
-type bind_res() :: {ok, term()} | {error, term()} | term().
-type bind_fun() :: fun((term()) -> bind_res()).


-spec validate(term(), [bind_fun()]) -> bind_res().
validate(Init, Functions) ->
    lists:foldl(fun '|>'/2, Init, Functions).

-spec '|>'(bind_fun(), bind_res())-> bind_res().
'|>'(F, {ok, Result}) -> F(Result);
'|>'(F, {error, What} = Error) -> Error;
'|>'(F, Result) -> F(Result).

-spec validate_email(user()) -> {ok, user()} | {error, term()}. 
validate_email(#user{email = Email}) ->
...
-spec validate_username(user()) -> {ok, user()} | {error, term()}.
validate_username(#user{name = Name}) ->
...
-spec validate_password(user()) -> {ok, user()} | {error, term()}.    
validate_password(#user{password = Password}) ->
...

validate(#user{...}, [
    fun validate_email/1,
    fun validate_username/1,
    fun validate_password/1
]).
于 2019-07-13T04:59:59.390 回答
-3

也许你需要使用

receive
    message1 -> code1;
    message2 -> code2;
    ...
end.

但是，当然会有 spawn() 方法。

于 2013-05-05T07:47:59.110 回答