delphi - 如何在按钮单击时将组件动态添加到另一个下方？

Question

我创建了一个 TScrollBox。我在按钮单击时动态添加了标签和编辑框。为了设置组件的位置，我使用了组件的 height,width,left,top 属性。但是当添加了 5 个组件后，滚动条出现在屏幕上时，下一个组件的位置就会受到干扰。并且下一个组件不会以同步的方式放置在 ScrollBox 上。

Answer 1

放置在 ScrollBox 上的控件的Top坐标需要考虑已经发生的“滚动”量。如果一次添加所有控件，这不是问题，因为 ScrollBox 没有机会“滚动”。

如果在 ScrollBox有机会“滚动”后将控件添加到它，则需要考虑发生的垂直“滚动”量。这是一个示例代码，它将向 中添加标签ScrollBox1，考虑到垂直滚动，因此控件不会相互重叠。在这里，我使用表单的“Tag”属性来保存Top添加的下一个控件，并且我还Tag用于为标签生成唯一名称（因此您可以看到它们在正确的坐标处进入 ScrollBox） .

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Tag + ScrollBox1.VertScrollBar.Size - ScrollBox1.VertScrollBar.Position;
  Tag := Tag + L.Height;
end;

我有时使用的另一种方法是跟踪最后添加的控件，并将新控件的坐标基于最后添加的控件的坐标：

var LastControl: TControl;

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  if Assigned(LastControl) then
    L.Top := LastControl.Top + LastControl.Height
  else
    L.Top := 0;
  Tag := Tag + L.Height;

  LastControl := L;
end;

还有另一种方法是找到最低的控件并根据它的坐标添加控件：

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
    Bottom, TestBottom: Integer;
    i: Integer;
begin
  // Find "Bottom"
  Bottom := 0;
  for i:=0 to ScrollBox1.ControlCount-1 do
    with ScrollBox1.Controls[i] do
    begin
      TestBottom := Top + Height;
      if TestBottom > Bottom then
        Bottom := TestBottom;
    end;
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Bottom;
  Tag := Tag + L.Height;
end;