kotlin - 如何使用 kotlin kotest 定位 js？

Question

我一直在尝试在 kotlin 多平台项目中设置 kotest。在 kotest 入门指南中，它说要将此依赖项添加到commonTest

implementation 'io.kotest:kotest-framework-engine:$version'

不幸的是，这并没有解决

Could not resolve io.kotest:kotest-framework-engine:4.4.1.
Required by:
    project :**strong text**

如果仅添加此依赖项即可jvmTest解决。我找不到任何为多平台设置 kotest 的指南。

Answer 1

kotest 似乎还不支持 Kotlin 编译器的 JS IR 后端。这是kotest 问题 2037。如果您为 JS 多平台设置配置 LEGACY 编译器后端，它应该可以工作。

当您在每个部分中选择最右边的选项卡（“多平台”）时， Kotest 的快速入门文档实际上涵盖了多平台配置。

这些是脚本中的相关部分，该build.gradle.kts脚本将 kotest 与 JVM 上的 IR 后端以及 JS 上的 LEGACY 后端一起使用：

val kotestVersion = "4.4.1"

kotlin {
    jvm("backend") {
        compilations.all {
            kotlinOptions.useIR = true
        }
        withJava()
    }
    js("frontend", LEGACY) {
        browser {
            binaries.executable()
            testTask {
                useKarma {
                    useChromeHeadless()
                    webpackConfig.cssSupport.enabled = true
                }
            }
        }
    }
    sourceSets {
        val commonTest by getting {
            dependencies {
                implementation("io.kotest:kotest-framework-engine:$kotestVersion")
                implementation("io.kotest:kotest-assertions-core:$kotestVersion")
                implementation("io.kotest:kotest-property:$kotestVersion")
            }
        }
        val backendTest by getting {
            dependencies {
                implementation("io.kotest:kotest-runner-junit5:$kotestVersion")
            }
        }
    }
}

tasks {
    // Tests
    withType<Test> {
        useJUnitPlatform()
    }
}