0

这是关于如何在 oracle 中将对象类型作为参数传递的下一级问题。

我的问题是在相同的上下文中，主子嵌套级别关系更深一些，它是对象中的对象。而且我没有找到任何方法从 PL-SQL 调用这样的过程。

让我们修改上述问题中给出的示例，如下所示：

创建对象和类型：

CREATE OR REPLACE TYPE domain_details_ot AS OBJECT
(
    domain_name VARCHAR2(50),
    domain_ip   VARCHAR2(50)

);
CREATE OR REPLACE TYPE domain_details_nt AS TABLE OF domain_details_ot;

CREATE OR REPLACE TYPE CALLBACK_T AS OBJECT
(
    url VARCHAR2(50),
    uri_key NUMBER,
    domains  domain_details_nt

);
CREATE OR REPLACE TYPE callbck AS TABLE OF callback_t;

为需求创建和插入语句：

CREATE TABLE url_hdr
(url_hdr_id   INT 
, url VARCHAR2(100)
, url_key NUMBER
, CONSTRAINT url_hdr_pk PRIMARY KEY (url_hdr_id)
);

CREATE TABLE url_dtl
(url_dtl_id INT
, url_hdr_id   INT 
, domain_name VARCHAR2(500)
, domain_ip  VARCHAR2(50)
, CONSTRAINT url_dtl_pk PRIMARY KEY (url_dtl_id)
, CONSTRAINT url_dtl_fk1 FOREIGN KEY (url_hdr_id)  REFERENCES url_hdr(url_hdr_id)
);

INSERT INTO url_hdr VALUES (1, 'www.abc.com', 12345);
INSERT INTO url_hdr VALUES (2, 'www.xyz.com',23456);

INSERT INTO url_dtl VALUES (1, 1, 'abc.com', '0.0.0.0');
INSERT INTO url_dtl VALUES (2, 1, 'def.com', '0.0.0.1');
INSERT INTO url_dtl VALUES (3, 2, 'uvw.com', '0.0.0.2');
INSERT INTO url_dtl VALUES (4, 2, 'xyz.com', '0.0.0.3');
COMMIT;

SELECT uh.url, uh.url_key, ud.domain_name, ud.domain_ip
FROM url_hdr uh
,url_dtl ud
WHERE uh.url_hdr_id = ud.url_hdr_id
AND uh.url_hdr_id IN (1,2);

程序示例代码：

CREATE OR REPLACE PROCEDURE get_callback_info(
                                              pi_clbk      IN     callbck := callbck()
                                             )
IS
BEGIN
    FOR i IN 1..pi_clbk.COUNT
    LOOP
        dbms_output.put_line('i : '||i ||' '||pi_clbk(i).url);
        FOR j IN 1..pi_clbk(i).domains.COUNT
        LOOP
            dbms_output.put_line('i : '||i || ' j : '||j ||' '||pi_clbk(i).uri_key);
            dbms_output.put_line('i : '||i || ' j : '||j ||' '||pi_clbk(i).domains(j).domain_name);
            dbms_output.put_line('i : '||i || ' j : '||j ||' '||pi_clbk(i).domains(j).domain_ip);
        END LOOP;
    END LOOP;
END;
/

由于这是从 Java 代码调用的，因此他们可以使用 in 对象创建对象。我不需要从 PL-SQL 端调用它，我就得救了。

现在，我的问题是如何从 PL-SQL 调用这样的过程？我想为 Select 语句返回的记录调用此过程。基本上我需要将这些值存储在 callbck 类型的变量中。

4

1 回答 1

0

您实例化对象实例的方式与在 SQL 中执行的方式相同，例如：

select callbck
       ( callback_t
         ( 'www.abc.com'
         , 12345
         , domain_details_nt
           ( domain_details_ot('abc.com', domain_ip => '0.0.0.0')
           , domain_details_ot('xyz.com', domain_ip => '0.0.0.1') ) )
       , callback_t
         ( 'www.xyz.com'
         , 23456
         , domain_details_nt
           ( domain_details_ot('xyz.com', domain_ip => '0.0.0.2')
           , domain_details_ot('abc.com', domain_ip => '0.0.0.3') ) )
       )
from   dual;

所以，要调用一个过程，它就像

begin
    get_callback_info(
        callbck
        ( callback_t
          ( 'www.abc.com'
          , 12345
          , domain_details_nt
            ( domain_details_ot('abc.com', domain_ip => '0.0.0.0')
            , domain_details_ot('xyz.com', domain_ip => '0.0.0.1') ) )
        , callback_t
          ( 'www.xyz.com'
          , 23456
          , domain_details_nt
            ( domain_details_ot('xyz.com', domain_ip => '0.0.0.2')
            , domain_details_ot('abc.com', domain_ip => '0.0.0.3') ) )
        )
    );
end;
于 2021-01-22T19:51:23.040 回答