4

Fedora 33 Raku

我正在尝试使用 Raku 的 NativeCall 与 libX11.so 对话以打印出我的屏幕和显示器：

use NativeCall;

class Display is repr('CStruct') { has Pointer $.DisplayPtr };

# libX11.so --> X11
sub XOpenDisplay(Str $name = ':0') returns Display is native('X11') { * }
sub XDefaultScreen(Display $) returns int32 is native('X11') { * }

my Display $display = XOpenDisplay()
    or die "Can not open display";
 
my int $screen = XDefaultScreen($display);

print "display = <" ~ $display ~ ">\n";
print "screen =  <" ~ $screen  ~ ">\n";


$ libX11.pl6
display = <Display<90201160>>
screen =  <0>

问题。我缺少关于类语法的一些内容，因为它向我显示了一个指针地址而不是我的显示，我认为它是“：0”。我也认为类声明应该在某处显示一个字符串。

4

2 回答 2

7

您有点混淆了Display，它是一个用于与 X 交互的对象，以及一个display name，它是一个可用于识别和连接到 Display 的字符串。

此外，最好不要使用repr('CPointer')，而不是repr('CStruct')，XDisplay *因为 Xlib 文档说它应该被视为一个不透明的指针，并且通过函数访问的所有内容，并且将整个结构转换为 Raku 会很费力（而且不是很有用）。

由于它就像一个对象，您可以选择将所有 Xlib 函数封装在Display类中，并将它们包装在方法中，如NativeCall 文档的指针部分所示。到目前为止，我对这种风格的代码的翻译是：

use NativeCall;

class Display is repr('CPointer') {
  sub XOpenDisplay(Str) returns Display is native('X11') { * }
  method new(Str $name = ':0') {
    XOpenDisplay($name);
  }

  # You can wrap a libX11 function in a method explicitly, like this...
  sub XDisplayString(Display) returns Str is native('X11') { * }
  method DisplayString {
    XDisplayString(self);
  }

  # Or implicitly, by putting 'is native' on a method declaration 
  # and using 'is symbol' to match the names
  # (self will be passed as the first argument to the libX11 function)
  method DefaultScreen() returns int32 is native('X11') 
    is symbol('XDefaultScreen') { * }

  method Str {
    "Display({ self.DisplayString })";
  }
}

my Display $display .= new
    or die "Can not open display";

my int $screen = $display.DefaultScreen;

print "display = <" ~ $display ~ ">\n";
print "screen =  <" ~ $screen  ~ ">\n";

我提供了一个method Strfor Display，以便可以直接打印它，但同样，不要将对象与用于获取对象的字符串混淆。您可以从这里继续以相同的方式向Display、 以及定义Screen、Window等添加更多方法。您不必这样做——您可以自由地公开定义 subs 并使用对 XOpenDisplay 和其他所有内容的调用，就好像您正在编写 C 一样，但是 OO 样式往往更简洁一些。这是你的选择。

于 2020-12-21T08:10:17.677 回答
5

在评论@hobbs中指出了正确的方向，通过建议一个新函数 ，XDisplayString它实际上可用于将指针转换为描述显示的字符串，而实际上不需要进入指针的完整结构。所以这就是它的方式：

use NativeCall;

class Display is repr('CPointer') {};

# libX11.so --> X11
sub XOpenDisplay(str $name = ':0') returns Display is native('X11') { * }
sub XDefaultScreen(Str $) returns int32 is native('X11') { * }
sub XDisplayString(Display $display) returns Str is native('X11') { * }

my $display = XOpenDisplay() or die "Can not open display";
my Str $displayStr = XDisplayString($display);
my int $screen = XDefaultScreen( $displayStr );

print "display = <" ~ $displayStr ~ ">\n";
print "screen =  <" ~ $screen  ~ ">\n";

那将返回：

display = <:0>
screen =  <64>

至少在我的机器上。这里的关键是你实际上是在描述屏幕的正确方式，至少就目前XDisplayString而言，所以你把原来的 Pointer 变成 a Str，然后你在任何X*需要显示的字符串描述的地方使用它.

于 2020-12-21T07:16:29.727 回答