3

我是 Haskell 和 Megaparsec 库的初学者。在解析一行文本时，我需要解析行中剩余的文本，直到行尾（LF 或 CRLF）。我的想法是使用some，noneOf但即使在 GHCi 中测试后也无法编译代码，如下所示：

λ> import Data.Text (Text, pack)
λ> import Data.Void
λ> import Text.Megaparsec as M
λ> import Text.Megaparsec.Char as M
λ> import qualified Text.Megaparsec.Char.Lexer as L
λ> type Parser = Parsec Void Text
λ> 
λ> parse (some (noneOf "\r\n")) "" (pack "a line of text\r\n")
Right "a line of text"
λ> parse (some (noneOf "\r\n")) "" (pack "a line of text\n")
Right "a line of text"

所以解析器(some (noneOf "\r\n"))编译成功并返回我所期望的：“一行文本”，不包括行尾字符。但是，我无法在源文件中编译以下代码

pLineValue :: Parser Text
pLineValue = do
    str <- (some (noneOf "\r\n"))
    return (pack str)

编译器给出以下错误：

    • Ambiguous type variable ‘f0’ arising from a use of ‘noneOf’
      prevents the constraint ‘(Foldable f0)’ from being solved.
      Probable fix: use a type annotation to specify what ‘f0’ should be.
      These potential instances exist:
        instance Foldable (Either a) -- Defined in ‘Data.Foldable’
        instance Foldable Maybe -- Defined in ‘Data.Foldable’
        instance Foldable ((,) a) -- Defined in ‘Data.Foldable’
        ...plus one other
        ...plus 37 instances involving out-of-scope types
        (use -fprint-potential-instances to see them all)
    • In the first argument of ‘some’, namely ‘(noneOf "\r\n")’
      In a stmt of a 'do' block: str <- (some (noneOf "\r\n"))
      In the expression:
        do str <- (some (noneOf "\r\n"))
           return (pack str)
   |
78 |     str <- (some (noneOf "\r\n"))
   |                   ^^^^^^^^^^^^^

我究竟做错了什么？源文件中的正确语法是什么？还是有更好的方法来解析剩余的文本，但不包括 LF 或 CRLF 结尾？我会很感激任何帮助，谢谢。

4

2 回答 2

2

似乎您的符号之一并非来自您期望的地方。但是，很难准确判断问题出在哪里，因为您只提供了一部分编译代码，而不是独立的代码。

https://stackoverflow.com/help/minimal-reproducible-example

正如 Silvio Mayolo 的评论中提到的，编译器似乎无法看到它"\r\n"是一个String对象，因此是一个Chars 的列表，因此是一个类的实例Foldable。

 λ> 
 λ> :type M.noneOf
M.noneOf
  :: (Foldable f, MonadParsec e s m) => f (Token s) -> m (Token s)
 λ>

下面的代码非常相似，但可以完美地编译（和运行）：

import  Data.Text (Text, pack, unpack)
import  Data.Void
import  qualified  Text.Megaparsec  as  M

type MyParser = M.Parsec Void Text

pLineValue :: MyParser Text
pLineValue = do
    str <- (M.some (M.noneOf "\r\n"))
    return (pack str)


main :: IO ()
main = do
    let resT = M.parse pLineValue "-" (pack "a line of text\r\n")
        resS = case resT of
                 Right txt  ->  unpack txt
                 Left  _    ->  "ERROR"
    putStrLn $ "resS = " ++ resS
于 2021-02-23T11:48:25.370 回答
1

noneOf采用任意Foldable容器：

noneOf :: (Foldable f, MonadParsec e s m) => f (Token s) -> m (Token s)

"\r\n"通常是 a String，它是 的列表Char：

> :t "\r\n"
"\r\n" :: [Char]

> :i String
type String = [Char]    -- Defined in ‘GHC.Base’

但是，如果您已OverloadedStrings启用，"\r\n"则可以是任何IsString实例：

> :set -XOverloadedStrings
> :t "\r\n"
"\r\n" :: IsString p => p

因此调用noneOf是模棱两可的，因为容器的类型没有被固定：

> :t noneOf "\r\n"
noneOf "\r\n"
  :: (Foldable f, MonadParsec e s m,
      IsString (f (Token s))) =>
     m (Token s)

简单的解决方案是添加类型注释：

> :t noneOf ("\r\n" :: [Char])
noneOf ("\r\n" :: [Char])
  :: (MonadParsec e s m, Token s ~ Char) => m (Token s)

Foldable您可以使用任何- 或 -Traversable多态函数（如maximumor ）来观察这一点sum。

或者，您可以改用显式列表：

> :t noneOf ['\r', '\n']
noneOf ['\r', '\n']
  :: (MonadParsec e s m, Token s ~ Char) => m (Token s)

但请注意，如果您已OverloadedLists启用，这将具有相同类型的欠约束类型问题：

> :set -XOverloadedLists
> :t noneOf ['\r', '\n']
noneOf ['\r', '\n']
  :: (Foldable f, MonadParsec e s m,
      IsList (f (Token s)),
      Item (f (Token s)) ~ Char) =>
     m (Token s)

如果您在源文件和 GHCi 之间遇到更多奇怪的差异，这通常归结为 GHCi 为方便起见而使用的差异，例如“扩展默认规则”，因此在这种情况下尝试:set -XNoExtendedDefaultRulesvs.:set -XExtendedDefaultRules有时会有所帮助。

于 2021-02-23T18:45:50.920 回答