macros - 在 Common Lisp 中编写 ++ 宏

Question

出于语义原因，我一直在尝试编写一个 Lisp 宏，该宏将在其他编程语言中执行相当于 ++ 的功能。我尝试以几种不同的方式来做到这一点，但它们似乎都不起作用，并且都被解释器接受，所以我不知道我是否有正确的语法。我对如何定义的想法是

(defmacro ++ (variable)
  (incf variable))

但这在尝试使用它时给了我一个简单的类型错误。什么会让它发挥作用？

Answer 1

请记住，宏返回要计算的表达式。为此，您必须反引号：

(defmacro ++ (variable)
   `(incf ,variable))

Answer 2

前面的两个答案都有效，但它们为您提供了一个宏，您称之为

(++ varname)

而不是我怀疑你想要的 varname++ 或 ++varname。我不知道你是否真的可以得到前者，但对于后者，你可以做一个读取宏。由于它是两个字符，因此调度宏可能是最好的。未经测试，因为我没有一个方便的运行 lisp，但类似：

(defun plusplus-reader (stream subchar arg)
   (declare (ignore subchar arg))
   (list 'incf (read stream t nil t)))
(set-dispatch-macro-character #\+ #\+ #'plusplus-reader)

应该使 ++var 实际上读为 (incf var)。

Answer 3

语法(++ a)是一个无用的别名(incf a)。但是假设您想要后增量的语义：检索旧值。在 Common Lisp 中，这是用 完成的prog1，如：(prog1 i (incf i))。Common Lisp 不会受到不可靠或模棱两可的评估顺序的影响。前面的表达式意味着i被评估，并且值被隐藏在某个地方，然后(incf i)被计算，然后返回隐藏的值。

制作一个完全防弹pincf（post- incf）并不是一件容易的事。(incf i)具有i仅评估一次的 nice 属性。我们也想(pincf i)拥有那个属性。所以这个简单的宏不够用：

(defmacro pincf (place &optional (increment 1))
  `(prog1 ,place (incf ,place ,increment))

为了做到这一点，我们必须求助于 Lisp 的“分配位置分析器”get-setf-expansion来获取允许我们的宏正确编译访问的材料：

(defmacro pincf (place-expression &optional (increment 1) &environment env)
  (multiple-value-bind (temp-syms val-forms
                        store-vars store-form access-form)
                        (get-setf-expansion place-expression env)
    (when (cdr store-vars)
      (error "pincf: sorry, cannot increment multiple-value place. extend me!"))
    `(multiple-value-bind (,@temp-syms) (values ,@val-forms)
       (let ((,(car store-vars) ,access-form))
         (prog1 ,(car store-vars)
                (incf ,(car store-vars) ,increment)
                ,store-form)))))

使用 CLISP 进行一些测试。（注意：依赖于材料的扩展get-setf-expansion可能包含特定于实现的代码。这并不意味着我们的宏不可移植！）

8]> (macroexpand `(pincf simple))
(LET* ((#:VALUES-12672 (MULTIPLE-VALUE-LIST (VALUES))))
 (LET ((#:NEW-12671 SIMPLE))
  (PROG1 #:NEW-12671 (INCF #:NEW-12671 1) (SETQ SIMPLE #:NEW-12671)))) ;
T
[9]> (macroexpand `(pincf (fifth list)))
(LET*
 ((#:VALUES-12675 (MULTIPLE-VALUE-LIST (VALUES LIST)))
  (#:G12673 (POP #:VALUES-12675)))
 (LET ((#:G12674 (FIFTH #:G12673)))
  (PROG1 #:G12674 (INCF #:G12674 1)
   (SYSTEM::%RPLACA (CDDDDR #:G12673) #:G12674)))) ;
T
[10]> (macroexpand `(pincf (aref a 42)))
(LET*
 ((#:VALUES-12679 (MULTIPLE-VALUE-LIST (VALUES A 42)))
  (#:G12676 (POP #:VALUES-12679)) (#:G12677 (POP #:VALUES-12679)))
 (LET ((#:G12678 (AREF #:G12676 #:G12677)))
  (PROG1 #:G12678 (INCF #:G12678 1)
   (SYSTEM::STORE #:G12676 #:G12677 #:G12678)))) ;
T

现在这是一个关键的测试用例。在这里，这个地方包含一个副作用：(aref a (incf i)). 这必须只评估一次！

[11]> (macroexpand `(pincf (aref a (incf i))))
(LET*
 ((#:VALUES-12683 (MULTIPLE-VALUE-LIST (VALUES A (INCF I))))
  (#:G12680 (POP #:VALUES-12683)) (#:G12681 (POP #:VALUES-12683)))
 (LET ((#:G12682 (AREF #:G12680 #:G12681)))
  (PROG1 #:G12682 (INCF #:G12682 1)
   (SYSTEM::STORE #:G12680 #:G12681 #:G12682)))) ;
T

所以首先发生的是Aand(INCF I)被评估，并成为临时变量#:G12680and #:G12681。访问数组并在 中捕获值#:G12682。然后我们有我们的PROG1which 保留了返回值。system::store该值递增，并通过 CLISP 的函数存储回数组位置。请注意，此存储调用使用临时变量，而不是原始表达式A和I. (INCF I)只出现一次。

Answer 4

我强烈建议不要为 incf 创建别名。它会降低其他阅读您的代码的人的可读性，他们必须问自己“这是什么？它与 incf 有什么不同？”

如果你想要一个简单的后增量，试试这个：

(defmacro post-inc (number &optional (delta 1))
  "Returns the current value of number, and afterwards increases it by delta (default 1)."
  (let ((value (gensym)))
    `(let ((,value ,number))
       (incf ,number ,delta)
       ,value)))

Answer 5

从语义上讲，前缀运算符 ++ 和 -- 在诸如 c++ 之类的语言中或在普通 lisp 中等效的 incf/decf 中。如果你意识到这一点，并且像你的（不正确的）宏一样，实际上是在寻找一个句法改变，那么你已经被展示了如何使用像 `(incf ,x) 这样的反引号来做到这一点。甚至已经向您展示了如何让读者绕过这个来获得更接近非 lisp 语法的东西。不过，这就是问题所在，因为这些都不是一个好主意。一般来说，使一种语言更接近另一种语言的非惯用编码并不是一个好主意。

但是，如果实际上是在寻找语义，您已经得到了前面提到的前缀版本，但后缀版本在语法上并不容易匹配。您可以使用足够多的阅读器黑客技术来做到这一点，但这并不漂亮。

如果这就是你要找的，我建议 a) 坚持使用 incf/decf 名称，因为它们是惯用的并且工作良好 b) 编写 post-incf、post-decf 版本，例如 (defmacro post-incf (x) `(prog1 ,x (incf ,x)) 之类的东西。

就个人而言，我不认为这会特别有用，但 ymmv。

Answer 6

对于预增量，已经有 incf，但您可以定义自己的

(define-modify-macro my-incf () 1+)

对于后增量，您可以使用它（来自 fare-utils）：

(defmacro define-values-post-modify-macro (name val-vars lambda-list function)
 "Multiple-values variant on define-modify macro, to yield pre-modification values"
 (let ((env (gensym "ENV")))
   `(defmacro ,name (,@val-vars ,@lambda-list &environment ,env)
      (multiple-value-bind (vars vals store-vars writer-form reader-form)
          (get-setf-expansion `(values ,,@val-vars) ,env)
       (let ((val-temps (mapcar #'(lambda (temp) (gensym (symbol-name temp)))
                                 ',val-vars)))
          `(let* (,@(mapcar #'list vars vals)
                  ,@store-vars)
             (multiple-value-bind ,val-temps ,reader-form
               (multiple-value-setq ,store-vars
                 (,',function ,@val-temps ,,@lambda-list))
               ,writer-form
               (values ,@val-temps))))))))

(defmacro define-post-modify-macro (name lambda-list function)
 "Variant on define-modify-macro, to yield pre-modification values"
 `(define-values-post-modify-macro ,name (,(gensym)) ,lambda-list ,function))

(define-post-modify-macro post-incf () 1+)

Answer 7

尽管我肯定会记住simon在他的帖子中评论的评论和提示，但我真的认为user10029的方法仍然值得一试，所以，只是为了好玩，我试图将它与接受的答案结合起来使++x运算符工作（即，将 x 的值增加 1）。试试看！

解释：好的旧 SBCL 不会编译他的版本，因为必须在 dispatch-char 查找表上显式设置“+”符号make-dispatch-macro-character，并且在评估它之前仍然需要宏传递变量的名称。所以这应该做的工作：

(defmacro increment (variable)
  "The accepted answer"
  `(incf ,variable))

(make-dispatch-macro-character #\+) ; make the dispatcher grab '+'

(defun |inc-reader| (stream subchar arg)
  "sets ++<NUM> as an alias for (incf <NUM>).
   Example: (setf x 1233.56) =>1233.56
            ++x => 1234.56
            x => 1234.56"
   (declare (ignore subchar arg))
   (list 'increment (read stream t nil t)))

(set-dispatch-macro-character #\+ #\+ #'|inc-reader|)

有关用法示例，请参见|inc-reader|的文档字符串。（密切）相关的文档可以在这里找到：

• http://clhs.lisp.se/Body/f_set__1.htm
• http://clhs.lisp.se/Body/f_mk_dis.htm#make-dispatch-macro-character

这种实现的结果是不再理解像 +123 这样的数字条目（调试器使用 跳转no dispatch function defined for #\Newline）但进一步的解决方法（甚至避免）似乎是合理的：如果你仍然想坚持这个，也许最好的选择是不要采取++ 作为前缀，但 ## 或任何其他更多 DSL-ish 解决方案

干杯！

安德烈斯

Answer 8

这应该可以解决问题，但是我不是 lisp 大师。

(defmacro ++ (variable)
  `(setq ,variable (+ ,variable 1)))