4

我目前正在制作一个 Scotty API，但找不到任何 basicAuth 实现示例（Wai Middleware HttpAuth）。

具体来说，我想将基本身份验证标头（用户、密码）添加到我的一些端点（即以“admin”开头的端点）。我已经设置好了所有东西，但我似乎无法区分哪些端点需要身份验证，哪些不需要。我知道我需要使用这样的东西，但它使用 Yesod，我无法将它翻译成 Scotty。

到目前为止，我有这个：

routes :: (App r m) => ScottyT LText m ()
routes = do
  -- middlewares
  middleware $ cors $ const $ Just simpleCorsResourcePolicy
    { corsRequestHeaders = ["Authorization", "Content-Type"]
    , corsMethods = "PUT":"DELETE":simpleMethods
    }
    
  middleware $ basicAuth 
      (\u p -> return $ u == "username" && p == "password") 
      "My Realm" 
  
  -- errors
  defaultHandler $ \str -> do
    status status500
    json str

  -- feature routes
  ItemController.routes
  ItemController.adminRoutes
  
  -- health
  get "/api/health" $
    json True

但它为我的所有请求添加了身份验证。我只需要其中一些。

太感谢了！

4

1 回答 1

1

您可以使用 的authIsProtected字段AuthSettings来定义一个函数，该函数Request -> IO Bool确定特定 (Wai)Request是否需要通过基本身份验证进行授权。特别是，您可以检查 URL 路径组件并以这种方式进行确定。

不幸的是，这意味着授权检查与 Scotty 路由完全分离。这在您的情况下可以正常工作，但可能会使 Scotty 路线对授权的细粒度控制变得困难。

无论如何，源代码AuthSettings中有重载"My Realm"字符串，根据文档，定义设置的推荐方法是使用重载字符串编写如下内容：

authSettings :: AuthSettings
authSettings = "My Realm" { authIsProtected = needsAuth }

这看起来很可怕，但无论如何，该needsAuth函数将具有签名：

needsAuth :: Request -> IO Bool

因此它可以检查 WaiRequest并在 IO 中决定页面是否首先需要基本身份验证。调用pathInfo会Request为您提供路径组件列表（没有主机名和查询参数）。因此，根据您的需要，以下应该有效：

needsAuth req = return $ case pathInfo req of
  "admin":_ -> True   -- all admin pages need authentication
  _         -> False  -- everything else is public

请注意，这些是已解析的非查询路径组件，因此/adminand /admin/and /admin/whateverand even/admin/?q=hello受到保护，但显然/administrator/...不是。

一个完整的例子：

{-# LANGUAGE OverloadedStrings #-}

import Web.Scotty
import Network.Wai.Middleware.HttpAuth
import Data.Text ()   -- needed for "admin" overloaded string in case
import Network.Wai (Request, pathInfo)

authSettings :: AuthSettings
authSettings = "My Realm" { authIsProtected = needsAuth }

needsAuth :: Request -> IO Bool
needsAuth req = return $ case pathInfo req of
  "admin":_ -> True   -- all admin pages need authentication
  _         -> False  -- everything else is public

main = scotty 3000 $ do
  middleware $ basicAuth (\u p -> return $ u == "username" && p == "password") authSettings
  get "/admin/deletedb" $ do
    html "<h1>Password database erased!</h1>"
  get "/" $ do
    html "<h1>Homepage</h1><p>Please don't <a href=/admin/deletedb>Delete the passwords</a>"
于 2021-02-03T20:05:55.307 回答