0

我load-path使用包后缀 -0.13.1 为 Ivy 定制：

(add-to-list 'load-path "~/.zeroemacs/elpa/ivy-0.13.1/")

但是，当 ivy 包升级到 0.14.1 时，我不得不手动修改load-path为

(add-to-list 'load-path "~/.zeroemacs/elpa/ivy-0.14.1/")

ivy-*是否可以用匹配任何序列号的东西替换它？

4

1 回答 1

1

版本号有多种形状和大小。下面的函数不是尝试处理任何和所有版本格式，而是latest-file-version依赖于比较函数接受的版本字符串version-to-list。的文档version-to-list包括对它接受的内容的描述：

版本语法由以下 EBNF 给出：

版本 ::= 编号（分隔符编号）*。

数字 ::= (0|1|2|3|4|5|6|7|8|9)+。

SEPARATOR ::= 'version-separator' (见)
| 'version-regexp-alist'（见）。

如果 SEPARATOR 与 'version-regexp-alist' 中的元素匹配，则 NUMBER 部分是可选的。

您可以像这样在设置中使用该latest-file-version功能load-path：

(add-to-list 'load-path (latest-file-version "~/.zeroemacs/elpa" "ivy"))

第一个参数是要检查的目录，第二个参数是要检查的版本化文件名或目录名的前缀。

(defun latest-file-version (dir prefix)
  "Get the latest version of files in DIR starting with PREFIX.
Only filenames in DIR with the form PREFIX-version are
considered, where the version portion of the filename must have
valid version syntax as specified for `version-to-list'. Raise an
error if no filenames in DIR start with PREFIX or if no valid
matching versioned filenames are found."
  (let* ((vsn-regex (concat "^" prefix "-\\(.+\\)$"))
         (vsn-entries
          (seq-reduce
           #'(lambda (acc s)
               (if (string-match vsn-regex s)
                   (let* ((m (match-string 1 s))
                          (vsn (condition-case nil
                                   (version-to-list m)
                                 (error nil))))
                     (if vsn
                         (cons (cons m s) acc)
                       acc))
                 acc)) 
           (directory-files dir nil nil t) nil)))
    (if vsn-entries
        (concat (file-name-as-directory dir)
          (cdar (sort vsn-entries
                      #'(lambda (v1 v2)
                          (version<= (car v2) (car v1))))))
      (error "No valid versioned filenames found in %s with prefix \"%s-\""
             dir prefix))))

使用 emacs 27.1 测试。

于 2021-03-02T13:11:41.197 回答